Wendeschaltung programmieren ?

larsibaby2000 · 20 Februar 2008

Hallo zusammen,

ich bräuchte mal einen Denkanstoss da ich im moment keine Ahnung habe wie ich das machen soll.

Also ich habe einen Linienscanner ( Barcode von Sick ) dieser ist an einen Motor montiert. Der motor soll nun starten sich zu drehen ( also der Scanner draht sich über dem Teil und scannt).

Soviel zur Hardware

Sein soll es so das wenn das Teil bereit liegt starte ich den Scanner und den Motor. Der Motor soll eine 360 Grad Drehung machen und dann in die andere Richtung fahren. Ich habe noch einen Sensor mit dem ich feststellen kann ob er einmal rum ist.

Ich hab mir schon den Kopf zerbrochen aber irgendwie fällt mir nix mehr ein was auch funtz

Vielen Dank schonmal

godi · 20 Februar 2008

Hallo!

Ja und was ist jetzt schlecht an einer Wendeschaltung?
Oder weißt du nicht wie man sie Programmiert?

Bekommst du von der Kamera auch eine Rückmeldung ob sie Betriebsbereit ist?
Wenn ja dann lasse erst den Motor starten wenn dein Teil und deine Kamera bereit ist.

godi

larsibaby2000 · 20 Februar 2008

nein ein signal vom scanner bekomme ich nicht.

ja, ich weiss nicht wie man die programmiert

aber vielleicht hast ja ein beispiel ?

godi · 20 Februar 2008

Ja weißt du wie man sie Hardwaremäßig macht? Also mit Relais und Schütze usw aufbaut?
Dann kannst du dir ja das mal aufzeichnen und im KOP oder FUP nachprogrammieren.

Funktion (grob):
Anlage ein und Teil bereit dann Schütz für erste Drehrichtung ein bis Sensor anspricht. Wenn Sensor anspricht kurze Verzögerung und dann zweiten Schütz für zweite Drehrichtung ein bis wieder der Sensor anspricht.

Nach der Funktion könntest schon deine ersten Versuche starten. ;-)

maxi · 20 Februar 2008

Für welche Steuerung brauchst du das den?

larsibaby2000 · 20 Februar 2008

ist ne 315-2DP

Also ich blicks im moment echt nicht !

vierlagig · 20 Februar 2008

was hammer denn bis jetzt?

larsibaby2000 · 20 Februar 2008

Also im Prinzip nix genaues

Code:

UN Stop 
U Teil Bereit
S Motor rechts
 
U Motor rechts
U Sensor 
R Motor rechts
 
UN Motor rechts
U Sensor
FP M10.0
S Motor links

vierlagig · 20 Februar 2008

und dein problem ist, dass der motor immer links dreht, obwohl er noch gar nichts rechts gedreht hat? und er dreht nur weil irgendson depp den sensor belegt?

larsibaby2000 · 20 Februar 2008

Genau !

Und was noch viel schlimmer ist das ich total auf dem schlauch stehe !!!

vierlagig · 20 Februar 2008

ich könnt dir jetzt ne lösung präsentieren, aber erstmal ne frage:

hast du ne idee, warum er immer links rum dreht? und wenn du an zwischenergebnisse denkst auch ne kleine ahnung davon, was dir fehlt?

larsibaby2000 · 20 Februar 2008

Ja das Prüblem ist einfach das der Sensor immer belegt ist weil das ja meine "Grundstellung" ist.
Also ich habe da mal noch ein bissl überlegt und mir folgendes einfallen lassen.

Code:

      UN    E      0.0   // Nicht in Stop
      U     E      0.1    // Teil bereit
      L     S5T#2S      Sensor prellen
      SV    T      2      Timer
      S     A      4.0    Setze Motor rechts
     
      U     E      0.2      Senor
      U     A      4.0      Motor rechts
      UN    T      2        Timer
      R     A      4.0       Rücksetze Motor rechts

vierlagig · 20 Februar 2008

und das löst das linksfahr prob?

was heißt immer belegt? also ich kenn deine anlage ja nur aus deinen dürftigen beschreibungen und stell es mir wie folgt vor: da is was, was vorwärts (rechts) und rückwärts (links) fahren soll und zwar vorwärts solange, bis der sensor (die vermeintliche grundstellung) belegt ist und dann wieder zurück ... richtig?

Ralle · 20 Februar 2008

Sag mal, eine Frage, du hast ja nur einen Sensor zur Umkehr, im schlechtesten Fall kann natürlich der Motor mal drüber weglaufen (Schwung beim Abschalten etc.) und sich dann das Scannerkabel verwickeln. Ist das eine reale Anlage? Zwei Sensoren und feste Anschläge wären evtl. Materialschonender.

larsibaby2000 · 20 Februar 2008

Ne nicht wirklich habs grad getestet !

1.Kein teil da und sensor belegt
2.Dann kommt teil sensor noch belegt
3.Motor dreht rechts bis sensor wieder belegt
4.Dann Motor links rum bis Sensor wieder belegt
5.Dann empfange ich den String vom Scanner oder aber auch nicht
wenn String vorhanden dann fördere ich teil aus
wenn kein String dann auch bzw bekomme ich einen fehlerstring
den ich weiter hinten verarbeite.

