Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Ergebnis 1 bis 2 von 2

Thema: WinCC7 Prüfen ob Prozess läuft

  1. #1
    Registriert seit
    07.09.2005
    Ort
    MOS
    Beiträge
    156
    Danke
    22
    Erhielt 26 Danke für 17 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Hallo,
    was ist die beste Möglichkeit um in der WinCC7 Visu anzuzeigen, ob ein Prozess (eine normale exe, in der Taskleiste sichtbar) noch läuft.

    Grüße
    David
    Zitieren Zitieren WinCC7 Prüfen ob Prozess läuft  

  2. #2
    Registriert seit
    30.03.2005
    Beiträge
    2.096
    Danke
    0
    Erhielt 673 Danke für 541 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Hallo David,

    das folgende VBScript prüft, ob auf dem Computer der Prozess notepad.exe läuft.

    Das VBScript ist in WinCC nicht getestet.

    Code:
    ' =================================================
    ' Name: Prozess.vbs
    ' Autor: Kai
    ' Version: 1.0
    ' Beschreibung: Das VBScript prüft, ob auf dem 
    ' Computer der Prozess notepad.exe läuft.
    ' =================================================
     
    Option Explicit
     
    Dim objWMIService
    Dim colProcess
    Dim objProcess
     
    Const strComputer =  "."
    Const strProcess = "notepad.exe"
     
    Set objWMIService = GetObject("winmgmts:" & _
    "{impersonationLevel=Impersonate}!\\" & strComputer & "\root\cimv2")
     
    Set colProcess = objWMIService.ExecQuery("Select * from Win32_Process")
     
    For Each objProcess In colProcess
        If objProcess.Name = strProcess Then 
            WScript.Echo("Prozess " & strProcess & " läuft")
            WScript.Quit
        End If
    Next
     
    WScript.Echo("Prozess " & strProcess & " läuft nicht")
    In WinCC sollte anstelle der Textausgabe mit der WScript.Echo-Methode eine Variable (Tag) mit der Write-Methode
    geschrieben werden (nicht getestet).

    Code:
    Dim objTag
     
    Set objTag = HMIRuntime.Tags("Tag")
     
    For Each objProcess In colProcess
        If objProcess.Name = strProcess Then 
            objTag.Write 1
            WScript.Quit
        End If
    Next
     
    objTag.Write 0
    Oder

    Code:
    For Each objProcess In colProcess
        If objProcess.Name = strProcess Then 
            HMIRuntime.Tags("Tag").Write 1
            WScript.Quit
        End If
    Next
     
    HMIRuntime.Tags("Tag").Write 0
    Gruß Kai

  3. Folgender Benutzer sagt Danke zu Kai für den nützlichen Beitrag:

    LuZi (25.08.2016)

Ähnliche Themen

  1. WinCC7 PictureTreeManager
    Von repök im Forum HMI
    Antworten: 2
    Letzter Beitrag: 16.09.2011, 09:40
  2. Antworten: 3
    Letzter Beitrag: 22.08.2011, 20:55
  3. in laufenden Prozess eingreifen
    Von friesen im Forum CODESYS und IEC61131
    Antworten: 0
    Letzter Beitrag: 16.09.2010, 09:58
  4. Prozess Abbild
    Von RobiHerb im Forum Programmierstrategien
    Antworten: 1
    Letzter Beitrag: 14.04.2010, 10:30
  5. Prozess-Teilprozessabbild
    Von johnij im Forum Simatic
    Antworten: 1
    Letzter Beitrag: 25.10.2007, 13:57

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •