Adressierung

[bubu]

Zuviel Werbung?
-> Hier kostenlos registrieren

Hallo,

ich habe eine Aufgabe und ich wiess nicht wie kann ich die Aufgabe machen. Ich bittte um Hilfe.

AUFGABE: Durch Eingabe einer Integerzahl soll das entsprechende Bit in einem Datenbaustein gestezt werden.

Ich habe schon etwas mit ANY-Zeiger probiert aber konnte nichts machen.

Vielen Dank!

 

[vierlagig]

dafür sollte ein gewöhnlicher pointer reichen

wie groß ist denn das anzusprechende feld?
übergibst du byte und bit getrennt oder ist DBX4.7 einfach das 40. bit?

 

[derwestermann]

Zuviel Werbung?
-> Hier kostenlos registrieren

Welches Bit?

In SCl könnte man's so machen:

FUNCTION FC177 : BOOL
TITLE = 'SetBitDB'
VERSION : '1.0'
AUTHOR  : kai
NAME    : SetBitDB
FAMILY  : xS7
VAR_INPUT
  IN : INT;
  Set : BOOL;
END_VAR
VAR_TEMP
    Bytezeiger : INT;
    Boolzeiger : INT;
END_VAR
  
BEGIN
Bytezeiger := IN / 8;
Boolzeiger := IN MOD 8;
IF Set THEN
    DB10.DBX[Bytezeiger,Boolzeiger] := TRUE;
END_IF;
FC177 := FALSE;
END_FUNCTION

 

[vierlagig]

In SCl könnte man's so machen:

in awl dann äquivalänt so:

*
      L     #iBitNumber
      L     8
      /I    
      T     #iByte

      L     #iBitNumber
      L     8
      MOD   
      T     #iBit

      L     #iByte
      SLD   3
      L     #iBit
      +D    
      LAR1  

      AUF   #DbByNumber
      U     #xSet
      S     DBX [AR1,P#0.0]

aber verstehen mußtes selber ...wobei hier 40 das bit 5.0 ist

so is schöner:

*
      L     #iBitNumber
      L     8
      /I    
      T     #dTemp

      L     P##dTemp
      LAR1  

      L     W [AR1,P#2.0]
      SLD   3
      L     W [AR1,P#0.0]
      +D    
      LAR1  

      AUF   #DbByNumber
      U     #xSet
      S     DBX [AR1,P#0.0]

 

[bubu]

Vielen Dank,

ich habe geschaft...melde ich mich bald mit neuen Probleme

Ciao

 

[vierlagig]

Zuviel Werbung?
-> Hier kostenlos registrieren

ich habe geschaft...

auch verstanden

 

[Gerhard K]

auch verstanden

scheint jetzt nebensächlich zu sein.du hast ja schon die lösung präsentiert.

 

[vierlagig]

scheint jetzt nebensächlich zu sein.du hast ja schon die lösung präsentiert.

derwestermann wars ... ich hatte noch mit 40 auf 4.7 gerechnet und kam mit dem rest nicht hin

 

[bubu]

Zuviel Werbung?
-> Hier kostenlos registrieren

sorry Leute, mein Deutsch ist nicht am besten...die Lösung von vierlagig habe ich natürlich auch verstanden

Danke sehr noch einmal