Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Ergebnis 1 bis 4 von 4

Thema: TON/TOF mit "MM:SS" beschalten und zurücklesen

  1. #1
    Registriert seit
    18.04.2005
    Ort
    Fast an der Schweiz
    Beiträge
    856
    Danke
    208
    Erhielt 108 Danke für 76 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Hallo Leute,

    kurze Frage wie bekomme ich aus einem laufenden TON/TOF Timer den MM:SS (Bsp 1:59) zurück ? TON auslesen ist kein Problem das weiss ich ja.
    Den Timer mit MM:SS vorbelegen kann ich ja mit 2 Variabeln erledigen und entsprechend umrechnen.

    Umgekehrt auch oder ? Ich hab mal gesucht hier bei uns mit TON Minuten Sekunden.
    Vielleicht gibt es ein Beispiel dazu ?

    Gruss & Danke
    Michael
    Code:
     RTFM ! Read The F..ing Manual
    Arbeitet mit : Step7 V5.5 SPx / WinCC Flex 2008 SPx / Intouch / Winmod /TIA V14 (abgestürzt...Zitat der Hotline : "Sie dürfen nicht so viel rumdrücken....." TIA, so isses halt)

    ║▌║█║║▌║█║ Warnung! Falscher oder fehlender Kaffee - Benutzer angehalten --(◔̯◔)--
    1334566890111
    Zitieren Zitieren TON/TOF mit "MM:SS" beschalten und zurücklesen  

  2. #2
    Registriert seit
    22.03.2007
    Ort
    Detmold (im Lipperland)
    Beiträge
    11.794
    Danke
    398
    Erhielt 2.417 Danke für 2.013 Beiträge

    Standard

    Hallo Michael,

    wenn du mit TON/TOF die SFB4,5 meinst dann wäre das der OUT .ET des Bausteins. Der gibt dir die abgelaufene Zeit in Millisekunden zurück. Das müßtest du dann nur noch umrechnen ...

    Gruß
    Larry

  3. Folgender Benutzer sagt Danke zu Larry Laffer für den nützlichen Beitrag:

    Waelder (20.01.2014)

  4. #3
    Registriert seit
    09.08.2006
    Beiträge
    3.642
    Danke
    915
    Erhielt 661 Danke für 543 Beiträge

    Standard

    Zitat Zitat von Larry Laffer Beitrag anzeigen
    Das müßtest du dann nur noch umrechnen...
    DIV_DI und MOD_DI sind da Dein Freund

  5. Folgender Benutzer sagt Danke zu ducati für den nützlichen Beitrag:

    Waelder (20.01.2014)

  6. #4
    Avatar von Waelder
    Waelder ist offline Erfahrener Benutzer
    Themenstarter
    Registriert seit
    18.04.2005
    Ort
    Fast an der Schweiz
    Beiträge
    856
    Danke
    208
    Erhielt 108 Danke für 76 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Sodele, erster Versuch die Time in 3x Integer umzuwandeln und umgekehrt :
    Baustein ist getestet und hat für meinen zweck funktioniert.
    U.u. ist eine Optimierung noch möglich.

    Code:
    FUNCTION "FC_TOx T_TO_HMS" : VOID
    TITLE =
    //Umskalierung S7 Zeit T nach "Stunden : Minuten : Sekunden"
    AUTHOR : BA
    FAMILY : Konvert
    NAME : TOxToHMS
    VERSION : 0.1
    
    
    VAR_INPUT
      ZEIT : TIME ;    
    END_VAR
    VAR_OUTPUT
      Stunden : INT ;    
      Minuten : INT ;    
      Sekunden : INT ;    
    END_VAR
    VAR_TEMP
      Zeit_1000 : DINT ;    
      H_R : REAL ;    
      M_R : REAL ;    
      S_R : REAL ;    
      M_ZWT_1 : DINT ;    
      M_ZWT_2 : DINT ;    
      S_ZWT_1 : DINT ;    
      S_ZWT_2 : DINT ;    
    END_VAR
    BEGIN
    NETWORK
    TITLE =
    
    //Durch 1000 Teilen
          L     #ZEIT; 
          L     L#1000; 
          /D    ; 
          T     #Zeit_1000; 
    
    //Stunden errechnen
          L     #Zeit_1000; 
          L     L#3600; 
          /D    ; 
          T     #Stunden; 
    //Minuten errechnen
          L     #Zeit_1000; 
          L     60; 
          /D    ; 
          T     #M_ZWT_1; 
    
          L     #Stunden; 
          L     L#60; 
          *D    ; 
          T     #M_ZWT_2; 
    
          L     #M_ZWT_1; 
          L     #M_ZWT_2; 
          -D    ; 
          T     #Minuten; 
    //Sekunden
          L     #Stunden; 
          L     L#3600; 
          *D    ; 
          T     #S_ZWT_1; 
    
          L     #Minuten; 
          L     L#60; 
          *D    ; 
          T     #S_ZWT_2; 
    
          L     #Zeit_1000; 
          L     #S_ZWT_1; 
          -D    ; 
          L     #S_ZWT_2; 
          -D    ; 
          T     #Sekunden; 
    END_FUNCTION
    DTO für 3x Integer in Zeit
    Code:
    FUNCTION "FC_TOx HMS_TO_T" : VOID
    TITLE =
    //skalierung "Stunden : Minuten : Sekunden" nach S7 Zeit
    AUTHOR : BA
    FAMILY : Konvert
    NAME : TOxHMS_T
    VERSION : 0.1
    
    
    VAR_INPUT
      Stunden : INT ;    
      Minuten : INT ;    
      Sekunden : INT ;    
    END_VAR
    VAR_OUTPUT
      ZEIT : TIME ;    
    END_VAR
    VAR_TEMP
      H_Tmp : TIME ;    
      M_Tmp : TIME ;    
      S_Tmp : TIME ;    
    END_VAR
    BEGIN
    NETWORK
    TITLE =
    
    //Stunden
          L     #Stunden; 
          L     L#3600000; 
          *D    ; 
          T     #H_Tmp; 
    //Minuten
          L     #Minuten; 
          L     L#60000; 
          *D    ; 
          T     #M_Tmp; 
    //Sekunden
          L     #Sekunden; 
          L     L#1000; 
          *D    ; 
          T     #S_Tmp; 
    //Ergebnis
          L     #H_Tmp; 
          L     #M_Tmp; 
          +D    ; 
          L     #S_Tmp; 
          +D    ; 
          T     #ZEIT; 
    END_FUNCTION
    Code:
     RTFM ! Read The F..ing Manual
    Arbeitet mit : Step7 V5.5 SPx / WinCC Flex 2008 SPx / Intouch / Winmod /TIA V14 (abgestürzt...Zitat der Hotline : "Sie dürfen nicht so viel rumdrücken....." TIA, so isses halt)

    ║▌║█║║▌║█║ Warnung! Falscher oder fehlender Kaffee - Benutzer angehalten --(◔̯◔)--
    1334566890111
    Zitieren Zitieren Lösungsvorschlag V01  

Ähnliche Themen

  1. Antworten: 28
    Letzter Beitrag: 25.06.2015, 14:52
  2. "TOF" und Lifebit
    Von Flux im Forum Simatic
    Antworten: 7
    Letzter Beitrag: 27.03.2013, 10:44
  3. Probleme mit 12/24V "high" und 0V als "low" Auswertung
    Von PraktikantMarkus im Forum CODESYS und IEC61131
    Antworten: 8
    Letzter Beitrag: 14.12.2011, 01:37
  4. Antworten: 8
    Letzter Beitrag: 17.03.2009, 22:18
  5. Antworten: 15
    Letzter Beitrag: 27.12.2007, 20:38

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •