DB Werte auffaddieren

Eigentlich mach ich sowas ungern, aber schau die mal diese Rampenbaustein genau an:

Code:
FUNCTION FC195 : REAL
TITLE = 'Rampenfunktion'
//
// Rampen bzw. Treppengenerator
//
// Bei Eingangsänderungen erhöht der Baustein Eingangswert innerhalb der angegebenen Zeit an
// Anwendung: Sollwertsprünge am Reglereingang abfedern

VERSION : '1.0'
AUTHOR  : 'F.A'
NAME    : 'Rampe1'
FAMILY  : 'CONTR'

// Bausteinparameter
VAR_INPUT
  // Eingangsparameter
    EIN : REAL;
    SPRUNG_MIN : REAL; // Mindeständerung, ab dem die Rampe wirksam wird, sonst direkte Durchschleifung des Eingangs
    RAMPENZEIT : INT; //Ausgangsrampen innerhalb dieser Zeit (100ms)
    ZYKLUS : INT; // Aufrufzyklus (100ms)
END_VAR
VAR_IN_OUT
  // Durchgangsparameter
  Z : INT := 0 ; // Interner Zähler für Zyklus
  EIN_ALT :REAL := 0.0;
  AUS : REAL;
END_VAR
VAR_OUTPUT
 // Ausgangsparameter
END_VAR

VAR_TEMP
  // temporäre Variablen
  DELTA : REAL; 
END_VAR
  // Anweisungsteil
   IF  EIN <> EIN_ALT  THEN
            Z := (RAMPENZEIT ) DIV ZYKLUS;
            EIN_ALT := EIN;
   END_IF;
   IF ABS(EIN-AUS) < SPRUNG_MIN THEN
        AUS := EIN;
        Z := 0;
   END_IF;
   
   IF Z > 0 THEN
       DELTA := (EIN - AUS) / Z;
       AUS := AUS + DELTA;
       Z := Z-1;
   END_IF;
       
  FC195 := AUS;
END_FUNCTION

hoffe das hilft

P.S. wenn du immer noch auf dem Schlauch stehst, solltest du für heute Feierabend machen, oder gleich Wochenende...
 
Zuviel Werbung?
-> Hier kostenlos registrieren
ich bekomm zwar jetzt den wert, um den jede minute erhöht werden muss, kann aber den wert nicht erhöhen, weil ich net weiß wie, wobei ich wieder am anfang steh, hab doch versucht den wert im step7 programm immer auffzuaddieren also z.B. auf die 50 C° immer 1 ° pro min, bin doof oder?

Ist nicht schwer:
Du weisst die Steigung zB x °C / min
Dann nimmst einen Timer

U T1
=M1.0

UN T1
L s5t#60s
SE T1

Der M1.0 ist jetzt jede Minute einen Zyklus lang VKE 1

U M1.0
SPBN WEIT
L Sollwert //hier wird nun erhöht
L Steigung
+R
T Sollwert

L Endwert
<R
SPB WEIT

L Endwert //als Begrenzung nach oben
T Sollwert

WEIT: NOP 0


Aber es ist einfacher Du nimmst einen Rampenbaustein, weil der geht in beide Richtungen!
 
ja stimmt, die andere richtung also temperatur ernidrigen benötige ich ja auch, hab eben versucht diesen rampenbaustein zu finden, wo sind die genau? in der standard library hab ich keinen FB52 gefunden, welchen kann ich denn jetzt für meine aufgabe nehmen?

@ kiestumpe: jetzt bin ich wirklich verwirrt, is das VB??? ich glaub ich geh gleich heim;) , trotzdem danke
 
Wieso nicht wie borromeus?

Das ist einfach, unklompiziert und funzt auch. Bei der negativen Steigung sollte das auch funktionieren.
Die Probleme kommen dann noch, nämlich das eventl. die Regler anfangen zu schwingen usw.
 
ich probier do hin und her, programmier scripte und denk net dran dass siemens so "tolle" Standard FB's hat die einem das leben oft erleichtern, jetzt muss ich nur noch den richtigen finden, weiß jemand zufällig grad welchen ich nehmen kann und in welcher LIB der steckt?