larsibaby2000 · 20 Februar 2008

Ja genau das ist da problem !
Die anlage ist real. jedoch läuft der motor sehr langsam und der Auftraggeber musst wohl sparen !!!

vierlagig · 20 Februar 2008

da ich gleich ins bett muß und ich auch keine lust habe mich im chat oberlehrer oder arrogantes arschloch nennen zu lassen, obwohl, das ist ja gar nicht passiert ... kinners das schleift ... mal ein eventueller lösungsansatz:

Code:

      UN    #stop
      SPBN  _001

      U     #teil_bereit
      UN    #wir_sind_schon_rechts_rum
      S     #rechts

      U     #rechts
      U     #umdrehung_ok
      R     #rechts
      S     #wir_sind_schon_rechts_rum

      U     #wir_sind_schon_rechts_rum
      U     #umdrehung_ok
      S     #links
      S     #wir_fahn_zurück

      U     #wir_fahn_zurück
      U     #ende_links_fahn
      R     #links
      R     #wir_fahn_zurück

_001: NOP   0

godi · 20 Februar 2008

vierlagig schrieb:
da ich gleich ins bett muß und ich auch keine lust habe mich im chat oberlehrer oder arrogantes arschloch nennen zu lassen, obwohl, das ist ja gar nicht passiert ... kinners das schleift ... mal ein eventueller lösungsansatz:

Code:

UN #stop SPBN _001 U #teil_bereit UN #wir_sind_schon_rechts_rum S #rechts U #rechts U #umdrehung_ok R #rechts S #wir_sind_schon_rechts_rum U #wir_sind_schon_rechts_rum U #umdrehung_ok S #links S #wir_fahn_zurück U #wir_fahn_zurück U #ende_links_fahn R #links R #wir_fahn_zurück _001: NOP 0

Hallo Vierlagig!

Ich würde den Stop nicht mit den Sprung machen weil wenn während des betriebes Stop gedrückt wird dann fährt alles weiter da die Bits nicht zurückgesetzt werden.
Ausserdem gehört das wir_sind_schon_rechts_rum am ende zurückgesetzt und ein Bit gehört auch gesetzt wenn der Teil fertig ist da ja das Teil entnommen werden auch soll und das nächste nachgeführt werden soll.

godi

vierlagig · 20 Februar 2008

godi schrieb:
Hallo Vierlagig!

Ich würde den Stop nicht mit den Sprung machen weil wenn während des betriebes Stop gedrückt wird dann fährt alles weiter da die Bits nicht zurückgesetzt werden.
Ausserdem gehört das wir_sind_schon_rechts_rum am ende zurückgesetzt und ein Bit gehört auch gesetzt wenn der Teil fertig ist da ja das Teil entnommen werden auch soll und das nächste nachgeführt werden soll.

godi

es war ein denkanstoß ... bei dem stop muß ich dir ein *ACK* verpassen, über stop denk ich zu wenig nach ... laufen muß die kiste, immer laufen

HSchedo · 22 Februar 2008

Mhhh, wenn ich das Richtig verstanden habe, dann gibt es nur einen Sensor um sowohl den Rechts- wie auch den Linkslauf zu stoppen.

Ich hab' mal ein etwas längeren, aber daür auch leicht verstänlichen Lösungsansatz.

// Zuerst auf die Startbedingungen warten und damit den
//Rechtslauf einschalten.
U #Teilvorhanden
U #Sensor
UN #Ausgang_Rechtslauf
UN #Ausgang_Linkslauf
FP M 120.0
S #Ausgang_Rechtslauf

// Danach erst mal daruf warten, dass der Sensor verlassen wurde,
// damit beim erneuten erreichen des Sensors
// auf Linkslauf umgeschaltet werden kann.
U #Ausgang_Rechtslauf
UN #Sensor
S "Sensor verlassen Rechtsl"

// Wenn die Endposition erreicht ist, dann den Rechtslauf
// abschalten.
U "Sensor verlassen Rechtsl"
U #Sensor
R #Ausgang_Rechtslauf

// Vielleicht brauchen wir eine kleine Pause zwischen.
// Rechts- und Linkslauf.
U "Sensor verlassen Rechtsl"
U #Sensor
L S5T#1S
SE T 1

// Nachdem die Wartezeit abgelaufen ist, den Linkslauf
// starten.
U T 1
S #Ausgang_Linkslauf
R "Sensor verlassen Rechtsl"

// Auch beim Linkslauf muss erstmal darauf gewartet werden,
// das der Sensor verlassen wurde.
U #Ausgang_Linkslauf
UN #Sensor
S "Sensor verlassen Linksl"

// Wenn der Sensor wieder erreicht ist, dass kann auch der
// Linkslauf wieder abgeschaltet werden.
U "Sensor verlassen Linksl"
U #Sensor
R #Ausgang_Linkslauf
R "Sensor verlassen Linksl"

Gruß Heiko

Wendeschaltung programmieren ?

Level-1

Level-1

Level-1

Level-1

Level-2

Level-1

Level-1

Level-1

Level-1

Level-1

Level-1

Level-1

Level-1

Super-Moderator , User des Jahres 2006-2007

Level-1

Level-1

Level-1

Level-1

Level-1

Level-1

Similar threads

Wir schützen deine Privatsphäre