FUNCTION_BLOCK "Leistungsdaten"
//
// Liest über SFC51 die Leistungsdaten der CPU aus
//
VAR_INPUT
REQ : BOOL; // Steigende Flanke startet eine Abfrage
END_VAR
VAR_OUTPUT
ERROR : BOOL; // TRUE bei Fehler
BUSY : BOOL; // TRUE = Lesevorgang noch nicht abgeschlossen
ANZ_PAE : DINT; // PAE (Anzahl in Byte), -1 wenn nicht verfügbar
ANZ_PAA : DINT; // PAA (Anzahl in Byte), -1 wenn nicht verfügbar
ANZ_M : DINT; // Merker (Anzahl in Byte), -1 wenn nicht verfügbar
ANZ_L : DINT; // Lokaldaten (Anzahl in Byte), -1 wenn nicht verfügbar
ANZ_T : INT; // Zeiten (Anzahl), -1 wenn nicht verfügbar
ANZ_Z : INT; // Zähler (Anzahl), -1 wenn nicht verfügbar
END_VAR
VAR
REQ_OLD : BOOL;
STATE : INT;
RDSYSST_REQ : BOOL;
RDSYSST_BUSY : BOOL;
RDSYSST_RETVAL : INT;
DR : ARRAY[1..10] OF
STRUCT
Index : WORD;
Code : WORD;
Anzahl : WORD;
Reman : WORD;
END_STRUCT;
SZL_HEADER : STRUCT
LENTHDR : WORD;
N_DR : WORD;
END_STRUCT;
END_VAR
VAR_TEMP
i : INT;
BEGIN
CASE STATE OF
//************
//* Start
0:
RDSYSST_REQ := false;
BUSY := false;
IF REQ AND NOT REQ_OLD THEN
ERROR := false;
BUSY := true;
STATE := 1;
END_IF;
//************
//* Vorhandenen Listen löschen
1:
FOR i := 1 TO 10 DO
DR[i].Index := 0;
DR[i].code := 0;
DR[i].Anzahl := 0;
DR[i].Reman := 0;
END_FOR;
SZL_HEADER.LENTHDR := 0;
SZL_HEADER.N_DR := 0;
RDSYSST_REQ := true;
STATE := 2;
// Ergebnis SFC Aufruf auswerten
2:
IF NOT RDSYSST_BUSY THEN
IF RDSYSST_RETVAL = 0 AND SZL_HEADER.LENTHDR = W#16#8 AND SZL_HEADER.N_DR <> 16#0 THEN // Erfolg
STATE := 3;
ELSE // Wenn SFC Aufruf mit Fehler, dann Ende mit Fehler
ERROR := true;
STATE := 0;
END_IF;
END_IF;
// Bereiche prüfen und auswerten
3:
ANZ_PAE := -1;
ANZ_PAA := -1;
ANZ_M := -1;
ANZ_L := -1;
ANZ_T := -1;
ANZ_Z := -1;
IF WORD_TO_INT(SZL_HEADER.N_DR) > 10 THEN
SZL_HEADER.N_DR := 10;
END_IF;
FOR i := 1 TO WORD_TO_INT(SZL_HEADER.N_DR) DO
CASE WORD_TO_INT(DR[i].Index) OF
1: ANZ_PAE := WORD_TO_DINT(DR[i].Anzahl);
2: ANZ_PAA := WORD_TO_DINT(DR[i].Anzahl);
3: ANZ_M := WORD_TO_DINT(DR[i].Anzahl) / 8; // Merker (Anzahl in Bit)
4: ANZ_T := WORD_TO_INT(DR[i].Anzahl);
5: ANZ_Z := WORD_TO_INT(DR[i].Anzahl);
//6: Anzahl der Byte im logischen Adreßraum
7: ANZ_L := WORD_TO_INT(DR[i].Anzahl); // Ergebnis in Byte
8: ANZ_M := WORD_TO_DINT(DR[i].Anzahl); // Merker (Anzahl in Byte)
9: ANZ_L := WORD_TO_DINT(DR[i].Anzahl) * 1024; // Ergebnis in kByte
END_CASE;
END_FOR;
STATE := 0;
END_CASE;
////////////////
RDSYSST_RETVAL := RDSYSST(
REQ := RDSYSST_REQ,
SZL_ID := 16#0014,
INDEX := 16#0000,
BUSY := RDSYSST_BUSY,
SZL_HEADER := SZL_HEADER,
DR := DR
);
REQ_OLD := REQ;
END_FUNCTION_BLOCK