Wenn die regler anfangen zu schwingen ruf ich meinen Regelungstechnik Prof an und dann klappts, nee im ernst, dafür stehen mir profis zur seite die im gegensatz zu mir, nicht nur Vorlesungswissen, sondern viel praktische einstellerfahrung haben

Mein Dank an alle
 
@ kiestumpe: was is ST( Structured Text bestimmt?!)ohje mit strukturiertem text musste ich mich rumschlagen nachdem ich ein 500 seiten Step5 programm konvertiert habe und es 100 mal durch den compiler gejagt hab bis er die bausteine erstellen konnte. hab Professional
 
Zuletzt bearbeitet:
Zuviel Werbung?
-> Hier kostenlos registrieren
ganz genau, auch SCL genannt (eine art Turbo-Pascal für SPS)

Achja, a propos Regler, mit dem Standard-Regler (FB41) solltest du dir das Tool "PID Control parametrieren" anschauen. Das gibt's sogar in der Unprofessional-Version... ;-)
 
ja danke, hab den FB42, "PID Control Parametrieren" hab ich natürlich schon genutzt, schade is dass es diesen kurvenschreiber nur mit dem softwarepaket "Standard PID" gibt, bei den reglern kann man auch viel mehr einstellen
 
Zuviel Werbung?
-> Hier kostenlos registrieren
jetzt mal ne frage, ich muss noch ne studiarbeit über SCL machen, is das die gleiche sprache wie die ST-AWL-Quelle die ich nach dem konvertieren angezeigt bekomme? das könnt ich ja dann schon wegen dem konvertieren von dem riesen Step5 programm
 
nein, AWL oder Anweisungsliste ist eher wie Assembler (und nur schwer zu lesen)
SCL ist eine höhere Programmiersprache und in IEC 61131-3 aufgeführt.
 
die in der firma haben gesagt, die standard regler von step7 reichen aus, ich denke zwar das die regler in der alten s5 mehr konnten aber ich hoffe die standards aus s7 tuns auch. hab ziemlich lang gebraucht um durch das s5 programm durchzublicken, wurde von nem absoluten Pro programmiert und ich als kleiner student hab das riesige programm dann konvertiert, das war en act, und die visu durft ich auch von intouch auf flex umstellen
 
Zuviel Werbung?
-> Hier kostenlos registrieren
kiestumpe schrieb:
nein, AWL oder Anweisungsliste ist eher wie Assembler (und nur schwer zu lesen)
SCL ist eine höhere Programmiersprache und in IEC 61131-3 aufgeführt.

nee die datei nach dem konvertieren hieß AWL quelle, war aber structurierter text den man bearbeiten muss damit der compiler daraus bausteine machen kann

kennt glaub ich jeder der mal en s5 programm konvertiert hat, denk ich
 
hatte in der uni auch nur c++ und assembler, und bis ich mal durch awl einigermaßen durchgeblickt habe hats ne weile gedauert, haben auf der uni fast nur fup gemacht in den laboren
 
nochmal:

Es gibt im Ordner "Quellen"

AWL-Quellen
SCL-Quellen (entspricht ST)

Es gibt im Ordner "Bausteine"

AWL-Bausteine: Können sowohl aus Quellen erzeugt, oder direkt im Bausteinordner erzeugt werden.
SCL-Bausteine (entspricht ST): Müssen immer aus Quellen erzeugt werden, braucht Zusatzpaket SCL oder die Professionalversion.

Ein Beispiel für SCL findest du in dem was ich weiter oben gecodet habe.
 
Zuviel Werbung?
-> Hier kostenlos registrieren
stimmt, da war ich wohl mal wieder zu schnell ohne nachzudenken, du hast selbstverständlich recht und die awl quelle besteht aus awl code, sorry,

mh muss ich wohl doch noch en bissl was schaffen für die studienarbeit, verdammt :rolleyes:
 
apropo SCL studienarbeit, ich hab den wellenreuther um scl zu verstehn und bissl zu lernen, kannst du den empfehlen? oder kannst du mir auch noch was vorschlagen wie ich am besten an scl rankomme?
 
okay, bin dann mal wech, endlich wochenende, wenn du en tipp wegen scl hast würd ich mich freuen wenn du mir ihn gibst,


dann mal schönes wochenende an alle

und danke nochmal für die hilfen von euch
 
Zurück
Oben