Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Ergebnis 1 bis 2 von 2

Thema: SCL Beispiel für ANY Pointer Bearbeitung

  1. #1
    Registriert seit
    13.08.2008
    Beiträge
    35
    Danke
    0
    Erhielt 9 Danke für 7 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Vielleicht nützt es dem einen oder anderem. Hatte das mal kodiert um mit SCL zu arbeiten.

    Code:
    //------------------------------------------------------------------------------------------------------
    //
    //  Beispiel FC: zeigt wie man ein ANY Pointer dynamisiert bevor man ihn als //  Parameter dem SFC20 übergibt.
    //
    //------------------------------------------------------------------------------------------------------
    
    FUNCTION FC200 :VOID
    VAR_TEMP
        // Temporäre variable
            
        SOURCE:ANY;  // Symbolischer Name des ANY Pointers
        VON AT SOURCE: STRUCT  // Mit dem  AT Befehl wird der gleiche Bereich in einer anderen Form définiert
           ID  : WORD;  // ID für ANY (1002 hex = es wird mit Bytes gearbeitet)
           NBR :INT;    // Anzahl Daten
           DBN : INT;   // DB der im ANY Pointer benutzt wird ANY
           PTR : DWORD; // Pointer Doppelwort um den Angfang des Datenbereichs und den Datentyp zu definieren (84hex = DB Datentyp)
        END_STRUCT;
           
                  
            
        DESTIN:ANY;
        NACH AT DESTIN: STRUCT
           ID  : WORD;
           NBR : INT;
           DBN : INT;
           PTR : DWORD;
        END_STRUCT;
            
        ORIG : INT;
        SFC_Err:INT;  // RETVAL des SFC
    
    END_VAR
    
        // Befehle
        //__________________________
        
        ORIG := 10; // Beispiel: man will bei DBX10.0 anfangen
        
        // Aufbauen des ANY Pointers der Quelle (VON) (z.B. P#DB150.DBX10.0 BYTE 100)
        
        VON.ID  := 16#1002;  // ID 10 et 02 um mit Bytes zu arbeiten
        VON.NBR := 100;  // entspricht BYTE 100. Könnte eine Variable sein.
        VON.DBN := 150; // DB 150
        VON.PTR := INT_TO_DWORD (8*ORIG) OR 16#8400_0000;  // Pointer zeigt zuf Bit, deshalb 8*Byte Nummer
        
        // Aufbauen des ANY Pointers des Ziels (NACH)(P#DB200.DBX10.0 BYTE 100)
        NACH.ID   := 16#1002;
        NACH.NBR  := 100;
        NACH.DBN  := 200;
        NACH.PTR:= INT_TO_DWORD (8*ORIG) OR 16#8400_0000;
    
      
       
        
        
        // Aufruf des SFC 20
        SFC_Err := BLKMOV(SRCBLK := SOURCE // IN: ANY
               ,DSTBLK := DESTIN // OUT: ANY
               ); // INT
          
       
       
       
       END_FUNCTION
    Zitieren Zitieren SCL Beispiel für ANY Pointer Bearbeitung  

  2. Folgende 3 Benutzer sagen Danke zu clweb für den nützlichen Beitrag:

    /*Matthias*/ (18.08.2008),Olimoli50 (23.08.2016),onikos (18.07.2012)

  3. #2
    Registriert seit
    27.05.2004
    Ort
    Thüringen/Berlin
    Beiträge
    12.263
    Danke
    537
    Erhielt 2.708 Danke für 1.957 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Ja, nette Zusammenfassung. Das Bemühen der Suche im Forum fördert dazu etliches zu Tage, z.Bsp. auch dieses:

    http://www.sps-forum.de/showthread.p...AT+Pointer+Any

    Vielleicht nimmt der Volker ja mal eine SCL-ANY-Variante in die Any-FAQ auf !
    Gruß
    Ralle

    ... there\'re 10 kinds of people ... those who understand binaries and those who don\'t …
    and the third kinds of people … those who love TIA-Portal

Ähnliche Themen

  1. C-Norm für die Bearbeitung von Gläser
    Von Wignatz im Forum Maschinensicherheit - Normen und Richtlinien
    Antworten: 1
    Letzter Beitrag: 14.07.2011, 08:11
  2. Pointer praktisches Beispiel??
    Von Backdoor im Forum Simatic
    Antworten: 5
    Letzter Beitrag: 30.04.2010, 08:49
  3. Rockwell - Bearbeitung von Tags
    Von georg_demmler im Forum Sonstige Steuerungen
    Antworten: 3
    Letzter Beitrag: 21.04.2010, 18:21
  4. String-Bearbeitung
    Von Anna im Forum Simatic
    Antworten: 24
    Letzter Beitrag: 05.05.2006, 06:16
  5. Indirekete Bearbeitung S5 nach S7
    Von Marc_3 im Forum Simatic
    Antworten: 15
    Letzter Beitrag: 13.07.2004, 19:58

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •