FUNCTION "MODE_HAND_AUTO_STOP" : VOID
TITLE =UMSCHALTUNG HAND-AUTO-STOP FÜR A-ANLAGEN ALLGEMEIN
NAME : HA_AU_ST
VERSION : 0.0
VAR_INPUT
MODE_ENABLE : BOOL ; //MODEBIT SEKTIONSFREIGABE
COM_MANUAL : BOOL ; //COM-BIT HAND
COM_AUTO : BOOL ; //COM-BIT AUTOMATIK
UNLOCKED : BOOL ; //MODE-BIT UNLOCKED (ALLE DIESER BETREFFENDEN GRUPPE)
START_UP_WT : BOOL ; //ANFAHRWARNUNG ZEITBIT
END_VAR
VAR_IN_OUT
MOD_MAN_PSL : BOOL ; //MODE VORWAHL HAND
MOD_AUT_PSL : BOOL ; //MODE VORWAHL AUTOMATIK
MOD_MANUAL : BOOL ; //MODE BETRIEBSART HAND
MOD_AUTO : BOOL ; //MODE BETRIEBSART AUTOMATIK
END_VAR
BEGIN
NETWORK
TITLE =MODE xxx VORWAHL HAND
//DIE VORWAHL DER BETRIEBSART WIRD DIREKT DURCH DRÜCKEN DER ENTSPRECHENDEN
//TASTERBEDINUNG (HW ODER VISU) AKTIVIERT.
U #MODE_ENABLE;
U( ;
O #COM_MANUAL;
O #MOD_MAN_PSL;
) ;
UN #MOD_MANUAL;
= #MOD_MAN_PSL;
NETWORK
TITLE =MODE xxx VORWAHL AUTOMATIK
//DIE VORWAHL DER BETRIEBSART WIRD DIREKT DURCH DRÜCKEN DER ENTSPRECHENDEN
//TASTERBEDINUNG (HW ODER VISU) AKTIVIERT.
U #MODE_ENABLE;
U( ;
O #COM_AUTO;
O #MOD_AUT_PSL;
) ;
UN #MOD_AUTO;
UN #UNLOCKED;
= #MOD_AUT_PSL;
NETWORK
TITLE =MODE xxx BETRIEBSART HAND
//DIE VORWAHL DER BETRIEBSART WIRD DIREKT DURCH DRÜCKEN DER ENTSPRECHENDEN
//TASTERBEDINUNG (HW ODER VISU) AKTIVIERT. NACH ABLAUF DER ANFAHRWARNUNG WIRD DIE
//BETRIEBSAT DANN AKTIVIERT. EINE UMSCHALTUNG VON AUTOMATIK AUF HAND IST OHNE
//ANFAHRWARNUNG MÖGLICH.
U #MODE_ENABLE;
U( ;
U #MOD_MANUAL;
UN #MOD_AUTO;
O ;
U #MOD_MAN_PSL;
U( ;
O #START_UP_WT;
O #MOD_AUTO;
) ;
) ;
= #MOD_MANUAL;
NETWORK
TITLE =MODE xxx BETRIEBSART AUTOMATIK
//DIE VORWAHL DER BETRIEBSART WIRD DIREKT DURCH DRÜCKEN DER ENTSPRECHENDEN
//TASTERBEDINUNG (HW ODER VISU) AKTIVIERT. NACH ABLAUF DER ANFAHRWARNUNG WIRD DIE
//BETRIEBSAT DANN AKTIVIERT. EINE UMSCHALTUNG VON AUTOMATIK AUF HAND IST OHNE
//ANFAHRWARNUNG MÖGLICH.
U #MODE_ENABLE;
U( ;
U #MOD_AUTO;
UN #MOD_MANUAL;
O ;
U #MOD_AUT_PSL;
U #START_UP_WT;
) ;
= #MOD_AUTO;
END_FUNCTION