Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Seite 4 von 5 ErsteErste ... 2345 LetzteLetzte
Ergebnis 31 bis 40 von 44

Thema: Digitale Impulse eines Durchflussmessers in Volumenstrom umrechnen

  1. #31
    Registriert seit
    11.09.2007
    Beiträge
    128
    Danke
    16
    Erhielt 8 Danke für 7 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Zitat Zitat von vierlagig Beitrag anzeigen
    möööp, nicht das was er sucht... du ermittelst lediglich das volumen, er möchte aber den volumenstrom

    jesper ist da schon auf dem richtigen dampfer

    Hatte ich auch schon geändert

    Aber mit dem einen ist das andere auch Möglich
    _____________________________________________
    Wer die F1 Taste kontrolliert ist ein König !!

  2. #32
    Registriert seit
    11.09.2007
    Beiträge
    128
    Danke
    16
    Erhielt 8 Danke für 7 Beiträge

    Standard

    Digitale Impulse eines Durchflussmessers in Volumenstrom umrechnen

    Hatte mich erst verlesen, kam wegen dem Durchflussmesser durcheinander. Wenn man nen Padel oder ne Turbine hat ist das zwar ne Durchflussmessung aber die man errechnen muss, aus den Impulsen.

    Das sind 3 - 4 Netzwerke in dem du das Berechnen kannst.

    Morgen im laufe des Nachmittags poste ich hier mal den Code aus meinem Baustein


    _____________________________________________
    Wer die F1 Taste kontrolliert ist ein König !!

  3. #33
    Atlas ist offline Benutzer
    Themenstarter
    Registriert seit
    28.06.2007
    Beiträge
    63
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Danke für deine Unterstützung. Ich habe ja bereits einen Baustein der das macht. Original ist der in AWL geschrieben aber fürs Forum hab ich den FB als AWL Quelle exportiert:

    Code:
    FUNCTION_BLOCK "Imp_To_Flow"
    TITLE =Imp_To_Flow
    //Für die Funktion dieses Bausteines wird der SFB3 "TP" benötigt!
    //
    //Der Baustein zählt digitale Impulse (Count-Impulses) in einem einstellbaren 
    //Zeitfenster (Time-Impuls). Die gezählten Impulse werden mit einer einstellbaren 
    //Einheit (Faktor) multipliziert und nach ablauf des Zeitfensters ausgegeben.
    //
    //Mit der Funktion können z.B. Impulse eines Durchflussmessers in einen 
    //Volumenstrom pro Zeit umgerechnet werden.
    //
    //Beispiel:
    //Einheit pro Impuls = 0.01m³
    //Bei einer Zeitbasis von PT = 15s ergibt sich folgende Einheit für den CImp 
    //welcher bei CImpE angegeben werden kann:
    //
    //         0.01m³
    //CImpE = ------ * 3600 = 2,4 m³/h
    //          15s
    AUTHOR : Atlas
    VERSION : 1.0
    
    
    VAR_INPUT
      CImp : BOOL ;    //Count Impuls
      CImpE : REAL ;    //Einheit eines Count Impulses. z.B. 0,01m³ = 0.01
      PT : TIME ;    //Zeitbasis in der die CImp ausgewertet werden.
    END_VAR
    VAR_OUTPUT
      Flow : REAL ;    
    END_VAR
    VAR
      SFB3_TP : "TP";    
      CImpCounter : REAL ;    
      ImpFP : BOOL ;    
      TImp_Done : BOOL ;    
      TImp_Start : BOOL ;    
    END_VAR
    BEGIN
    NETWORK
    TITLE =
    // Mit Hilfe des SFB3 einen Time-Impuls mit definierter Zeit erzeugen. 
    // Dieser Impuls dient als Zeitbasis für die weitere
    // Abarbeitung des Bausteines.
          UN    #SFB3_TP.Q; 
          =     #TImp_Start; 
    
          CALL #SFB3_TP (
               IN                       := #TImp_Start,
               PT                       := #PT);
    
    // Nächsten Schritt nur abarbeiten wenn T-Impuls true
          UN    #SFB3_TP.Q; 
          SPB   Calc; 
    
    // Hilfsmerker zur Berechnung wieder rücksetzen
          R     #TImp_Done; 
    
    // Pei pos. Flanke des Count-Impulses Zählen 
          U     #CImp; 
          FP    #ImpFP; 
    
          SPBNB Cnt1; 
          L     #CImpCounter; 
          L     1.000000e+000; 
          +R    ; 
          T     #CImpCounter; 
    Cnt1: BE    ; 
    
    // Die gezählten C-Impulse mit der Einheit verrechnen und ausgeben
    // Wurde die Berechnung bereits durchgeführt direkt zum Ergebnis springen
    Calc: U     #TImp_Done; 
          SPB   End1; 
    
          L     #CImpE; 
          L     #CImpCounter; 
          *R    ; 
          T     #Flow; 
    
    // C-Impuls Counter zurücksetzen
          L     0.000000e+000; 
          T     #CImpCounter; 
    
    // Über Hilfsmerker speichern, dass Wert berechnet wurde
          S     #TImp_Done; 
    
    End1: BE    ; 
    END_FUNCTION_BLOCK
    Geändert von Atlas (01.02.2011 um 23:34 Uhr)

  4. #34
    Registriert seit
    06.10.2003
    Beiträge
    3.403
    Danke
    447
    Erhielt 502 Danke für 406 Beiträge

    Standard

    Es ist eine Ermessensfrage, ob man die Zeit zwischen zwei oder zwischen mehreren Impulsen auswertet. Bei 300 bis 1000 Impulsen pro Stunde liegt die Periode zwischen 3,6 und 12s. Ich denke, man kommt hier mit der Zeit zwischen zwei Impulsen ganz gut hin. Prozessalarm oder gar Zählerkarten braucht man normalerweise nicht. Gewöhnliche Zähler sind so ausgelegt dass die Impulse mit ebenso gewöhnlichen SPS-Eingängen ausgewertet werden können. Durchflüsse von Gasmengenzählern, Güllezählern oder auch die Leistung über einen Stromzähler (S0-Schnittstelle) berechne ich auch über die Zeit zwischen zwei Impulsen. Die Berechnung beginnt ab dem zweiten Impuls. Über eine Impulsüberwachung setze ich die Berechnung zurück. Wenn z.Bsp. nach 15s kein Impuls kommt, wird alles auf Null gesetzt (oder auch über ein Freigabesignal). Mit einer kommenden Flanke wird die Berechnung wieder aktiv. Zur Ermittlung der Zeit zwischen den Impulsen verwende ich die Systemzeit (SFC64). Wenn man dann das Ergebnis oder die ermittelte Zykluszeit dämpft, erhält man quasi einen "Analogwert", d.h. man vermeidet die Sprünge in der Anzeige zwischen den Aktualisierungen. Wie gesagt, alles eine Ermessensfrage.
    Es gibt viel mehr Leute, die freiwillig aufgeben, als solche, die echt scheitern.
    Henry Ford

  5. #35
    Atlas ist offline Benutzer
    Themenstarter
    Registriert seit
    28.06.2007
    Beiträge
    63
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Habe gerade gesehen, dass in meinem geposteten SCL code noch ein kleiner Fehler ist. Tut zur Veranschaulichung aber nichts zur sache und ich habe keine einfache Copy & Paste Vorlage geliefert

    War ein langer weg bis hier her, aber ich glaube ich setz einfach nen Filter dahinter wie von Dagobert vorgeschlagen und gut ist!

  6. #36
    Registriert seit
    08.08.2007
    Ort
    Dresden
    Beiträge
    9.648
    Danke
    1.059
    Erhielt 2.046 Danke für 1.627 Beiträge

    Standard

    ich such immernoch den SCL code
    [SIGNATUR]
    Ironie setzt Intelligenz beim Empfänger voraus.
    [/SIGNATUR]

  7. #37
    Atlas ist offline Benutzer
    Themenstarter
    Registriert seit
    28.06.2007
    Beiträge
    63
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Ja, das mit dem SCL war wohl etwas stark vereinfacht geschrieben

    Habe den Baustein als Quelle exportiert und dabei kam dann der (98%ige) AWL Code in der SCL Umgebung dabei raus den ich hier super reinkopieren konnte...

  8. #38
    Registriert seit
    03.04.2008
    Beiträge
    6.200
    Danke
    237
    Erhielt 815 Danke für 689 Beiträge

    Standard

    Zitat Zitat von vierlagig Beitrag anzeigen
    ich such immernoch den SCL code
    AWL Quelle fielleich?

    Denn von SCL habe ich auch nix gefunden


    bike

  9. #39
    Registriert seit
    03.04.2008
    Beiträge
    6.200
    Danke
    237
    Erhielt 815 Danke für 689 Beiträge

    Standard

    Zitat Zitat von Atlas Beitrag anzeigen
    Ja, das mit dem SCL war wohl etwas stark vereinfacht geschrieben

    Habe den Baustein als Quelle exportiert und dabei kam dann der (98%ige) AWL Code in der SCL Umgebung dabei raus den ich hier super reinkopieren konnte...
    War das der Quelleneditor fielleicht?
    Hat wenig mit scl zu tun, was du da gepostet hast.

    bike

    P.S. Ich denke es ist nicht so ganz gut einen fehlerhaften Code hier stehen zu lassen.
    Hast du Angst dass der kopiert wird, oder warum korrigierst du den von dir selbst geschrieben Fehler nicht?

  10. #40
    Atlas ist offline Benutzer
    Themenstarter
    Registriert seit
    28.06.2007
    Beiträge
    63
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Überredet, ist korrigiert. Dafür hab ich die nächste doofe Frage frei

Ähnliche Themen

  1. Gewicht umrechnen...
    Von anne im Forum Simatic
    Antworten: 43
    Letzter Beitrag: 08.06.2010, 10:58
  2. Antworten: 8
    Letzter Beitrag: 05.05.2010, 19:02
  3. Wasserwerk Druck / Volumenstrom
    Von EnemyNr1 im Forum Simatic
    Antworten: 9
    Letzter Beitrag: 08.04.2010, 10:07
  4. Impulse einer Haspel in eine Länge umrechnen
    Von mg1382 im Forum Simatic
    Antworten: 18
    Letzter Beitrag: 20.07.2009, 11:30
  5. Geberwerte in U/min Umrechnen
    Von Thomed im Forum Simatic
    Antworten: 7
    Letzter Beitrag: 07.06.2007, 08:52

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •