Step 7 Berechnung in AWL

Supermario73 · 23 Mai 2013

Hallo zusammen

Wer kann diese Formel von Excel in AWL umsetzen:

=((d/2)^2*ARCCOS(((d/2)-h)/(d/2))-((d/2)-h)*(2*(d/2)*h-h^2)^(0.5))*L

oder als Formel:

d= Eingabe Durchmesser
h= Eingabe Füllstand
L= Eingabe Länge des Tanks

Diese Formel berechnet anhand des Füllstands eines zylinderförmigen Tanks das Volumen.

Besten Dank für Eure Hilfe

vollmi · 23 Mai 2013

Das können wir alle. Aber du kriegst ja den Lohn dafür.

Fang doch einfach mal an.

L #D
L 2.0
/R
= #Dd2

L #Dd2 // ich weiss nicht zwingend nötig
L #h
-R
T #zwm

Etc.

Mfg René

WL7001 · 23 Mai 2013

Für SUPERMARIO sollte DAS doch nun wirklich kein Problem sein

Sind das Hausaufgaben? Die Formel sieht toll aus.
Im praktischen Leben würde ich: Auslitern, DB erstellen in der gewünschten Auflösung, Füllhöhe messen und fertig.

vollmi · 23 Mai 2013

Nönö berechnen ist schon okay. Kann man sich n baustein machen. 10kubikmeter auslitern kann sich hinziehen.

Ich würd der übersichtlichkeithalber SCL vorziehen.

ducati · 23 Mai 2013

vollmi schrieb:
Nönö berechnen ist schon okay. Kann man sich n baustein machen. 10kubikmeter auslitern kann sich hinziehen.

Ich würd der übersichtlichkeithalber SCL vorziehen.

Naja, aber wenn sich in der Praxis die Behältermaße nicht ständig ändern, wovon auszugehen ist, muss man das nicht in jedem Zyklus berechnen sondern vorher einmal in Excel und dann das Ergebnis in die SPS... auch ohne auslitern

abundzu muss man mal klugscheißen...

vollmi · 23 Mai 2013

Natürlich hast du recht. Aber vielleicht soll er ja den speicherinhalt für die speicherhügel in echtzeit rechnen

http://www.spektrum.de/alias/speichertechnik/ein-granitblock-voller-energie/1061069

Oder es ist ne Hausaufgabe die er gerne von uns gelöst hätte. ;-)

ducati · 23 Mai 2013

Hmm, würde mich mal interessieren, wie die Abdichtung zwischen Granitblock und Berg funktioniert. Spontan hätte ich ja gedacht, das Wasser drückt eher durch den Spalt, als dass der Block sich hebt... aber schaun wir mal, wenn der erste Prototyp fertig ist...

nebenbei, die Formel sieht eher nach nem liegenden Tank aus, stehend wäre sie V=pi/4*d²*h

PN/DP · 23 Mai 2013

ducati schrieb:
aber wenn sich in der Praxis die Behältermaße nicht ständig ändern

Anscheinend wurde dem TE aber aufgetragen, mit variablen Werten (Eingaben) zu rechnen.

Supermario73 schrieb:
d= Eingabe Durchmesser
h= Eingabe Füllstand
L= Eingabe Länge des Tanks

ducati schrieb:
nebenbei, die Formel sieht eher nach nem liegenden Tank aus, stehend wäre sie V=pi/4*d²*h

Auf seinem Bild mit der Originalformel steht ja auch "Horizontal cylinder" ... ich wollte ihn aber auch schon auf die Formel für den stehenden Zylinder hinweisen.

Harald

Supermario73 · 23 Mai 2013

Also nun habe ich rausgefunden: In STEP 7 gibt es nur die Möglichkeit mit der Eulerschen Zahl e (e = 2.7182818 ...) zu potenzieren (EXP).....

Ich werde also die Formel weiterbasteln.....

Ralle · 23 Mai 2013

Guckst du hier !

ducati · 23 Mai 2013

a^0,5 = a^(1/2) = Quadratwurzel(a)

Potenzgesetzte... ohne Mathe wird's auch als SPS-Programmierer nix...

Supermario73 · 23 Mai 2013

So nun habe ich mal einen FC erstellt.
Leider Rechnet dieser ein wenig falsch, finde aber im Moment den Fehler nicht.
Verwendete Parameter:
Länge: 2.48
Durchmesser: 1.9
Wasserspiegel: 1.9

