Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Seite 6 von 6 ErsteErste ... 456
Ergebnis 51 bis 52 von 52

Thema: AWL nach SCL convertieren

  1. #51
    Registriert seit
    29.03.2004
    Beiträge
    5.741
    Danke
    143
    Erhielt 1.687 Danke für 1.226 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Ja, scheint zu groß. Ich habe noch ein einfacheres Beispiel.
    AWL-Input ist
    Code:
          SET   
          SAVE  
          =     L      4.1
          L     1
          T     #x
          L     100
          T     #i
    A7d0: L     #i
          L     0
          >I    
          SPBN  A7d1
          L     #i
          L     5
          >I    
          SPBN  A7d2
          L     #x
          L     #i
          +I    
          T     #x
          L     #x
          L     10
          >I    
          SPBN  A7d4
          L     0
          T     #x
          SPA   A7d4
    A7d2: L     #i
          L     20
          >I    
          SPBN  A7d5
          L     #i
          T     #x
          SPA   A7d4
    A7d5: L     1
          T     #x
    A7d4: L     #i
          L     1
          -I    
          T     #i
          SPA   A7d0
    A7d1: CLR   
          U     L      4.1
          SAVE  
          BE
    SCL-Code war
    Code:
    FUNCTION FC201 : VOID
    
    VAR_TEMP
        i : INT;
        x : INT;
    END_VAR
    BEGIN
    
    x := 1;
    i := 100;
    
    WHILE i > 0 DO
        IF i > 5 THEN
            x := x + i;
            IF x > 10 THEN
                x := 0;
            END_IF;
        ELSIF i > 20 THEN
            x := i;
        ELSE
            x := 1;
        END_IF;
        i := i - 1;
    END_WHILE;    
    
    END_FUNCTION
    Um die Schleifentypen zu erkennen benötigt man etwas Wissen aus der Graphentheorie, dominierende Blöcke usw. Dann gilt es zu erkennen ob und welche die Schleifenvariable ist. Ich weiß gar nicht wie weit ich da war. Glaub ich würde es heute neu schreiben.
    Eigentlich ein interessantes Themengebiet, aber z.Zt. habe ich dafür keine Anwendung.
    Angehängte Grafiken Angehängte Grafiken

  2. #52
    Registriert seit
    16.10.2012
    Beiträge
    743
    Danke
    51
    Erhielt 36 Danke für 29 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Hm. Also ich habe dafür schon Verwendung, weil ich grundsätzlich da Bedarf sehe, weil wenn die Kunden dann mal vor so einem Problem stehen dann heißt es Software neu entwickeln, obwohl man es möglicherweise vermeiden könnte.
    Zu obigem Diagramm: die IF-Abfragen lassen sich recht gut erkennen (... zwei Zustände) beim Zyklus sieht man daß es einer ist, aber nicht welcher. Mir wäre es aber wurscht weil WHILE / FOR / DO-WHILE lassen sich ja gegenseitig ersetzen. Wichtig ist, daß man die Funktionalität beibehält.

    So ein Diagramm ist in der Tat eine gute Grundlage.
    Geändert von Draco Malfoy (26.01.2015 um 00:07 Uhr)

Ähnliche Themen

  1. OP5 nach WIN CC
    Von HannesIVA im Forum Simatic
    Antworten: 1
    Letzter Beitrag: 15.12.2009, 10:54
  2. Von °C nach °F
    Von Kitefriend im Forum Programmierstrategien
    Antworten: 2
    Letzter Beitrag: 03.03.2009, 12:19
  3. Beispiele einer automatischen Querübersetzung von ST nach IL bzw. nach FBS
    Von sps freak im Forum Werbung und Produktneuheiten
    Antworten: 1
    Letzter Beitrag: 04.07.2008, 22:52
  4. S7 SCL FB nach S5
    Von Florian_Niedermaier im Forum Simatic
    Antworten: 6
    Letzter Beitrag: 10.02.2008, 18:19
  5. AWL nach KOP (die x'te)
    Von dkeipp im Forum Simatic
    Antworten: 11
    Letzter Beitrag: 17.11.2006, 20:24

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •