fertige Stern-Dreick-Schaltung
FUNCTION "cSternDreieck" : VOID
TITLE =Stern- Dreieck- Anlauf
//Stern-Dreieck Anlauf
//
//IN:
//START: Stern-Dreieck Anlauf Einschalten
//FRG : Freigabe
//T_STERN: Stern Anlaufzeit im S5 Zeitformat
//TIMER_S5: Timer im S5-Format
//
//InOut:
//bTmp: externes dauerhaftes Speicherbyte für Hilfsignale
//
//OUT:
//NETZ: Netz-Schütz
//DREIECK: Dreick-Schütz
//STERN: Stern-Schütz
//
//AUTOR: Stefan Maag, Dipl.-Ing. (FH) Elektrotechnik
//DATUM: 01/2006
//
//AENDERUNGSVERMERKE:
//--------------------------------------------------------------------------------
//DATUM NAME AENDERUNG
//--------------------------------------------------------------------------------
//
//--------------------------------------------------------------------------------
//
//HINWEISE:
AUTHOR : 'S.Maag'
VERSION : 0.1
VAR_INPUT
START : BOOL ;
FRG : BOOL ; //Freigabe
T_STERN : S5TIME ;
TIMER_S5 : TIMER ;
END_VAR
VAR_OUTPUT
NETZ : BOOL ; //Netzschütz
DREIECK : BOOL ; //Dreieckschütz
STERN : BOOL ; //Sternbrücke
END_VAR
VAR_IN_OUT
bTmp : BYTE ;
END_VAR
VAR_TEMP
lb_NETZ : BOOL ;
lb_DREIECK : BOOL ;
lb_STERN : BOOL ;
lb3 : BOOL ;
lb4 : BOOL ;
lb5 : BOOL ;
lb6 : BOOL ;
lb7 : BOOL ;
END_VAR
BEGIN
NETWORK
TITLE =
NETWORK
TITLE =Speichervariable in Lokaldaten
L #bTmp;
T LB 0;
NETWORK
TITLE =
U #lb_NETZ;
L #T_STERN;
SE #TIMER_S5;
NOP 0;
NOP 0;
NOP 0;
NOP 0;
NETWORK
TITLE =Netz
U #START;
S #lb_NETZ;
U( ;
ON #FRG;
ON #START;
) ;
R #lb_NETZ;
NOP 0;
NETWORK
TITLE =Stern
U #lb_NETZ;
UN #TIMER_S5;
UN #lb_DREIECK;
= #lb_STERN;
NETWORK
TITLE =Dreieck
U #lb_NETZ;
U #TIMER_S5;
UN #lb_STERN;
= #lb_DREIECK;
NETWORK
TITLE =Ausgang Netz
U #lb_NETZ;
= #NETZ;
NETWORK
TITLE =Ausgang Dreieck
U #lb_DREIECK;
U #lb_NETZ;
UN #lb_STERN;
= #DREIECK;
NETWORK
TITLE =Ausgang Stern
U #lb_STERN;
UN #lb_DREIECK;
= #STERN;
NETWORK
TITLE =Lokaldaten wieder in Speichervariable zurück
L LB 0;
T #bTmp;
END_FUNCTION