Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Ergebnis 1 bis 5 von 5

Thema: Fehlerauswertung Analogeingang

  1. #1
    Registriert seit
    23.02.2007
    Ort
    Hamburg
    Beiträge
    695
    Danke
    198
    Erhielt 84 Danke für 74 Beiträge

    Frage


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Moin,

    Habe eine Anlage mit mehreren 4-20mA und einigen PT100.
    Diese Werte lese ich ein, wandel sie entsprechend des Messbereihcs um und überwache sie auf die entsprechenden Grenzwerte. (Ohne FC105)

    Nun muss ich aber noch sicherstellen das auch bei z.B. Drahtbruch eine Fehlermeldung "Sensorfehler" kommt. Wie kann ich das am einfachsten/besten machen?

    Selber überprüfen ob der ADC Wert außerhalb von 0 - 27648 liegt?

    oder aber

    Bietet Siemens für jeden Kanal ein eigenes Fehlerbit?

    (Bei Schneider gibt es z.B. für einen Analogeingang "%IW.0.4.1" immer ein Kanalfehlerbit "%I.0.4.1.ERR", welches bei Messbereihchsunter- und überschreitung true wird.)


    Danke, eYe
    Siemens: Step7, WinCC Flexible, Logo
    Schneider: PL7, Unity Pro, Vijeo Look, Vijeo Designer, XBTL1000, Premium, M340, Twido, Zelio
    Moeller: Galileo, EASY
    B&R: Automation Studio 3.0
    Zitieren Zitieren Fehlerauswertung Analogeingang  

  2. #2
    Registriert seit
    20.06.2003
    Ort
    Sauerland.NRW.Deutschland
    Beiträge
    4.866
    Danke
    78
    Erhielt 806 Danke für 549 Beiträge

    Standard

    schau mal in die hw-config in den eigenschaften deiner ai-baugruppe.
    dort gibt es einen diagnosealarm. mit F1 gibts nähere infos
    .
    mfg Volker .......... .. alles wird gut ..

    =>Meine Homepage .. direkt zum Download

    Meine Definition von TIA: Total Inakzeptable Applikation

  3. Folgender Benutzer sagt Danke zu volker für den nützlichen Beitrag:

    eYe (19.03.2009)

  4. #3
    Registriert seit
    01.01.2008
    Beiträge
    104
    Danke
    43
    Erhielt 21 Danke für 19 Beiträge

    Standard

    Hallo,

    ich hab das vor kurzem mit einem AI von einer ET200S gemacht. (4-20mA)

    Wie Volker sagte in der Hardware Config den Haken "Diagnose" bei der AI setzen, danach kannst du im Programm diesen auf Drahtbuch überprüfen.


    Einfach das entsprechende PEW auf gleich 32767 vergleichen, wenn der Vergleich TRUE ist, dann hast du einen Drahtbruch. Funktioniert prima.

    Gruß

    Da_Basco
    Gruß
    Da_Basco


    Ich kann über das Wasser laufen,
    weil ich weiß wo die Steine sind... (Rainald Grebe)

  5. Folgender Benutzer sagt Danke zu Da_Basco für den nützlichen Beitrag:

    eYe (19.03.2009)

  6. #4
    Registriert seit
    19.12.2006
    Beiträge
    185
    Danke
    25
    Erhielt 26 Danke für 21 Beiträge

    Standard

    Hallo,

    bei 4...20mA Signalen sinkt das PEW unter 4mA unter 0.
    Man kann sich einen Grenzwert in mA ausrechnen ab wann eine Meldung erfolgen soll.

    Hier mal ein Beispiel (SCL inkl. Skalierung):

    Code:
    //Funktion zum Skalieren von 4...20mA Signalen
    //inkl. Drahtbruchauswertung
    FUNCTION FC205 : VOID
    
    // Bausteinparameter
    VAR_INPUT
       IN:INT;    //PEW 
       HI_LIM: REAL; //Obergrenze
       LO_LIM: REAL; //Untergrenze
       FAIL_VAL: REAL; //Fehlerstrom
    END_VAR
    
    VAR_OUTPUT
       OUT:REAL;  //skalierter Ausgang
       FAIL:BOOL; //Fehlerausgang 
    END_VAR
    
    
    VAR_TEMP
        // temporäre Variablen
        temp: REAL;
        
        
    END_VAR
        
        //Skalierung
        //********************************************************
        temp :=((IN/27648.0)*(HI_LIM-LO_LIM))+LO_LIM;
         
        //Ergebnis zwischen LO_LIM und HI_LIM ??? 
        IF ((temp>LO_LIM) & (temp<HI_LIM))Then
        OUT:=temp;
        END_IF;
         
        //Sonst an LO_LIM bzw. HI_LIM binden 
        IF (temp<LO_LIM) THEN        
            OUT:=LO_LIM; 
        ELSIF (temp>HI_LIM)THEN
            OUT:=HI_LIM;
           
        END_IF;
        
     
     
        //Drahtbruchauswertung
        //********************************************************
        FAIL:=FALSE; //Drahtbruchauswertung n.o.k.
        IF ((FAIL_VAL<3.9)&(FAIL_VAL>0.0)) THEN
            temp:= -((4.0 - FAIL_VAL)/0.00058); //4mA - Fehlerstrom/0.00058
            //Fehlerausgabe  
            IF (temp < IN) THEN
            FAIL:=TRUE; //Drahtbruchauswertung o.k.
            END_IF;
        END_IF;
    
                           
     END_FUNCTION
    oder AWL

    Code:
    FUNCTION FC 106 : VOID
    TITLE =
    VERSION : 0.1
    
    
    VAR_INPUT
      IN : INT ;    
      HI_LIM : REAL ;    
      LO_LIM : REAL ;    
      FAIL_VAL : REAL ;    
    END_VAR
    VAR_OUTPUT
      OUT : REAL ;    
      FAIL : BOOL ;    
    END_VAR
    VAR_TEMP
      temp_1 : REAL ;    
    END_VAR
    BEGIN
    NETWORK
    TITLE =Scale
    //PEW zwischen LO_LIM und HI_LIM skalieren
    //Nach Unterschreitung von LO_LIM => an LO_LIM binden
    //Nach Überschreitung von HI_LIM  => an HI_LIM binden
    //Skalieren
          L     #IN; //PEW
          ITD   ; //nach 32 BIT
          DTR   ; //nach Real
          L     2.764800e+004; //durch Konstante teilen
          /R    ; 
          T     #temp_1; //speichern
    
          L     #HI_LIM; //HI_LIM - LO_LIM 
          L     #LO_LIM; 
          -R    ; 
    
          L     #temp_1; //mit Speicher Multiplizieren
          *R    ; 
          L     #LO_LIM; //mit LO_LIM Addieren
          +R    ; 
          T     #OUT; //Ergebnis
          L     #LO_LIM; 
          <R    ; //mit LO_LIM Vergleichen
          SPBN  M001; 
          L     #LO_LIM; //Ergebnis an LO_LIM binden
          T     #OUT; 
          L     #HI_LIM; 
          SPA   M002; 
    M001: TAK   ; 
          L     #HI_LIM; 
          >R    ; //mit HI_LIM Vergeleichen
          SPBN  M002; 
          L     #HI_LIM; //Ergebnis an HI_LIM binden
          T     #OUT; 
    
    M002: NOP   0; //Ergebnis größer LO_LIM
    
    NETWORK
    TITLE =Drahtbruch
    //Info:
    //Unter 4mA sinkt das PEW unter Wert=0
    //1 Digit = 0,00058mA, d.h. 3,9995mA entspricht -1 am PEW
    //
    //
    //Drahtbruchauswertung nur wenn Fehlerstrom (FAIL_VAL) zwischen 0...3,9mA
    //FAIL_VAL < 3,9mA
          L     #FAIL_VAL; 
          L     3.900000e+000; 
          <R    ; 
          SPBN  ende; 
    
    //FAIL_VAL > 0mA
          L     #FAIL_VAL; 
          L     0.000000e+000; 
          >R    ; 
          SPBN  ende; 
    
    NETWORK
    TITLE =Drahtbruchauswertung
    
          L     4.000000e+000; //Differenz ermitteln 
          L     #FAIL_VAL; 
          -R    ; 
          L     5.800000e-004; //Differenz/0,00058mA
          /R    ; 
          TRUNC ; //In Integer wandeln
          L     0; //Vorzeichen wechseln
          TAK   ; 
          -I    ; 
          L     #IN; //Ist PEW < grenze ?
          <I    ; 
          =     #FAIL; 
    NETWORK
    TITLE =Bausteinende
    
    ende: NOP   0; 
    
    
    END_FUNCTION
    Du kannst bei beiden Beispielen an IN FAIL_VAL ein Real angeben.
    Der Wert steht für die Drahtbrucherkennung in mA. Z.B. 3.6 -> sinkt der Messwert unter 3.6mA wird ein Fehler ausgewertet.

    Die stromgenaue Auswertung funktioniert nur bis nur bis 1,185mA, da das PEW unter 1,185mA auf –32768 sinkt.

    Die AWL Geschichte ist im Ergebnis natürlich kompakter.

    Diagnosealarm wird nicht bei jeder analog Baugruppe angeboten.

    Gruß
    Geändert von mkd (20.03.2009 um 10:25 Uhr)

  7. Folgende 3 Benutzer sagen Danke zu mkd für den nützlichen Beitrag:

    M-Arens (27.07.2011),McMeta (11.05.2009),SPS_S5_S7 (27.07.2011)

  8. #5
    Registriert seit
    02.09.2004
    Beiträge
    108
    Danke
    12
    Erhielt 0 Danke für 0 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Kann mir einer sagen wie ich das für einen PT100 anpassen muß?
    Gruß M-Arens

Ähnliche Themen

  1. S5 Analogeingang
    Von mariob im Forum Simatic
    Antworten: 6
    Letzter Beitrag: 26.04.2011, 21:16
  2. Fehlerauswertung im OB121
    Von Bensen83 im Forum Simatic
    Antworten: 10
    Letzter Beitrag: 18.02.2010, 08:49
  3. Fehlerauswertung Skalierungsblock FC 105
    Von Christoph T. im Forum Simatic
    Antworten: 6
    Letzter Beitrag: 21.12.2009, 09:56
  4. Siwarex U Fehlerauswertung
    Von ukofumo im Forum Simatic
    Antworten: 4
    Letzter Beitrag: 02.08.2009, 23:06
  5. Antworten: 8
    Letzter Beitrag: 24.04.2006, 11:27

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •