einen von Zehn Merker auf 1 abfragen

      L     #wIN                        // zu prüfendes Wort
      ITD   
      DTR   
      T     #rIn
      UD    DW#16#7FFFFF                // 23 Bits Mantisse
      L     0
      <>D   
      =     #MehrAlsEin                 // Es ist mehr als 1 Bit gesetzt

      L     #rIn
      SRD   23                          // Exponent extrahieren
      L     127                         // Bias des Exponenten abziehen
      -D                                // Anzahl um die geshiftet wird
      L     1                           // Bitmuster das geshiftet wird
      SLD                               // Shift-Operation nach links entspricht Multiplikation mit 2
      DTR   
      T     #r_2hochExp                 // Ergibt 2^Exponent

      L     #rIn                        // Restwert bestimmen der über dem Ganzzahligen vielfachen
      L     #r_2hochExp                 // von 2^x liegt.
      -R                                // Mit diesem Wert nochmal das gleiche wie bei Schritt 1
      UD    DW#16#7FFFFF
      L     0
      <>D   
      =     #MehrAlsZwei                // Es sind mehr als 2 Bits gesetzt

FUNCTION FC 2 : VOID
TITLE =Zählung der gesetzten Bit's innerhalb eines Doppelworts (32 Bit)
//Der Baustein zählt die 1-Signal führenden Bits innerhalb eines Doppelworts. 
//Sollen die 1-Signal führenden Bits innerhalb eines Worts (16 Bit) gezählt 
//werden,sind folgende Änderungen vor zu nehmen:
//1.) In den Deklarationszeilen sind ZAEHLWORT und ZW_Speicher als WORD zu dela-
//    rieren.
//2.) Der Schleifenzähler ist statt 32 mit 16 vor zu besetzen.
AUTHOR : 190B
FAMILY : 
NAME : BIT_Z_32
VERSION : 0.1

VAR_INPUT
  ZAEHLWORT : DWORD ; //Doppelwort, dessen gesetzte Bits gezählt werden sollen.
END_VAR
VAR_OUTPUT
  ANZAHL : INT ; //Anzahl der gezählten, 1-Signal führenden Bit's.
END_VAR
VAR_TEMP
  Zaehler : INT ; //Schleifenzähler
  ZW_Speicher : DWORD ; //Zwischenspeicher
END_VAR
BEGIN
NETWORK
TITLE =
      L     #ZAEHLWORT; // Zählwort an
      T     #ZW_Speicher; // Zwischenspeicher übergeben.
      L     0; // Anzahl mit dem Wert 0
      T     #ANZAHL; // vorbesetzen.
      LAR1  P##ZW_Speicher; // Adressregister vorbelegen.
//;
      L     32; // Schleifenzähler mit 32
Next: T     #Zaehler; // vorbesetzen.
      UN    L [AR1,P#0.0]; // Bit n auf 0-Signal abfragen.
      SPB   M001; // Wenn 0-Signal, dann springen.
      L     #ANZAHL; // Anzahl laden,
      INC   1; // 1 hinzu addieren
      T     #ANZAHL; // und neuen Wert wegspeichern.
M001: +AR1  P#0.1; // Adressregister auf nächstes Bit setzen.
      L     #Zaehler; // Wert des Schleifenzählers laden und bei
      LOOP  Next; // NICHT NULL an den Schleifenanfang springen.
END_FUNCTION