"Schaltpunkte" korrekt programmieren (4-Punkt Regler)

FUNCTION_BLOCK FB 100
TITLE =Vierpunktregler für zwei Ventilatoren
//Für jeden der zwei Ventilatoren wird ein eigener Zweipunktregeler und damit
//insgesamt ein Vierpunktregler verwendet.
//   
AUTHOR : Kai
FAMILY : SPSForum
NAME : '45507'
VERSION : 1.0
 
VAR_INPUT
  Ventilator_1_Aus : REAL ; //Volumenstrom Ventilator 1 Aus [m3/h]
  Ventilator_2_Aus : REAL ; //Volumenstrom Ventilator 2 Aus [m3/h]
  Ventilator_1_Ein : REAL ; //Volumenstrom Ventilator 1 Ein [m3/h]
  Ventilator_2_Ein : REAL ; //Volumenstrom Ventilator 2 Ein [m3/h]
  Volumentstrom : REAL ; //Volumenstrom [m³/h]
END_VAR
VAR_OUTPUT
  Ventilator_1 : BOOL ; //Ventilator 1 Ein
  Ventilator_2 : BOOL ; //Ventilator 2 Ein
END_VAR
VAR
  Ventilator_1_Betrieb : BOOL ; //Ventilator 1 Betrieb
  Ventilator_2_Betrieb : BOOL ; //Ventilator 2 Betrieb
END_VAR
BEGIN
NETWORK
TITLE =Ventilator 1
//Volumenstrom [m³/h] < Volumenstrom Ventilator 1 Ein [m³/h] => Ventilator 1 Ein
//Volumenstrom [m³/h] > Volumenstrom Ventilator 1 Aus [m³/h] => Ventilator 1 Aus
//    
      U(    ; 
      L     #Volumentstrom; 
      L     #Ventilator_1_Ein; 
      <=R   ; 
      )     ; 
      S     #Ventilator_1_Betrieb; 
      U(    ; 
      L     #Volumentstrom; 
      L     #Ventilator_1_Aus; 
      >=R   ; 
      )     ; 
      R     #Ventilator_1_Betrieb; 
      U     #Ventilator_1_Betrieb; 
      =     #Ventilator_1; 
NETWORK
TITLE =Ventilator 2
//Volumenstrom [m³/h] < Volumenstrom Ventilator 2 Ein [m³/h] => Ventilator 2 Ein
//Volumenstrom [m³/h] > Volumenstrom Ventilator 2 Aus [m³/h] => Ventilator 2 Aus
//    
      U(    ; 
      L     #Volumentstrom; 
      L     #Ventilator_2_Ein; 
      <=R   ; 
      )     ; 
      S     #Ventilator_2_Betrieb; 
      U(    ; 
      L     #Volumentstrom; 
      L     #Ventilator_2_Aus; 
      >=R   ; 
      )     ; 
      R     #Ventilator_2_Betrieb; 
      U     #Ventilator_2_Betrieb; 
      =     #Ventilator_2; 
END_FUNCTION_BLOCK