GELÖST: BSEND/BRCV - mit Vipa CPU315-4PN12 - so geht's
Gelöst. Ob der Hinweis von hovonlo funktioniert, kann ich nicht sagen,
jedoch hat der Vipa Support hier glänzend gearbeitet. Meinen Dank an die Vipa Kollegen!
Hier kann man durchaus eine Lanze für die Vipa Kollegen im dortigen Support brechen. Miniprojekt hingeschickt, analysiert und funktionstüchtig zurück bekommen innerhalb von 24 Std. Gebremst hatte ich dabei, wollte auch Feierabend haben.... am nächsten Nachmittag war'S gegessen. Inbetriebnahmen sind ja auch so anstrengend genug.
So was war's?
Hier die genaue Antwort.
Wie hovonlo angemerkt hat, sind die 318er abgespeckte 400er CPUs. Jedoch sind die diese von Vipa funktions kompatible Geräte, die über die Siemens Kisten hinausgehen. z.B. haben die 315-4PN12 Kisten zusätzlliche Ethernet Ports und enthalten neben der CPU mit ihrem PN Port auch noch einen CP343-1 Advanced CP auf dem Mutterbrett.
Der Fehler war, die Original, für Siemens Hardware geschriebenen FB12/FB13 aus der SIEMENS Std Library zu verwenden.
Korrekt wäre gewesen, die für die VIPA Hardware geschriebenen Vipa FB12/FB13 aus der Vipa System Library zu nehmen!
Eine einfache Regel Siemens Firmwareabhängige Software/SPFB/FB auch aus der Siemens Std Lib, und Vipa Firmware abhängige Software aus der Vipa Lib. Kann man so verstehen, verschiedene Hersteller, verschiedene "Treiber". Man kann einen Ati Grafiktreiber ja auch nicht mit einem Nvidia Karte laufen lassen. Passt einfach nicht und funktionieren schon gar nicht.
Ich habe hier für alle die der Suchfunktion mächtig sind eine Lösung als Kochbuch geschrieben, vielleicht taugt das ja auch als Eintrag für die FAQs.
Achtung Vipa CPU Datenkopplung BSEND/BRCV.
Vipa BSEND/BRCV
In der Geräte Doku wird darauf hingewiesen, wie man mit den CPUs richtig umgeht.
Ist nicht wirklich besonders, jedoch gelten:
- als CPU318-2AJ00- konfigurieren
- am Ende des Racks einen "virtuellen" CP343-1EX11- einfügen
- rechts vom dem Ersten einen zweiten virtuellen CP343-1EX21- einfügen, das ist der Advanced Typ.
Somit kann diese 315-4PN12 Cpu wirklich alles. Luxus.
Als nächstes sollte man in
NetPro die Verbindungen projektieren. Je CPU-CPU Übertragung eine.
Hinkanal Mobil -> Fest habe ich ID: W#16#1
Rückanal Fest -> Mobil habe ich ID: W#16#2
Nachdem NetPro die Daten in beide CPUs geladen hat, diese ihren obligatorischen Neustart gemacht haben,
sieht man in der Spezial Diagnose (CP343-1 Advanced auswählen, Strg-D, Dann Knopf Spezialdiagnose in Step7 V5.4), siehe Screenshots.
Nächster Schritt die
Vipa Lib installieren (s.u. im Anhang) und von dort die
BSEND/BRCV Blöcke (FB12/FB13) ins Projekt kopieren.
Hat man die schon von einem Siemens Std Lib einkopiert, diese einfach mit den Vipa FBs. Das ist gaanz wichtig.
Auch hier das Laden der FBs nicht vergessen.
Als nächstes muss man den Daten DB bereitstellen.
Der wird einfach so wie er ist, auf die Partner/Empfänger CPU kopiert. (Noch hat der Empfangs DB Null-Inhalte)
Auf der Sendeseite mit Lebenden oder Demo Daten besalzen, nur Null Daten kommen nicht so gut, weil man nach erfolgreicher Übertragung kein Ergebnis sieht.
Nun kann man dort auf der Empfänger CPU sich ans Werk machen, den "Briefkasten anzuschrauben", sprich, BRCV zu aktivieren.
Im Demo Projekt FC10, hier als AWL Quelle, am Ende des Beitrages, in den Anhängen hab ich das Demo Projekt veröffentlicht.
BRCV
Code:
FUNCTION "Senden+Empfangen vonKran" : VOID
TITLE =DB 36 empfangen
VERSION : 0.1
VAR_TEMP
done : BOOL ;
error : BOOL ;
ndr : BOOL ;
len : WORD ;
status : WORD ;
test : WORD ;
END_VAR
BEGIN
NETWORK
TITLE =
U M 0.1;
= L 8.0;
BLD 103;
U M 0.1;
SPBNB _001;
CALL "BRCV" , "IDB-FB13-BRCV" (
EN_R := L 8.0,
ID := W#16#1,
R_ID := DW#16#500,
NDR := M 16.0,
ERROR := M 16.1,
STATUS := #status,
RD_1 := P#DB36.DBX0.0 BYTE 22,
LEN := MW 190);
_001: NOP 0;
NETWORK
TITLE =
U M 16.1;
SPBNB _002;
L #status;
T MW 192;
_002: NOP 0;
NETWORK
TITLE =
L DB40.DBD 20;
T "Bodendaten".BSW_ist_x;
NOP 0;
END_FUNCTION
Beim Laden nicht vergessen den Instanz-DB mit zu Laden
Nächster Schritt, den Sender aktivieren:
Der Merker M1.7 im FC10 ist ein Blinktakt, für den Anfang 2s Takt, um regelmäßig das Senden zu aktivieren. Am Schlluß hierzu mehr.
BSEND
Code:
FUNCTION "Kopplung Bodenstation" : VOID
TITLE =Datenbaustein DB 36 zum Boden Senden
VERSION : 0.1
VAR_TEMP
done : BOOL ;
error : BOOL ;
ndr : BOOL ;
len : WORD ;
status : WORD ;
END_VAR
BEGIN
NETWORK
TITLE =
L 22;
T MW 190;
NOP 0;
NETWORK
TITLE =
U M 1.7;
= L 6.0;
BLD 103;
U M 15.3;
= L 6.1;
BLD 103;
U M 0.1;
SPBNB _001;
CALL "BSEND" , "IDB-FB12-BSEND" (
REQ := L 6.0,
R := L 6.1,
ID := W#16#1,
R_ID := DW#16#500,
DONE := M 15.1,
ERROR := M 15.2,
STATUS := #status,
SD_1 := P#DB36.DBX0.0 BYTE 22,
LEN := MW 190);
_001: NOP 0;
NETWORK
TITLE =
U M 15.2;
SPBNB _002;
L #status;
T MW 192;
_002: NOP 0;
NETWORK
TITLE =
U( ;
U M 15.1;
BLD 100;
FP M 15.4;
) ;
S M 15.4;
U M 15.5;
R M 15.4;
NOP 0;
END_FUNCTION
Auch diesen Laden und den Instanzdatenbausten (IDB) nicht vergessen. Sobald alles an seinem Platz ist, kann man den Empfangsbaustein beobachen und sieht das Daten ankommen.
Performance Betrachtung
Anmerkung noch zum Sende Takt Merker. Man kann auch Die Rückker "Done" auswerten und mit selbigem nach einer Zeit wieder einen Sende Auftrag starten. Aber Vorsicht hierbei! Man müllt leicht das Ethernet zu. Eine so schnelle CPU wie die Vipa 315 mit ihren am SpeedBus hängenden CPs heizen ordentlich. Die schaffen es den Ethernet zuzuschmeissen.
Verglichen mit einer ähnlichen Anordnung mit 2 CPU 315 + CP343-1EX11 oder CP343-1EX10 hat das Vipa Gespann sehr deutliche Performancegewinne bei sehr viel weniger Kosten.
Des weiteren benutzen wir über den
CP343 eine TCP-Fetch/TCP-Write Verbindung zu unserem Krancontroller, quasi ein "MCP" - eine Kranführeremulation in Silizium. Die Vipa CPUs schaffen deutlich mehr Poll Cyclen pro Sekunde. Der reine Siemens Aufbau machte max. 3-5 Polls pro Sekunden, mit diesem disktuiertem Vipa Gespann liegt es bei ca. 30.
So ich denke ich habe alles zusammengestellt, um anderen bei dieser Aktion zu helfen.
Das Demo Beispiel funktioniert nur mit eine Vipa Hardware!
Um das als BSEND/BRCV Demo mit Siemens zu nutzen, muß man die FBs wieder gegen Siemens FBs austauschen und selbstverständlich im Hardware Projekt die richtigen Komponenten eintragen.
Euer Schatten
Anlagen
Vipa Handbücher:
http://www.vipa.com/de/service-support/handbuecher/
Vipa Lib:
http://www.vipa.com/uploads/tx_sbdownloader/Vipa_Bibliothek_V131_02.zip
Funktionierendes Demo Projekt:
http://www.automatix.de/jojo/Vipa_CPU315-4PN12_BSEND-BRCV-Demo.zip
Edit 18.07.2013, Links repariert