Resultat sollte 7.0315 ergeben
doch es spuckt 6.853 aus

Wo ist wohl der Fehler versteckt, ich finde diesen nicht! Wenn jemand einen Vorschlag hat..... dieser ist willkommen!

Quelle:
FUNCTION "Vol_Tank_Calc" : VOID
TITLE =Berechnet das Volumen eines Tankes
VERSION : 0.1

VAR_INPUT
Durchmesser_Tank : REAL ;
Laenge_Tank : REAL ;
Hoehe_Wasserspiegel : REAL ;
END_VAR
VAR_OUTPUT
Liter : REAL ;
END_VAR
VAR_TEMP
Temp_Real_1 : REAL ;
Temp_Real_2 : REAL ;
Temp_Real_3 : REAL ;
Teil_1 : REAL ;
Teil_2 : REAL ;
Teil_3 : REAL ;
Teil_4 : REAL ;
Teil_1_mul_Teil_2 : REAL ;
Teil_3_mul_Teil_4 : REAL ;
END_VAR
BEGIN
NETWORK
TITLE =Teil 4 berechnen

L #Durchmesser_Tank;
L #Hoehe_Wasserspiegel;
*R ;
T #Temp_Real_1;
L #Hoehe_Wasserspiegel;
L #Hoehe_Wasserspiegel;
*R ;
T #Temp_Real_2;

L #Temp_Real_1;
L #Temp_Real_2;
-R ;
T #Temp_Real_3;

