// Schrittkette
SET
L Z 10
SPL STR
SPA S000
SPA S001
SPA S002
SPA S003
SPA S004
SPA S005
SPA S006
SPA S007
SPA S008
SPA CLR
STR: SPA KEND
// Schritt 0 - warte auf Eingabe;
S000: L "CodeHSK".CodeTasten
T "CodeHSK".Code1st
U "CodeHSK".Taste_CLR
SPB CLR
U "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 1 - Eingabe auf 1.Codestelle schreiben;
S001: L "CodeHSK".Code1st
T "CodeHSK".Code12
T "CodeHSK".CodeAnzeige
UN "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 2 - warte auf Eingabe;
S002: L "CodeHSK".CodeTasten
T "CodeHSK".Code2st
U "CodeHSK".Taste_CLR
SPB CLR
U "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 3 - Eingabe auf 2.Codestelle schreiben;
S003: L "CodeHSK".Code1st
L 10
*I
L "CodeHSK".Code2st
+I
T "CodeHSK".CodeAnzeige
T "CodeHSK".Code12
UN "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 4 - warte auf Eingabe;
S004: L "CodeHSK".CodeTasten
T "CodeHSK".Code3st
U "CodeHSK".Taste_CLR
SPB CLR
U "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 5 - Eingabe auf 3.Codestelle schreiben;
S005: L "CodeHSK".Code12
L 10
*I
L "CodeHSK".Code3st
+I
T "CodeHSK".CodeAnzeige
T "CodeHSK".Code123
UN "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 6 - warte auf Eingabe;
S006: L "CodeHSK".CodeTasten
T "CodeHSK".Code4st
U "CodeHSK".Taste_CLR
SPB CLR
U "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 7 - Eingabe auf 4.Codestelle schreiben;
S007: L "CodeHSK".Code123
L 10
*I
L "CodeHSK".Code4st
+I
T "CodeHSK".CodeAnzeige
UN "CodeHSK".Taste_gedrueckt
ZV Z 10
SPA KEND
// Schritt 8 - IstCode mit SollCode vergleichen
S008: L "CodeHSK".CodeAnzeige //entspricht IST-Code
L "CodeHSK".CodeSoll //entspricht SOLL-Code
==I
S "CodeHSK".CodeOK
R Z 10
L "CodeHSK".CodeAnzeige //entspricht IST-Code
L "CodeHSK".CodeSoll //entspricht SOLL-Code
<>I
ZV Z 10
SPA KEND
// Schritt CLR zum Löschen aller Eingaben
CLR: L 0 //alle DBW ruecksetzen
T "CodeHSK".Code1st
T "CodeHSK".Code2st
T "CodeHSK".Code3st
T "CodeHSK".Code4st
T "CodeHSK".CodeAnzeige
T "CodeHSK".Code12
T "CodeHSK".Code123
U "CodeHSK".Taste_CLR
R Z 10
R "CodeHSK".CodeOK //Code-ok rücksetzen
SPA KEND
KEND: NOP 0
Bookmarks