Serien Stromstoßrelais

ich weiß zwar nicht was ein "Serien" Stromstoßschalter ist, aber wenn du mal die Suchfunktion bemühen würdest, dann wärst du bestimmt fündig geworden.

Stichworte: Binäruntersetzer, Eltako, Stromstoßschalter

Im übrigen schadet es gar nichts, wenn man mal ein bissel seine grauen Zellen oder sein Hirnschmalz fordern würde - so schwierig ist das ganze nun auch wieder nicht.
 
Zuviel Werbung?
-> Hier kostenlos registrieren
@Uncle Tom:
ein Serienschalter ist die Kombination von 2 Aus-Schaltern in einem Gehäuse (also eine Doppelwippe). Vielleicht ist dann ein Serien-Stromstoss-Schalter ein Doppel-Stromstoss-Schalter ...? :rolleyes:

@dolchen:
... das würde mich auch mal interessieren ...
Und ... was hast du eigentlich genau vor ?
 
ich hab grad mal ein bissel gegoogelt. Von Eltako gibt´s mittlerweile recht interessante Bauteile ;).

z.B. einen Multifunktions-Stromstoßschalter Link - der hat dann die besagte "Serien-Stromstoßfunktion". Es werden hier quasi 2 getrennte Verbraucher mit einem Tasteingang über Schaltfolgen gesteuert (z.B. AUS-1-2-1+2).

In einer S7 könnte man das z.B. in etwa so realisieren:

Code:
//unsinnige Werte abfangen

L #Zaehler
L 0
<I
SPBN Nex0

L 0
T #Zaehler

Nex0: NOP 0

//Flankenauswertung Taster

U "Taster"
FP #HM_Flanke
= #Flanke

//Schaltfolgenzaehler

U #Flanke
SPBN Nex1

L #Zaehler
L 1
+I
T #Zaehler

Nex1: NOP 0

//Zaehler zuruecksetzen

L #Zaehler
L 4
>=I
SPBN Nex2

L 0
T #Zaehler

Nex2: NOP 0

//Ausgaenge zuweisen

L Zaehler
L 1
==I
O(
L #Zaehler
L 3
==I
)
= "Lampe_1"

L #Zaehler
L 2
==I
O(
L #Zaehler
L 3
==I
)
= "Lampe_2"
es gibt bestimmt noch elegantere und kürzere Versionen !

Für ne S5 müsste man sich das halt dann noch passend ableiten.

Mfg
uncle_tom
 
Zuviel Werbung?
-> Hier kostenlos registrieren
anmerkung zu deiner lösung: hätteste noch ne sprungleiste eingebaut, dann wärst du mein persönlicher held heut geworden ...

die Sprungleiste hatte ich schon im Gedanken, hab sie dann aber wieder fallen lassen, da ich grad kein Step7 zum Spicken zur Hand hab, und ich mir bei der Syntax aus dem Stehgreif heraus nicht 100%ig sicher bin. :)
 
Zuletzt bearbeitet:
so hab jetzt mal schnell VMware angeschmissen und hab das ganze in Step 7 reingeklopft und durchsimuliert - jetzt mit Sprungleiste :cool:

Code:
//unsinnige Werte abfangen

      L     #Zaehler
      L     0
      <I    
      SPBN  Nex0

      L     0
      T     #Zaehler

Nex0: NOP   0

//Flankenauswertung Taster

      U     #Taster
      FP    #HM_Flanke
      SPBN  Nex1

      L     #Zaehler
      +     1    
      T     #Zaehler
 
//Ausgaenge zuweisen per Sprungleiste

Nex1: L     #Zaehler
      SPL   LSTX
      SPA   Null
      SPA   Eins
      SPA   Zwei
      SPA   Drei

LSTX: CLR                               //Schaltspielzaehler hat ungueltigen Wert 
      =     #Lampe_1
      =     #Lampe_2
      L     0
      T     #Zaehler
      SPA   Comm

Null: CLR                               //Schaltfolgezaehler Wert 0
      =     #Lampe_1
      =     #Lampe_2
      SPA   Comm

Eins: SET                               //Schaltfolgezaehler Wert 1
      =     #Lampe_1
      CLR   
      =     #Lampe_2
      SPA   Comm

Zwei: CLR                               //Schaltfolgezaehler Wert 2
      =     #Lampe_1
      SET   
      =     #Lampe_2
      SPA   Comm

Drei: SET                               //Schaltfolgezaehler Wert 3
      =     #Lampe_1
      =     #Lampe_2
      SPA   Comm

Comm: NOP   0

funktioniert !

Die Lösung von vierlagig ist kürzer, wenn man nur 2 Ausgänge bzw. Schaltspiele hat. Bei mehreren Ausgängen ist die Variante mit Zähler und Sprungleiste aber vermutlich einfacher und verständlicher.

Klinke mich dann hier an dieser Stelle aus, da ich Samstag Abend auch noch was besseres zu tun hab ;)

Mfg
uncle_tom

Edit: Hab den Code nochmal angepasst - ist jetzt etwas kürzer und schlanker - Danke an vierlagig
 
Zuletzt bearbeitet:
Zurück
Oben