CALL "Potenz" (
P_in := #Temp_Real_3,
X_in := 5.000000e-001,
Y_out := #Teil_4);

NETWORK
TITLE =Teil 3 berechnen

L #Durchmesser_Tank;
L 2.000000e+000;
/R ;
L #Hoehe_Wasserspiegel;
-R ;
T #Teil_3;

NETWORK
TITLE =Teil 3 mit Teil 4 multiplizieren

L #Teil_3;
L #Teil_4;
*R ;
T #Teil_3_mul_Teil_4;
NETWORK
TITLE =Teil 1 berechnen

L #Durchmesser_Tank;
L 2.000000e+000;
/R ;
T #Temp_Real_1;

CALL "Potenz" (
P_in := #Temp_Real_1,
X_in := 2.500000e+000,
Y_out := #Teil_1);

NETWORK
TITLE =Teil 2 berechnen

L #Durchmesser_Tank;
L 2.000000e+000;
/R ;
T #Temp_Real_1;

L #Teil_3;
L #Temp_Real_1;
/R ;
T #Temp_Real_2;
ACOS ;
T #Teil_2;

NETWORK
TITLE =Teil 1 mit Teil 2 multiplizieren

L #Teil_1;
L #Teil_2;
*R ;
T #Teil_1_mul_Teil_2;

NETWORK
TITLE =#Teil_1_mul_Teil_2 von Teil_3_mul_Teil_4 subtrahieren

L #Teil_1_mul_Teil_2;
L #Teil_3_mul_Teil_4;
-R ;
T #Temp_Real_1;
NETWORK
TITLE =...mit der Länge multiplizieren

L #Temp_Real_1;
L #Laenge_Tank;
*R ;
T #Liter;
END_FUNCTION

Quelle des FC3:
FUNCTION FC 3 : VOID
TITLE =Potenz
VERSION : 0.1

VAR_INPUT
P_in : REAL ; //Basis
X_in : REAL ;
END_VAR
VAR_OUTPUT
Y_out : REAL ;
END_VAR
BEGIN
NETWORK
TITLE =Potenz

L #P_in;
LN ;
L #X_in;
*R ;
EXP ;
T #Y_out;
END_FUNCTION

ducati · 23 Mai 2013

sehe in Deiner Formel nix mit a^2,5

Code:

CALL "Potenz" (
P_in := #Temp_Real_1,
X_in := 2.500000e+000,
Y_out := #Teil_1);

Gruß.

smilie108 · 23 Mai 2013

Hi

Mhm Mir hat ein schlauer mann bei Siemens gesagt das beim rechnen mit real zahlen fehler auftreten ( rechenfehler) in der cpu) hatte mengenrechner mit realzahlen gemacht die aber falsch rechneten nicht viel aber ein bischen. er sagte ich muss da umdispunieren und mit int und ganzen zahlen rechnen sprich vergleich wann ich eine gewisse zahl adieren kann und die dann adieren aber im ganzzahlbereich mit gleitzahlen rechnet die s7 falsch. Ob das bei jeder S7 ist weis ich nicht.

ducati · 23 Mai 2013

smilie108 schrieb:
Hi

Mhm Mir hat ein schlauer mann bei Siemens gesagt das beim rechnen mit real zahlen fehler auftreten ( rechenfehler) in der cpu) hatte mengenrechner mit realzahlen gemacht die aber falsch rechneten nicht viel aber ein bischen. er sagte ich muss da umdispunieren und mit int und ganzen zahlen rechnen sprich vergleich wann ich eine gewisse zahl adieren kann und die dann adieren aber im ganzzahlbereich mit gleitzahlen rechnet die s7 falsch. Ob das bei jeder S7 ist weis ich nicht.

Das ist was ganz anderes...

bei real kannst Du irgendwann nicht mehr 1 dazuaddieren, weils nicht im Real abgebildet wird. Aber im DINT geht's noch... Im real gehen 8 bits für den Exponenten verloren, bei DINT stehen die zur Verfügung

Gruß

Supermario73 · 23 Mai 2013

@ducati

Genau das wars!!!!! Ich danke Dir!!! Habe ich nicht gefunden.

Der Fehler war:

CALL "Potenz" (
P_in := #Temp_Real_1,
X_in := 2.500000e+000, muss 2.000000e+000 sein!
Y_out := #Teil_1);

Werde nun noch die runden Ende des Tanks links und rechts berechnen und mit dem Zylinder addieren das Ganze, wahrscheinlich morgen, hier einstellen!

Besten Dank und Grüsse

ducati · 23 Mai 2013

Bitte bitte,

übersichtlicher wird's, wenn Du anstatt der Potenzfunktion einfach SQRT nimmst, und den Radius einmal am Anfang berechnest, dann musst Du nicht xmal D/2 rechnen...

Supermario73 schrieb:
Werde nun noch die runden Ende des Tanks links und rechts berechnen

da bin ich ja mal gespannt...

volker · 23 Mai 2013

auf meiner hp liegt ein projekt zum berechnen eines liegenden zylinders
ob ich das mit der obigen formel berechnet hab weiß ich nicht mehr. 100 jahre her

Supermario73 · 24 Mai 2013

@ducati
Ja hast recht, doch ich habs gelassen, damit die Nachvollziehbarkeit auch noch in 5 Monaten möglich ist.

@Volker
Vielen Dank für Dein Link mit all den Bausteinen

So, nun die Quelle für FC3

Code:

FUNCTION FC 3 : VOID
TITLE =Potenz
VERSION : 0.1


VAR_INPUT
  P_in : REAL ;     //Basis
  X_in : REAL ;     
END_VAR
VAR_OUTPUT
  Y_out : REAL ;  
END_VAR
BEGIN
NETWORK
TITLE =Potenz

      L     #P_in; 
      LN    ; 
      L     #X_in; 
      *R    ; 
      EXP   ; 
      T     #Y_out; 
END_FUNCTION

...und die Berechnung des Volumens für liegen Zylinder mit runden Köpfen

Code:

FUNCTION "Vol_Tank_Calc" : VOID
TITLE =Berechnet das Volumen eines Tankes
VERSION : 0.1


VAR_INPUT
  Durchmesser_Tank : REAL ;        
  Laenge_Tank : REAL ;   
  Hoehe_Wasserspiegel : REAL ;  
END_VAR
VAR_OUTPUT
  Liter : REAL ;     
END_VAR
VAR_TEMP
  Temp_Real_1 : REAL ;   
  Temp_Real_2 : REAL ;   
  Temp_Real_3 : REAL ;   
  Teil_1 : REAL ;  
  Teil_2 : REAL ;  
  Teil_3 : REAL ;  
  Teil_4 : REAL ;  
  Teil_1_mul_Teil_2 : REAL ;         
  Teil_3_mul_Teil_4 : REAL ;         
  Zylinder : REAL ;             
  Koepfe : REAL ;               
END_VAR
BEGIN
NETWORK
TITLE =Teil 4 berechnen

      L     #Durchmesser_Tank; 
      L     #Hoehe_Wasserspiegel; 
      *R    ; 
      T     #Temp_Real_1; 
      L     #Hoehe_Wasserspiegel; 
      L     #Hoehe_Wasserspiegel; 
      *R    ; 
      T     #Temp_Real_2; 

      L     #Temp_Real_1; 
      L     #Temp_Real_2; 
      -R    ; 
      T     #Temp_Real_3; 

      CALL "Potenz" (
           P_in                     := #Temp_Real_3,
           X_in                     := 5.000000e-001,
           Y_out                    := #Teil_4);

NETWORK
TITLE =Teil 3 berechnen

      L     #Durchmesser_Tank; 
      L     2.000000e+000; 
      /R    ; 
      L     #Hoehe_Wasserspiegel; 
      -R    ; 
      T     #Teil_3; 

NETWORK
TITLE =Teil 3 mit Teil 4 multiplizieren

      L     #Teil_3; 
      L     #Teil_4; 
      *R    ; 
      T     #Teil_3_mul_Teil_4; 
NETWORK
TITLE =Teil 1 berechnen

      L     #Durchmesser_Tank; 
      L     2.000000e+000; 
      /R    ; 
      T     #Temp_Real_1; 

      CALL "Potenz" (
           P_in                     := #Temp_Real_1,
           X_in                     := 2.000000e+000,
           Y_out                    := #Teil_1);

NETWORK
TITLE =Teil 2 berechnen

      L     #Durchmesser_Tank; 
      L     2.000000e+000; 
      /R    ; 
      T     #Temp_Real_1; 

      L     #Teil_3; 
      L     #Temp_Real_1; 
      /R    ; 
      T     #Temp_Real_2; 
      ACOS  ; 
      T     #Teil_2; 
NETWORK
TITLE =Teil 1 mit Teil 2 multiplizieren

      L     #Teil_1; 
      L     #Teil_2; 
      *R    ; 
      T     #Teil_1_mul_Teil_2; 

NETWORK
TITLE =#Teil_1_mul_Teil_2 von Teil_3_mul_Teil_4 subtrahieren

      L     #Teil_1_mul_Teil_2; 
      L     #Teil_3_mul_Teil_4; 
      -R    ; 
      T     #Temp_Real_1; 
NETWORK
TITLE =...mit der Länge multiplizieren

      L     #Temp_Real_1; 
      L     #Laenge_Tank; 
      *R    ; 
      T     #Zylinder; 
NETWORK
TITLE =Köpfe berechnen

      L     #Hoehe_Wasserspiegel; 
      L     #Hoehe_Wasserspiegel; 
      *R    ; 
      T     #Temp_Real_1; 

      L     3.141593e+000; 
      L     6.000000e+000; 
      /R    ; 
      L     #Temp_Real_1; 
      *R    ; 
      T     #Temp_Real_2; 

      L     1.500000e+000; 
      L     #Durchmesser_Tank; 
      *R    ; 
      L     #Hoehe_Wasserspiegel; 
      -R    ; 
      T     #Temp_Real_3; 

      L     #Temp_Real_2; 
      L     #Temp_Real_3; 
      *R    ; 
      T     #Koepfe; 
NETWORK
TITLE =Zylinder und Köpfe addieren

      L     #Koepfe; 
      L     2.000000e+000; 
      *R    ; 
      L     #Zylinder; 
      +R    ; 
      L     1.000000e+003; 
      *R    ; 
      T     #Liter; 
END_FUNCTION

Wünsche allen frohes Arbeiten und beste Grüsse......

wiesel187 · 24 Mai 2013

Berechnungen in AWL. Na ja ...
SCL wäre da schon die bessere Sprache.
Und schau die deine Berechnung noch mal genau an ( Köpfe )
Schlagwort Klöpperboden ...

Grüße
wiesel

Step 7 Berechnung in AWL

Level-2

Level-3

Level-2

Level-3

Level-3

Level-3

Level-3

User des Jahres 2011-2013; 2015-2017; 2020-2022

Level-2

Super-Moderator , User des Jahres 2006-2007

Level-3

Level-2

Level-3

Level-2

Level-3

Level-2

Level-3

Supermoderator

Level-2

Level-2

Similar threads

Wir schützen deine Privatsphäre