Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Ergebnis 1 bis 8 von 8

Thema: Zeiten in einem Funktionsbaustein

  1. #1
    Registriert seit
    13.03.2006
    Beiträge
    40
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Morgen!
    Eine Frage zu Funktionsbausteinen:
    Ich möchte in einem FC einen Stern Dreieck Anlauf programmieren und diesen später in mehreren anderen FC's als Makro verwenden.
    Darin ist ja eine Zeitfunktion vorhanden (SE).
    Ist es möglich diesen, wie auch die normalen Ein- und Ausgänge, indirekt zu adressieren?
    Oder kann ich ihn z.B. "T1" nennen und trotzdem in mehreren FC's nutzen?
    Gruß
    Roland
    Zitieren Zitieren Zeiten in einem Funktionsbaustein  

  2. #2
    Registriert seit
    20.06.2003
    Ort
    Sauerland.NRW.Deutschland
    Beiträge
    4.862
    Danke
    78
    Erhielt 805 Danke für 548 Beiträge

    Standard

    benutze ein IN-parameter vom typ timer.
    .
    mfg Volker .......... .. alles wird gut ..

    =>Meine Homepage .. direkt zum Download

    Meine Definition von TIA: Total Inakzeptable Applikation

  3. #3
    Registriert seit
    13.03.2006
    Beiträge
    40
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Gut probiere ich mal aus.
    Der Eingang wird mir dann ja auch später am Makro angezeigt.
    Womit belege ich den denn dann? Schreibe ich dann in der ersten Anwendung dieses Makros "T1" an den Eingang,bei der zweiten "T2" usw.?

  4. #4
    Registriert seit
    07.05.2004
    Ort
    Campbelltown
    Beiträge
    2.437
    Danke
    131
    Erhielt 276 Danke für 86 Beiträge

    Standard

    Ja genau, T1 usw.
    Alternativ kannst du auch die IEC Timer verwenden. Nachteil: Benötigen mehr Resourcen, Vorteil: Wesentlich einfacher Umgang.

    Gruß pt
    Gegen Schwachsinn, Schwachköpfe und armselige Trittbrettfahrer kann man nicht argumentieren.

    Gott sieht alles, auch Signaturen in Geheimschrift,,... aber er petzt nicht.

  5. #5
    Registriert seit
    13.03.2006
    Beiträge
    40
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Super, besten Dank!

  6. #6
    Registriert seit
    25.09.2005
    Ort
    Neuss
    Beiträge
    278
    Danke
    11
    Erhielt 31 Danke für 29 Beiträge

    Standard

    Die 1. Variante ist einfacher, wenn die Anzahl der benötigten Timer nicht zu hoch ist und / oder der Speicher der CPU knapp ist, würde ich das auf jeden Fall bevorzugen.

    Ansontsen verwende ich lieber die IEC-Timer als Multiinstanz, da brauch ich gar nix mehr beim Aufruf dran zu schreiben (keine Timer-Nr. nötig)- allerdings für Anwender, die sich mit Multiinstanzen nicht auskennen nicht ganz Ohne.
    Hier mal was zum schnuppern: http://www.automatisierungsprofi.de/TON/index.htm

  7. #7
    Registriert seit
    13.03.2006
    Beiträge
    40
    Danke
    0
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Besten Dank!
    Super Seite! Da hab ich auch gleich noch nen anderes Problem lösen können!

  8. #8
    Stefan Maag Gast

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    FUNCTION "cSternDreieck" : VOID
    TITLE =Stern- Dreieck- Anlauf
    //Stern-Dreieck Anlauf
    //
    //IN:
    //START: Stern-Dreieck Anlauf Einschalten
    //FRG : Freigabe
    //T_STERN: Stern Anlaufzeit im S5 Zeitformat
    //TIMER_S5: Timer im S5-Format
    //
    //InOut:
    //bTmp: externes dauerhaftes Speicherbyte für Hilfsignale
    //
    //OUT:
    //NETZ: Netz-Schütz
    //DREIECK: Dreick-Schütz
    //STERN: Stern-Schütz
    //
    //AUTOR: Stefan Maag, Dipl.-Ing. (FH) Elektrotechnik
    //DATUM: 01/2006
    //
    //AENDERUNGSVERMERKE:
    //--------------------------------------------------------------------------------
    //DATUM NAME AENDERUNG
    //--------------------------------------------------------------------------------
    //
    //--------------------------------------------------------------------------------
    //
    //HINWEISE:
    AUTHOR : 'S.Maag'
    VERSION : 0.1


    VAR_INPUT
    START : BOOL ;
    FRG : BOOL ; //Freigabe
    T_STERN : S5TIME ;
    TIMER_S5 : TIMER ;
    END_VAR
    VAR_OUTPUT
    NETZ : BOOL ; //Netzschütz
    DREIECK : BOOL ; //Dreieckschütz
    STERN : BOOL ; //Sternbrücke
    END_VAR
    VAR_IN_OUT
    bTmp : BYTE ;
    END_VAR
    VAR_TEMP
    lb_NETZ : BOOL ;
    lb_DREIECK : BOOL ;
    lb_STERN : BOOL ;
    lb3 : BOOL ;
    lb4 : BOOL ;
    lb5 : BOOL ;
    lb6 : BOOL ;
    lb7 : BOOL ;
    END_VAR
    BEGIN
    NETWORK
    TITLE =



    NETWORK
    TITLE =Speichervariable in Lokaldaten

    L #bTmp;
    T LB 0;


    NETWORK
    TITLE =



    U #lb_NETZ;
    L #T_STERN;
    SE #TIMER_S5;
    NOP 0;
    NOP 0;
    NOP 0;
    NOP 0;
    NETWORK
    TITLE =Netz

    U #START;
    S #lb_NETZ;
    U( ;
    ON #FRG;
    ON #START;
    ) ;
    R #lb_NETZ;
    NOP 0;
    NETWORK
    TITLE =Stern

    U #lb_NETZ;
    UN #TIMER_S5;
    UN #lb_DREIECK;
    = #lb_STERN;
    NETWORK
    TITLE =Dreieck

    U #lb_NETZ;
    U #TIMER_S5;
    UN #lb_STERN;
    = #lb_DREIECK;
    NETWORK
    TITLE =Ausgang Netz

    U #lb_NETZ;
    = #NETZ;
    NETWORK
    TITLE =Ausgang Dreieck

    U #lb_DREIECK;
    U #lb_NETZ;
    UN #lb_STERN;
    = #DREIECK;
    NETWORK
    TITLE =Ausgang Stern

    U #lb_STERN;
    UN #lb_DREIECK;
    = #STERN;
    NETWORK
    TITLE =Lokaldaten wieder in Speichervariable zurück

    L LB 0;
    T #bTmp;

    END_FUNCTION
    Zitieren Zitieren fertige Stern-Dreick-Schaltung  

Ähnliche Themen

  1. Funktionsbaustein in S40
    Von Arne30 im Forum Sonstige Steuerungen
    Antworten: 2
    Letzter Beitrag: 24.07.2006, 15:05
  2. Funktionsbaustein in S5 ???
    Von Tom1971 im Forum Simatic
    Antworten: 3
    Letzter Beitrag: 06.04.2006, 18:48
  3. Zeiten zyklisch in einem DB speichern
    Von Sebastian im Forum Simatic
    Antworten: 1
    Letzter Beitrag: 28.03.2006, 15:58
  4. Antworten: 5
    Letzter Beitrag: 22.08.2005, 11:39
  5. Zeiten in einem DB Hinterlegen!!!
    Von Anonymous im Forum Simatic
    Antworten: 1
    Letzter Beitrag: 11.08.2005, 15:32

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •