Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Seite 2 von 3 ErsteErste 123 LetzteLetzte
Ergebnis 11 bis 20 von 24

Thema: Drehzahlregelung über Analogausgang S7/300

  1. #11
    Registriert seit
    14.10.2008
    Ort
    Palz
    Beiträge
    89
    Danke
    9
    Erhielt 12 Danke für 9 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Zitat Zitat von bike Beitrag anzeigen
    Also das PAE wird am Anfang des OB 1 aktualisiert.
    Ja, du musst das PEW laden, doch glaub ich nicht, dass das so schnell mit einer S7/300 geht.
    bike
    Sry
    muß den Baustein nochmal überarbeiten.
    Ich habe das PEW noch nicht eingebunden

  2. #12
    Registriert seit
    14.10.2008
    Ort
    Palz
    Beiträge
    89
    Danke
    9
    Erhielt 12 Danke für 9 Beiträge

    Standard

    So - jetzt aber
    Angehängte Dateien Angehängte Dateien

  3. #13
    Registriert seit
    15.06.2008
    Beiträge
    119
    Danke
    19
    Erhielt 24 Danke für 19 Beiträge

    Standard

    Zitat Zitat von The Blue Beitrag anzeigen
    Über Feedback würde ich mich freuen
    Noch lachst Du!

    Wir fangen oben an und arbeiten uns langsam durch:

    Bausteinbeschreibung - nicht vorhanden!
    Symbolik - uneindeutig!
    Kommentare - Fehlanzeige!
    Struktur - nicht erkennbar!
    Zeiten - fix, Mehrwert des Bausteins nicht gegeben!

    Hast fein gemacht, gefällt mir - 6 setzen!

    Ich kriegs kotzen!
    Zitieren Zitieren Wenn Feedback explizit gewünscht wird, bitte schön!  

  4. #14
    Registriert seit
    14.10.2008
    Ort
    Palz
    Beiträge
    89
    Danke
    9
    Erhielt 12 Danke für 9 Beiträge

    Standard

    Zitat Zitat von forendiva Beitrag anzeigen
    Noch lachst Du!

    Wir fangen oben an und arbeiten uns langsam durch:

    Bausteinbeschreibung - nicht vorhanden!
    Symbolik - uneindeutig!
    Kommentare - Fehlanzeige!
    Struktur - nicht erkennbar!
    Zeiten - fix, Mehrwert des Bausteins nicht gegeben!

    Hast fein gemacht, gefällt mir - 6 setzen!

    Ich kriegs kotzen!
    Wie, Bausteinbeschreibung??
    Hab den Baustein doch mit "Dreh_Zahl_Richtung"
    genannt.
    Kann ich für einen Baustein eine richtige Beschreibung schreiben??
    Wenn ja - wie??

    OK die Schnittstelle hätte ich noch Kommentieren können...

    Aber im Baustein habe ich die Netzwerke so benannt,
    das ich ein zusätzliches Kommentar nicht notwendig fand!?

    Keine Struktur!?
    Wieso meinst Du??

    Die Zeiten sind fix - ja
    weil ich es nicht notwendig finde
    diese zu ändern
    Die Zeit an der Stillstandserkennung TOF
    ist nur, damit irgendwann auch mal gewährleistet ist,
    das der Ausgang "A_umschaltfreigabe" für eine Drehrichtungsänderung
    1 wird und der Drehzahlpuffer gelöscht wird
    Die Zeit TON ist dafür, das der Ausgegebene Wert Ablesbar ist
    wenn ich auf der Anzeige nur 8888 sehe,
    hab ich auch nix davon

    Dafür, das ich (nur) Inbetriebnehmer bin
    und die Bucks der Programmierer ausbügeln muß,
    find ich den Baustein gut.

  5. #15
    Registriert seit
    08.08.2007
    Ort
    Dresden
    Beiträge
    9.648
    Danke
    1.059
    Erhielt 2.046 Danke für 1.627 Beiträge

    Standard

    Zitat Zitat von The Blue Beitrag anzeigen
    Wie, Bausteinbeschreibung??
    Hab den Baustein doch mit "Dreh_Zahl_Richtung"
    genannt.
    Kann ich für einen Baustein eine richtige Beschreibung schreiben??
    Wenn ja - wie??
    hab es nicht runtergeladen aber ich kann mir vorstellen, dass du die kleinen grauen felder in den einzelnen netzwerken kennst, das ganze gibts für die gesamte funktion auch, ganz oder unterm titel...
    [SIGNATUR]
    Ironie setzt Intelligenz beim Empfänger voraus.
    [/SIGNATUR]

  6. #16
    Registriert seit
    15.06.2008
    Beiträge
    119
    Danke
    19
    Erhielt 24 Danke für 19 Beiträge

    Standard

    Zitat Zitat von The Blue Beitrag anzeigen
    find ich den Baustein gut.
    Dann frag nicht nach ernst gemeintem Feedback sondern bettel um Anerkennung für Deine ach so tolle Leistung!

  7. #17
    Registriert seit
    14.10.2008
    Ort
    Palz
    Beiträge
    89
    Danke
    9
    Erhielt 12 Danke für 9 Beiträge

    Standard

    Zitat Zitat von vierlagig Beitrag anzeigen
    kleinen grauen felder
    ä - die sind noch frei für...

  8. #18
    Registriert seit
    14.10.2008
    Ort
    Palz
    Beiträge
    89
    Danke
    9
    Erhielt 12 Danke für 9 Beiträge

    Standard

    Zitat Zitat von forendiva Beitrag anzeigen
    Dann frag nicht nach ernst gemeintem Feedback sondern bettel um Anerkennung für Deine ach so tolle Leistung!
    Ich bettel bestimmt nicht um Anerkennung !!

    Und ich meine es so, wenn ich sage/schreibe
    Danke für Dein Feedback

    wie sieht denn ein Baustein bei Dir aus???

    VG

  9. #19
    Registriert seit
    15.06.2008
    Beiträge
    119
    Danke
    19
    Erhielt 24 Danke für 19 Beiträge

    Standard

    Zitat Zitat von The Blue Beitrag anzeigen
    wie sieht denn ein Baustein bei Dir aus???
    Oh, eine Herausforderung.
    Anbei ein Beispiel früher Jahre zum selber übersetzen.

    Code:
    FUNCTION_BLOCK "M_1DRCT"
    TITLE =1 DIRECTION DRIVE
    //this function_block realize the control of a one direction drive.
    //all functions of the drive are monitored and avaible at wRetVal.
    //an error also will switch off the EN0 of the function_block.
    //
    //wRetVal - status
    //----------------
    //0000 - enable and ready to go
    //0001 - start drive
    //0003 - start drive and contactor on
    //0007 - drive run and all functions ok
    //
    //wRetVal - error
    //---------------
    //8000 - no extern enable
    //8001 - protectswitch off
    //8002 - repairswitch off
    //8003 - protectswitch and repairswitch off
    //8004 - contactor had not switched in time or is gone
    //8005 - motioncontrol had not switched in time or is gone
    //
    //DATE:     05.08.1997
    //AUTHOR:   fd
    //VERSION:  V0.1 BasicVer
    AUTHOR : 'fd'
    VERSION : 0.1
    
    
    VAR_INPUT
      xPlcPulse : BOOL ;	//plug the Mx.0 with 10Hz here
      xEnable : BOOL ;	//extern enable input (1=ON)
      xProtectSwitch : BOOL ;	//(1=OK)
      xRepairSwitch : BOOL ;	//(1=OK)
      xContactor : BOOL ;	//(1=ON)
      xMotionControl : BOOL ;	//(1=OK)
      xStart : BOOL ;	//(1=START)
      iContactorTime : INT ;	//normally a small number, maybe 10 (mean 1s)
      iMotionControlTime : INT ;	//a little more than the time the drive needs to run fullspeed
    END_VAR
    VAR_OUTPUT
      xContactorOut : BOOL ;	//the output for the drive
      wRetVal : WORD ;	//status/error information
    END_VAR
    VAR
      xHelpFlagEnable : BOOL ;	
      xHelpFlagPlcPulse : BOOL ;	
      xTimeEnable : BOOL ;	
      xAllFine : BOOL ;	
      iTimer : INT ;	
    END_VAR
    BEGIN
    NETWORK
    TITLE =
    
         
    // 
    //enable and init the function_block
    // 
    
          UN    #xEnable; //if enable false then
          R     #xAllFine; //reset intern start enable
          R     #xContactorOut; //make sure contactor is off
          SPBN  nore; 
          L     W#16#8000; 
          T     #wRetVal; //write status information
          SPA   end; //and leave the function
    
    nore: UN    #xStart; //if start not and
          SPBN  ston; 
          R     #xTimeEnable; 
          L     W#16#0; //only enable and all switches on
          T     #wRetVal; //wRetVal = 0000
    NETWORK
    TITLE =
    
    //
    //init and take ready for trigger
    //
    
    ston: U     #xEnable; //enable true
          U     #xStart; //and start
          FP    #xHelpFlagEnable; //new
          SPBN  nonw; 
          L     W#16#1; //then
          T     #wRetVal; //write status information
          L     0; //initialize
          T     #iTimer; //timer with zero
          S     #xTimeEnable; //and make enable
          S     #xAllFine; //set the intern enable
    NETWORK
    TITLE =
    
    // 
    //check the function
    // 
    
    nonw: UN    #xProtectSwitch; 
          SPBN  pok; 
          L     W#16#8001; //if protectswitch off
          UN    #xRepairSwitch; 
          SPBN  ron; 
          L     W#16#8003; //if protectswitch and repairswitch off
    ron:  T     #wRetVal; //write error information
          R     #xAllFine; 
          R     #xContactorOut; //make sure contactor is off
          SPA   err; //and leave the function
    
    pok:  UN    #xRepairSwitch; 
          SPBN  rok; 
          L     W#16#8002; //if repairswitch off
          T     #wRetVal; //write error information
          R     #xAllFine; 
          R     #xContactorOut; //make sure contactor is off
          SPA   err; //and leave the function
    NETWORK
    TITLE =
    
    // 
    //trigger the drive
    // 
    
    rok:  U     #xStart; //if start on
          U     #xAllFine; //and intern enable also
          =     #xContactorOut; //do the drive
    NETWORK
    TITLE =
    
    // 
    //start the timer for drive connections
    // 
    
          U     #xTimeEnable; 
          U     #xAllFine; //the intern enable
          U     #xPlcPulse; //do with the PlcPulse
          FP    #xHelpFlagPlcPulse; 
          SPBN  equ; 
          L     #iTimer; //a timer
          +     1; 
          T     #iTimer; 
    NETWORK
    TITLE =
    //
    //stop if neccessary - contactor
    //
    equ:  U(    ; 
          L     #iTimer; //if the time
          L     #iContactorTime; //bigger than the settime
          >=I   ; //for the contactor
          )     ; 
          UN    #xContactor; //and the contactor off
          SPBN  cook; 
          L     W#16#8004; //write wRetVal
          T     #wRetVal; 
          R     #xAllFine; //and reset the intern enable
          SPA   err; 
    NETWORK
    TITLE =
    //
    //write status, if contactor OK
    //
    cook: U     #xContactor; 
          U     #xStart; 
          SPBN  noco; //contactor on
          L     W#16#3; //means 3
          T     #wRetVal; 
    NETWORK
    TITLE =
    //
    //stop if neccessary - motion control
    //      
    noco: U(    ; 
          L     #iTimer; //if the time
          L     #iMotionControlTime; //bigger than the settime
          >=I   ; //for the motion control
          )     ; 
          UN    #xMotionControl; //and the motion control
          SPBN  mook; 
          L     W#16#8005; //write wRetVal
          T     #wRetVal; 
          R     #xAllFine; //and reset the intern enable
          SPA   err; 
    NETWORK
    TITLE =
    //
    //write status if motion control OK
    //
    mook: U     #xMotionControl; 
          U     #xStart; 
          SPBN  tim; //motion control on
          L     W#16#7; //means 7
          T     #wRetVal; 
    NETWORK
    TITLE =
    //
    //stop the timer
    //
    tim:  L     #iMotionControlTime; //the big time
          L     100; //+100
          +I    ; 
          L     #iTimer; 
          <=I   ; 
          SPBN  end; 
          SET   ; 
          R     #xTimeEnable; //switch off the timer
    NETWORK
    TITLE =
    // 
    //EN0-handling
    // 
    
    end:  L     #wRetVal; //if the wRetVal
          L     W#16#8000; //bigger than 8000
          >D    ; //then is an error
          SPB   err; //and the EN0 are false
          SET   ; //else the EN0 are true
          SAVE  ; 
    err:  NOP   0; 
    END_FUNCTION_BLOCK

  10. #20
    Registriert seit
    27.05.2004
    Ort
    Thüringen/Berlin
    Beiträge
    12.264
    Danke
    537
    Erhielt 2.708 Danke für 1.957 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    @fd

    Code:
    U     #xEnable; //enable true
    Na ja, Kommentare in allen Ehren, aber man kanns auch locker mal übertreiben.
    Gruß
    Ralle

    ... there\'re 10 kinds of people ... those who understand binaries and those who don\'t …
    and the third kinds of people … those who love TIA-Portal

Ähnliche Themen

  1. Antworten: 9
    Letzter Beitrag: 03.05.2011, 11:11
  2. DC-Motor Drehzahlregelung mit Analogausgang
    Von dacripple im Forum Elektronik
    Antworten: 1
    Letzter Beitrag: 04.11.2008, 21:02
  3. DC-Motor Drehzahlregelung mit Analogausgang
    Von dacripple im Forum Antriebstechnik
    Antworten: 0
    Letzter Beitrag: 04.11.2008, 12:24
  4. Antworten: 14
    Letzter Beitrag: 18.04.2008, 20:04
  5. 6 versch. Werte über den Analogausgang ausgeben
    Von MRT im Forum Sonstige Steuerungen
    Antworten: 22
    Letzter Beitrag: 28.01.2008, 12:46

Stichworte

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •