Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Seite 2 von 8 ErsteErste 1234 ... LetzteLetzte
Ergebnis 11 bis 20 von 79

Thema: Profibus/Profinet-Teilnehmer Diagnose

  1. #11
    Registriert seit
    22.03.2007
    Ort
    Detmold (im Lipperland)
    Beiträge
    11.726
    Danke
    398
    Erhielt 2.402 Danke für 2.001 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    ... ging doch schneller als ich dachte.

    Hier also der Code zu "meinem" FB126 :
    Code:
    FUNCTION_BLOCK FB126                       // UP Profibus/ProfiNet-Diagnose
    TITLE   = 'UP Profibus/ProfiNet-Diagnose'  // UP Profibus/ProfiNet-Diagnose
    AUTHOR  : 'Larry'
    VERSION : '2.1'    //    01.06.2012
    FAMILY  : 'LL_Std'
    KNOW_HOW_PROTECT
    
    VAR_IN_OUT
       OBxx_Trigger  : BOOL ;
    END_VAR
    
    VAR_OUTPUT 
       Auswertung_aktiv : BOOL ;  
       ProfiBus_vorh    : BOOL ; 
       ProfiBus_IO      : BOOL ; 
       ProfiNet_vorh    : BOOL ; 
       ProfiNet_IO      : BOOL ; 
    END_VAR
    
    VAR
       PB_Slaves : STRUCT 
          Anzahl   : INT ; 
          Status   : ARRAY[0..255] OF BYTE ;        // Bit0 : projektiert, Bit1: nicht in Funktion, Bit2: Störung
       END_STRUCT ;
     
       PN_Slaves : STRUCT 
          Anzahl   : INT ; 
          Status   : ARRAY[0..2047] OF BYTE ;       // Bit0 : projektiert, Bit1: nicht in Funktion, Bit2: Störung
       END_STRUCT ;
    
       intern : STRUCT 
          Ablauf_Check   : INT := 0 ;       // Schrittkette für die Abfrage der Diagnose-Info's
       
          erster_Start     : BOOL := true ;   // Init-HM für die erste Erkennung, ob es PN oder PB nicht gibt
       
          Fn_x092_Aktiv  : BOOL ; 
          Fn_x292_Aktiv  : BOOL ; 
          Fn_x692_Aktiv  : BOOL ; 
          Fn_x094_Aktiv  : BOOL ; 
          Fn_x294_Aktiv  : BOOL ; 
          Fn_x694_Aktiv  : BOOL ; 
       END_STRUCT ;
          
       Abfrage_PB_Slaves : STRUCT 
             projektiert         : ARRAY[0..255] OF BOOL ; 
             in_Funktion         : ARRAY[0..255] OF BOOL ; 
             mit_Stoerung        : ARRAY[0..255] OF BOOL ; 
       END_STRUCT ;
          
       Abfrage_PN_Slaves : STRUCT 
             projektiert_Status  : WORD ;
             projektiert         : ARRAY[0..2047] OF BOOL ;
             in_Funktion_Status  : WORD ;
             in_Funktion         : ARRAY[0..2047] OF BOOL ; 
             mit_Stoerung_Status : WORD ;
             mit_Stoerung        : ARRAY[0..2047] OF BOOL ; 
       END_STRUCT ;
       at_Abfrage_PN_Slaves AT Abfrage_PN_Slaves : STRUCT 
             projektiert         : ARRAY[0..128] OF WORD ; 
             in_Funktion         : ARRAY[0..128] OF WORD ;  
             mit_Stoerung        : ARRAY[0..128] OF WORD ;  
       END_STRUCT ;
        
       Timer_ReTrigger        : SFB4 ;   
    END_VAR
    
    VAR_TEMP
       Fehler , i , j  : INT ; 
       Trigger_SFC51   : BOOL ; 
       
       mySZL_Header    : STRUCT
                    LenthDR : WORD ;
                    n_DR    : WORD ;
       END_STRUCT ;
       hm_ProfiBus_IO , hm_ProfiNet_IO : BOOL ; 
    END_VAR
    
    
    BEGIN
    
    IF (intern.Ablauf_Check <= 0) AND (OBxx_Trigger OR Timer_ReTrigger.Q OR intern.erster_Start) THEN 
       OBxx_Trigger := false ; 
       IF intern.erster_Start OR (PB_Slaves.Anzahl <> 0) THEN 
          intern.Ablauf_Check := 1 ;     // auch Profibus überprüfen
       ELSE 
          intern.Ablauf_Check := 7 ;     // nur Profinet überprüfen 
       END_IF ;
    END_IF ;
    Auswertung_aktiv := (intern.Ablauf_Check > 0) ;
    // ----------------
    Trigger_SFC51 := (intern.Ablauf_Check = 1) OR (intern.Ablauf_Check = 2) ;
    Fehler := RDSYSST (REQ := Trigger_SFC51
                      ,SZL_ID := w#16#0092               // Abfrage der projektierten ProfiBus-Stationen
                      ,INDEX := 1                        // Mastersystem-ID
                      ,BUSY := intern.Fn_x092_Aktiv
                      ,SZL_HEADER := mySZL_Header
                      ,DR := Abfrage_PB_Slaves.projektiert       // Ziel-Datenbereich für die abgefragten Daten
                      ) ;
    IF (intern.Ablauf_Check = 1) AND (intern.Fn_x092_Aktiv OR (Fehler = 0)) THEN intern.Ablauf_Check := 2 ; END_IF ;
    IF (intern.Ablauf_Check = 2) AND NOT intern.Fn_x092_Aktiv THEN intern.Ablauf_Check := 3 ; END_IF ;
                      
    Trigger_SFC51 := (intern.Ablauf_Check = 3) OR (intern.Ablauf_Check = 4) ;
    Fehler := RDSYSST (REQ := Trigger_SFC51
                      ,SZL_ID := w#16#0292               // Abfrage der nicht ausgefallenen ProfiBus-Stationen
                      ,INDEX := 1                        // Mastersystem-ID
                      ,BUSY := intern.Fn_x292_Aktiv
                      ,SZL_HEADER := mySZL_Header
                      ,DR := Abfrage_PB_Slaves.in_Funktion       // Ziel-Datenbereich für die abgefragten Daten
                      ) ;
           
    IF (intern.Ablauf_Check = 3) AND (intern.Fn_x292_Aktiv OR (Fehler = 0)) THEN intern.Ablauf_Check := 4 ; END_IF ;
    IF (intern.Ablauf_Check = 4) AND NOT intern.Fn_x292_Aktiv THEN intern.Ablauf_Check := 5 ; END_IF ;
                      
    Trigger_SFC51 := (intern.Ablauf_Check = 5) OR (intern.Ablauf_Check = 6) ;
    Fehler := RDSYSST (REQ := Trigger_SFC51
                      ,SZL_ID := w#16#0692               // Abfrage der gestörten ProfiBus-Stationen
                      ,INDEX := 1                        // Mastersystem-ID
                      ,BUSY := intern.Fn_x692_Aktiv
                      ,SZL_HEADER := mySZL_Header
                      ,DR := Abfrage_PB_Slaves.mit_Stoerung      // Ziel-Datenbereich für die abgefragten Daten
                      ) ;
           
    IF (intern.Ablauf_Check = 5) AND (intern.Fn_x692_Aktiv OR (Fehler = 0)) THEN intern.Ablauf_Check := 6 ; END_IF ;
    IF (intern.Ablauf_Check = 6) AND NOT intern.Fn_x692_Aktiv THEN intern.Ablauf_Check := 7 ; END_IF ;
                      
    // ----------------
    IF (intern.Ablauf_Check = 7) THEN  
       IF intern.erster_Start OR (PN_Slaves.Anzahl <> 0) THEN 
          intern.Ablauf_Check := 8 ;     // auch Profinet überprüfen
       ELSE 
          intern.Ablauf_Check := 14 ;     // Ende 
       END_IF ;
    END_IF ;
    Trigger_SFC51 := (intern.Ablauf_Check = 8) OR (intern.Ablauf_Check = 9) ;
    Fehler := RDSYSST (REQ := Trigger_SFC51
                      ,SZL_ID := w#16#0094               // Abfrage der projektierten ProfiNet-Stationen
                      ,INDEX := 100                      // Mastersystem-ID
                      ,BUSY := intern.Fn_x094_Aktiv
                      ,SZL_HEADER := mySZL_Header
                      ,DR := at_Abfrage_PN_Slaves.projektiert  // Ziel-Datenbereich für die abgefragten Daten
                      ) ;
    IF (intern.Ablauf_Check = 8) AND (intern.Fn_x094_Aktiv OR (Fehler = 0)) THEN intern.Ablauf_Check := 9 ; END_IF ;
    IF (intern.Ablauf_Check = 9) AND NOT intern.Fn_x094_Aktiv THEN intern.Ablauf_Check := 10 ; END_IF ;
                      
    Trigger_SFC51 := (intern.Ablauf_Check = 10) OR (intern.Ablauf_Check = 11) ;
    Fehler := RDSYSST (REQ := Trigger_SFC51
                      ,SZL_ID := w#16#0294               // Abfrage der nicht ausgefallenen ProfiNet-Stationen
                      ,INDEX := 100                      // Mastersystem-ID
                      ,BUSY := intern.Fn_x294_Aktiv
                      ,SZL_HEADER := mySZL_Header
                      ,DR := at_Abfrage_PN_Slaves.in_Funktion       // Ziel-Datenbereich für die abgefragten Daten
                      ) ;
           
    IF (intern.Ablauf_Check = 10) AND (intern.Fn_x294_Aktiv OR (Fehler = 0)) THEN intern.Ablauf_Check := 11 ; END_IF ;
    IF (intern.Ablauf_Check = 11) AND NOT intern.Fn_x294_Aktiv THEN intern.Ablauf_Check := 12 ; END_IF ;
                      
    Trigger_SFC51 := (intern.Ablauf_Check = 12) OR (intern.Ablauf_Check = 13) ;
    Fehler := RDSYSST (REQ := Trigger_SFC51
                      ,SZL_ID := w#16#0694               // Abfrage der gestörten ProfiNet-Stationen
                      ,INDEX := 100                      // Mastersystem-ID
                      ,BUSY := intern.Fn_x694_Aktiv
                      ,SZL_HEADER := mySZL_Header
                      ,DR := at_Abfrage_PN_Slaves.mit_Stoerung      // Ziel-Datenbereich für die abgefragten Daten
                      ) ;
           
    IF (intern.Ablauf_Check = 12) AND (intern.Fn_x694_Aktiv OR (Fehler = 0)) THEN intern.Ablauf_Check := 13 ; END_IF ;
    IF (intern.Ablauf_Check = 13) AND NOT intern.Fn_x694_Aktiv THEN intern.Ablauf_Check := 14 ; END_IF ;
                      
    // ----------------
    hm_ProfiBus_IO   := true ; 
    PB_Slaves.Anzahl := 0 ;
    FOR i := 0 TO 254 BY 1 DO
       j := i + 1 ;
       PB_Slaves.Status[j] := 0 ;
       IF Abfrage_PB_Slaves.projektiert[i] THEN 
          PB_Slaves.Status[j] := PB_Slaves.Status[j] OR 1 ; 
          PB_Slaves.Anzahl := PB_Slaves.Anzahl +1 ; 
          
          IF NOT Abfrage_PB_Slaves.in_Funktion[i] THEN PB_Slaves.Status[j] := PB_Slaves.Status[j] OR 2 ; hm_ProfiBus_IO := false ; END_IF ; 
          IF Abfrage_PB_Slaves.mit_Stoerung[i] THEN PB_Slaves.Status[j] := PB_Slaves.Status[j] OR 4 ; hm_ProfiBus_IO := false ; END_IF ;   
       END_IF ; 
    END_FOR ;    
    ProfiBus_vorh := (PB_Slaves.Anzahl > 0) ; 
    ProfiBus_IO   := ProfiBus_vorh AND hm_ProfiBus_IO ; 
    // ----------------
    hm_ProfiNet_IO   := true ; 
    PN_Slaves.Anzahl := 0 ;
    FOR i := 0 TO 2047 BY 1 DO
       PN_Slaves.Status[i] := 0 ;
       IF Abfrage_PN_Slaves.projektiert[i] THEN 
          PN_Slaves.Status[i] := PN_Slaves.Status[i] OR 1 ; 
          PN_Slaves.Anzahl := PN_Slaves.Anzahl +1 ;
          
          IF NOT Abfrage_PN_Slaves.in_Funktion[i] THEN PN_Slaves.Status[i] := PN_Slaves.Status[i] OR 2 ; hm_ProfiNet_IO := false ; END_IF ; 
          IF Abfrage_PN_Slaves.mit_Stoerung[i] THEN PN_Slaves.Status[i] := PN_Slaves.Status[i] OR 4 ; hm_ProfiNet_IO := false ; END_IF ;   
       END_IF ; 
    END_FOR ;    
    ProfiNet_vorh := (PN_Slaves.Anzahl > 0) ; 
    ProfiNet_IO   := ProfiNet_vorh AND hm_ProfiNet_IO ; 
    // ----------------
    IF (intern.Ablauf_Check >= 14) THEN 
        intern.erster_Start := false ;
        intern.Ablauf_Check := -2 ; 
    END_IF ;
    Timer_ReTrigger (IN:= (intern.Ablauf_Check = -2) ,
                     PT:= T#60s ) ;
    
    END_FUNCTION_BLOCK
    in den entsprechenden Fehler-OB's setze ich ein Trigger-Bit für diesen Baustein, der im OB1 aufgerufen wird. Der Baustein nimmt dann das Trigger-Bit wieder zurück.
    Die ermittelten Info's werden von mir in der Hauptsache in der Visu ausgewertet / angezeigt. Hier verwende ich dann die Instanz des FB direkt.

    Gruß
    Larry

  2. Folgende 11 Benutzer sagen Danke zu Larry Laffer für den nützlichen Beitrag:

    Blockmove (27.06.2012),erzteufele (29.10.2015),LargoD (02.11.2012),Manfred Stangl (28.06.2012),Matze001 (28.06.2012),netmaster (05.11.2012),Onkel Dagobert (02.07.2012),PN/DP (27.06.2012),Ralle (27.06.2012),rostiger Nagel (27.06.2012),vollmi (06.02.2014)

  3. #12
    Matze001 ist offline Erfahrener Benutzer
    Themenstarter
    Registriert seit
    11.12.2009
    Beiträge
    2.115
    Danke
    388
    Erhielt 390 Danke für 271 Beiträge

    Standard

    Rostiger Nagel:

    Dein Ansatz ist genial, leider nicht für PN geeignet!

    Larry:

    Der Baustein ist super, ich habe ihn grad mal mit Profibus getestet, ich denke mit dem PN wird es auch funktionieren.
    Das du ihn ins Forum stellst, heißt man darf ihn verwenden?

    Grüße

    Marcel

  4. #13
    Registriert seit
    22.03.2007
    Ort
    Detmold (im Lipperland)
    Beiträge
    11.726
    Danke
    398
    Erhielt 2.402 Danke für 2.001 Beiträge

    Standard

    Zitat Zitat von Matze001 Beitrag anzeigen
    Der Baustein ist super, ich habe ihn grad mal mit Profibus getestet, ich denke mit dem PN wird es auch funktionieren.
    Er funktioniert grundsätzlich - ich habe nur noch nicht alle Eventualitäten getestet ...

    Zitat Zitat von Matze001 Beitrag anzeigen
    Das du ihn ins Forum stellst, heißt man darf ihn verwenden?
    Die Frage war doch mehr rethorisch - oder ?
    Selbstverständlich kannst du ihn verwenden - falls du noch einen Fehler finden solltest lass es mich aber bitte wissen ...

    Gruß
    Larry

  5. #14
    Matze001 ist offline Erfahrener Benutzer
    Themenstarter
    Registriert seit
    11.12.2009
    Beiträge
    2.115
    Danke
    388
    Erhielt 390 Danke für 271 Beiträge

    Standard

    Die frage war natürlich rethorisch, aber fragen tue ich trotzdem... ich finde es gehört sich einfach

    Ich habe alle meine Eventualitäten gecheckt, und muss sagen er tut genau das was er soll!

    Für die Zukunft kommt vielleicht noch etwas, aber vielleicht kannst du mir da weiterhelfen...

    Es gibt z.B. in der Hardwareconfig die Info "Einspeisemodul gestört" als Detailmeldung wenn man auf einen Busteilnehmer klickt, kann ich die auch irgendwie mit dem SFC51 auslesen und verarbeiten?
    Das ist aber eher ein Nice-To-Have. Das man erstmal sieht das die Baugruppe gestört ist reicht mit für den Anfang!

    Oh eine Frage fällt mir noch ein:

    Die Profibusdiagnose funktioniert "live", stecker ziehen und stecken sehe ich direkt im dem entsprechenden Byte. Beim PN nur nach dem TRIGGER_OBxx (und vllt. noch nach dem TIMER?).
    Warum ist das so? Und warum ist der Timer auf t#60s eingestellt? Sollte man ihn nicht niedriger stellen?

    Grüße

    Marcel

  6. #15
    Registriert seit
    22.06.2009
    Ort
    Sassnitz
    Beiträge
    11.192
    Danke
    925
    Erhielt 3.292 Danke für 2.661 Beiträge

    Standard

    Zitat Zitat von rostiger Nagel Beitrag anzeigen
    Wenn dir der SFC51 zu mächtig erscheint, kannst du auch mit dem SFC12 nach dem hochlauf, den
    aktuellen Zustand abfragen, indem du den Mode auf "0" setzt. Wenn RetVal = "1" ist der Teilnehmer
    aktiviert, bei "2" ist er deaktiviert.
    Das sagt leider nichts darüber aus, ob der Teilnehmer vorhanden ist oder nicht. Sondern nur, ob er im Mastersystem aktiviert oder deaktiviert ist.
    Die nächste Falle: ist ein PB-Teilnehmer deaktiviert, dann erscheint er nicht mehr als "gestört", was aber nicht bedeutet, daß er OK wäre ...

    Harald
    Es ist immer wieder überraschend, wie etwas plötzlich funktioniert, sobald man alles richtig macht.

    FAQ: Linkliste SIMATIC-Kommunikation über Ethernet

  7. #16
    Registriert seit
    22.03.2007
    Ort
    Detmold (im Lipperland)
    Beiträge
    11.726
    Danke
    398
    Erhielt 2.402 Danke für 2.001 Beiträge

    Standard

    Zitat Zitat von Matze001 Beitrag anzeigen
    Es gibt z.B. in der Hardwareconfig die Info "Einspeisemodul gestört" als Detailmeldung wenn man auf einen Busteilnehmer klickt, kann ich die auch irgendwie mit dem SFC51 auslesen und verarbeiten?
    Das ist aber eher ein Nice-To-Have. Das man erstmal sieht das die Baugruppe gestört ist reicht mit für den Anfang!
    Das schaue ich mir mal an ...

    Zitat Zitat von Matze001 Beitrag anzeigen
    Die Profibusdiagnose funktioniert "live", stecker ziehen und stecken sehe ich direkt im dem entsprechenden Byte. Beim PN nur nach dem TRIGGER_OBxx (und vllt. noch nach dem TIMER?).
    Warum ist das so? Und warum ist der Timer auf t#60s eingestellt? Sollte man ihn nicht niedriger stellen?
    Also den Trigger setze ich im OB100, OB82, OB83, OB86, OB??? (weiß ich gerade nicht - 121 ??) - es kann m.E. nur damit etwas zu tun haben.
    Der Refresh-Timer ist eigentlich mehr als eine Art Zwischen-Aktualisierung da drin (falls man mal ein Event doch nicht mitbekommen hat). Den solltest du nicht zu niedrig stellen, da der FB ja doch eine gewisse Belastung für das zyklische Programm ist - so hatte ich es jedenfalls gedacht.

    Gruß
    Larry

  8. #17
    Matze001 ist offline Erfahrener Benutzer
    Themenstarter
    Registriert seit
    11.12.2009
    Beiträge
    2.115
    Danke
    388
    Erhielt 390 Danke für 271 Beiträge

    Standard

    Du musst dir wegen mir jetzt keine Aufgaben aufhalsen, vielleicht schau ich selbst auch mal.
    Bisher ist es egal, deine drei Signale sind mehr als ausreichend!

    Also sollte das Programm nur ablaufen wenn der Trigger gesetzt wird, so habe ich das auch rausgelesen.
    Witzigerweise wird der DB für Profibus sofort aktualisiert, ich habe an dem Trigger nen Merker stehen der im Programm nicht verwendet wird. (Testweise) Bei Profinet tut es nur wenn ich den Trigger auf TRUE setze.

    Ob der Baustein einmal die Minute oder alle 10 Sekunden meinen Zyklus beeinflusst sollte doch eigentlich keine Rolle spielen, außer er läuft A-Zyklisch...

    Grüße

    Marcel

  9. #18
    Registriert seit
    22.03.2007
    Ort
    Detmold (im Lipperland)
    Beiträge
    11.726
    Danke
    398
    Erhielt 2.402 Danke für 2.001 Beiträge

    Standard

    Hallo Marcel,
    für die Funktion des Bausteins ist ja nur der Trigger relevant. Den setze ich in den genannten OB's (der letzte fehlende war bei mir der OB122). Hast du irgendeinen Fehler so wird der zuständige OB aufgerufen und dort der Trigger-Merker gesetzt (bei mir z.B. : UN M7.7 S M7.7). Der ist an dem im OB1 aufgerufenen FB126 dann der Trigger. Die Out-Info's des Bausteins verwende ich ggf. im weiteren SPS-Programm.

    Warum du den PB viel schneller aktualisiert bekommst als den PN kann ich so nicht beurteilen. Der Baustein hat aber auch eine gewisse Laufzeit (über ettliche SPS-Zyklen, da der SFC51 ja asynchron arbeitet).

    Für mich ist der Sinn dieses Bausteins, in der Visu auf einen Blick die Verfügbarkeit der Busteilnehmer darzustellen (das ist schon das eine oder andere Mal für die Instandhalter ein ganz gutes Feature gewesen). Bei der Visu kommt es aber auf 1 Sek. mehr oder weniger für die Anzeige nicht so an. Deswegen ist mir das vielleicht auch selbst noch nicht aufgefallen ...

    Das mit dem "Arbeit aufhalsen" ist nicht so ein Thema. Für mich ist der FB ein Standard-Baustein, der in allen (zukünftigen) Projekten Anwendung finden soll. Manchmal fallen einem bei so etwas aber dann Dinge, die man vielleicht auch noch gebrauchen kann, nicht sofort auf. Deine Rand-Note hat für mich im Augenblick aber auch keine Prio-1 - aber schauen werde ich - interessiert mich ja auch ...

    Gruß
    Larry

  10. #19
    Matze001 ist offline Erfahrener Benutzer
    Themenstarter
    Registriert seit
    11.12.2009
    Beiträge
    2.115
    Danke
    388
    Erhielt 390 Danke für 271 Beiträge

    Standard

    Okay vielleicht verstehst du nicht ganz was ich meine

    Profibus:

    An eingang Trigger_OBxx steht IMMER FALSE. Trotzdem werden die Daten der Profibusteilnehmer "live" * aktualisiert (sollte ja laut deiner Aussage nicht passieren)

    * Live = quasi in dem Moment wo ich den Stecker ziehe oder stecke, also spielt der TIMER REFRESH keine Rolle dabei

    Beim Profinet wird erst mit dem Trigger oder dem Timer aktualisiert, so wie von dir beschrieben.

    Grüße

    Marcel

  11. #20
    Registriert seit
    22.03.2007
    Ort
    Detmold (im Lipperland)
    Beiträge
    11.726
    Danke
    398
    Erhielt 2.402 Danke für 2.001 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Lieber Marcel,
    in meinem Script wird der "Trigger_OB", sofern der FB ihn erkannt hat, sofort gelöscht und die Schrittkette gestartet. Das bedeutet dann, dass man selbst mit ganz viel gutem Willen niemals den Trigger "1" sehen wird (es sei denn die Zykluszeit der SPS liegt im Sekundenbereich).
    Das einlesen der PB-Liste umfasst nur einen Bereich von 256 Bytes - der vom PN 2048 - ich denke mal, dass das den Unterschied macht - habe es aber bisher auch noch nicht gecheckt. Aber ... wie lange ist denn "Auswertung_Aktiv" bei dir =1 ? Das sollte dann ein ganz gutes Indiez sein ...

    Grüße
    Larry

Ähnliche Themen

  1. ProfiNet/ProfiBus Diagnose einfach
    Von kliebisch.m im Forum Simatic
    Antworten: 6
    Letzter Beitrag: 29.12.2011, 10:13
  2. Profinet Teilnehmer Diagnose
    Von GobotheHero im Forum Simatic
    Antworten: 3
    Letzter Beitrag: 11.08.2010, 17:31
  3. Diagnose Profinet-Teilnehmer anhand der IP
    Von Hawkster im Forum Simatic
    Antworten: 0
    Letzter Beitrag: 08.02.2010, 16:39
  4. Auswertung Profinet Teilnehmer
    Von Ensiferum im Forum Simatic
    Antworten: 7
    Letzter Beitrag: 27.05.2009, 22:51
  5. Hilfe; ProfiNet/ profiBus- Diagnose....
    Von Cliff im Forum Feldbusse
    Antworten: 12
    Letzter Beitrag: 19.02.2009, 18:53

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •