TYPE "ComCouple"
VERSION : 0.1
STRUCT
ComPro : Struct
TCON : Struct
CONN_DONE : Bool;
CONN_BUSY : Bool;
CONN_ERROR : Bool;
CONN_SETA : Bool;
DISCONNECT : Bool;
CONN_STATUS : Word;
STATUS_SAVE : Word;
Errorzähler : DInt;
Donezähler : DInt;
END_STRUCT;
TSEND : Struct
SEND : Bool;
DONE : Bool;
BUSY : Bool;
ERROR : Bool;
REQ_P : Bool;
REQ_I : Bool;
STATUS : Word;
STATUS_SAVE : Word;
NDR : Bool;
LEN : UDInt;
Errorzähler : DInt;
Donezähler : DInt;
END_STRUCT;
TRCV : Struct
REQ : Bool;
DONE : Bool;
BUSY : Bool;
ERROR : Bool;
REQ_P : Bool;
REQ_I : Bool;
STATUS : Word;
STATUS_SAVE : Word;
NDR : Bool;
LEN : UDInt;
Errorzähler : DInt;
Donezähler : DInt;
END_STRUCT;
Empfangstrigger : Bool;
END_STRUCT;
TCP_Parameter {InstructionName := 'TCON_IP_v4'; LibVersion := '1.0'} : TCON_IP_v4;
sSendeVerz : Struct
IN : Bool;
Q : Bool;
END_STRUCT;
Snd : Struct
Byte1 : Byte;
Byte2 : Byte;
Sendebereich : Array[0..256] of Byte;
END_STRUCT;
Rec : Struct
Byte1 : Byte;
Byte2 : Byte;
Empfangsbereich : Array[0..256] of Byte;
END_STRUCT;
END_STRUCT;
END_TYPE
FUNCTION_BLOCK "Kommunikationsaufbau"
TITLE = IKS Kommunikationsserver
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : VoR
FAMILY : Komm
VERSION : 0.3
//Baut die Verbindung zum Basler IKS auf. Umgerüstet für integrierte Profinetschnittstelle der 300er Reihe. Wird nicht mehr im Netpro projektiert!
VAR_INPUT
init : Bool;
END_VAR
VAR_OUTPUT
Error : Bool; // Verbindungsunterbuch
END_VAR
VAR_IN_OUT
ComCouple : "ComCouple";
END_VAR
VAR
TCON_Instance {InstructionName := 'TCON'; LibVersion := '4.0'} : TCON;
TSEND_Instance {InstructionName := 'TSEND'; LibVersion := '4.0'} : TSEND;
TRCV_Instance {InstructionName := 'TRCV'; LibVersion := '4.0'} : TRCV;
SendREQ_TON {InstructionName := 'TON_TIME'; LibVersion := '1.0'} : TON_TIME;
SendeVerz {InstructionName := 'TOF_TIME'; LibVersion := '1.0'} : TOF_TIME;
R_TRIG_TRCV_NDR {InstructionName := 'R_TRIG'; LibVersion := '1.0'} : R_TRIG;
T_DIAG_Instance {InstructionName := 'T_DIAG'; LibVersion := '1.2'} : T_DIAG;
T_DIAG_result {InstructionName := 'TDiag_Status'; LibVersion := '1.0'} : TDiag_Status;
T_RESET_Instance {InstructionName := 'T_RESET'; LibVersion := '1.2'} : T_RESET;
tVerbindungsreset {InstructionName := 'TON_TIME'; LibVersion := '1.0'} : TON_TIME;
stVerbindungsreset : Struct
IN : Bool;
q : Bool;
END_STRUCT;
TDISCON_Instance {InstructionName := 'TDISCON'; LibVersion := '2.1'} : TDISCON;
st_TDISCON : Struct
REQ : Bool;
END_STRUCT;
END_VAR
VAR_TEMP
Dummyval : Int;
END_VAR
VAR CONSTANT
akt_verz : Bool := 0; // Abstand zwischen telegrammen aktivieren?
akt_vz_Time : Time := t#100ms;
END_VAR
BEGIN
(*
Versionsinfo:
V0.1 Baustein erstellt auf Grundlage IKS Kommunikation Basel
V0.2 Baustein angepasst nach Dokument JSDoc_Class_PLC(003)
*)
(* Verbindungsparameter, vormals in NetPro eingerichtet.
Muss nicht zyklisch ausgeführt werden, kann also in OB100 verlegt werden *)
#TCON_Instance.REQ := #stVerbindungsreset.q;
IF #ComCouple.ComPro.TCON.CONN_DONE THEN
#ComCouple.ComPro.TCON.Donezähler := #ComCouple.ComPro.TCON.Donezähler + 1;
END_IF;
IF #ComCouple.ComPro.TCON.CONN_ERROR THEN
#ComCouple.ComPro.TCON.Errorzähler := #ComCouple.ComPro.TCON.Errorzähler + 1;
#ComCouple.ComPro.TCON.STATUS_SAVE := #ComCouple.ComPro.TCON.CONN_STATUS;
END_IF;
#TCON_Instance(ID:=#ComCouple.TCP_Parameter.ID,
DONE=>#ComCouple.ComPro.TCON.CONN_DONE,
BUSY=>#ComCouple.ComPro.TCON.CONN_BUSY,
ERROR=>#ComCouple.ComPro.TCON.CONN_ERROR,
STATUS=>#ComCouple.ComPro.TCON.CONN_STATUS,
CONNECT:=#ComCouple.TCP_Parameter);
#T_DIAG_Instance.REQ := NOT #T_DIAG_Instance.BUSY;
#T_DIAG_Instance(ID:=#ComCouple.TCP_Parameter.ID,
RESULT:=#T_DIAG_result);
#stVerbindungsreset.IN := #T_DIAG_result.State <> 16#04 AND NOT #stVerbindungsreset.q;
#TDISCON_Instance(REQ:= #st_TDISCON.REQ,
ID:=#ComCouple.TCP_Parameter.ID);
#tVerbindungsreset(IN:=#stVerbindungsreset.IN,
PT:=t#30s,
Q=>#stVerbindungsreset.q);
// #T_RESET_Instance(REQ:=#stVerbindungsreset.q,
// ID:=#ComCouple.TCP_Parameter.ID);
REGION Sendeempfangsteil
IF #ComCouple.ComPro.TSEND.DONE THEN
#ComCouple.ComPro.TSEND.Donezähler := #ComCouple.ComPro.TSEND.Donezähler + 1;
#ComCouple.ComPro.TSEND.SEND := false;
END_IF;
IF #ComCouple.ComPro.TSEND.ERROR THEN
#ComCouple.ComPro.TSEND.Errorzähler := #ComCouple.ComPro.TSEND.Errorzähler + 1;
#ComCouple.ComPro.TSEND.STATUS_SAVE := #ComCouple.ComPro.TSEND.STATUS;
#ComCouple.ComPro.TSEND.SEND := false;
END_IF;
#TSEND_Instance(REQ := #ComCouple.ComPro.TSEND.SEND,
ID := #ComCouple.TCP_Parameter.ID,
LEN := #ComCouple.ComPro.TSEND.LEN,
DONE => #ComCouple.ComPro.TSEND.DONE,
BUSY => #ComCouple.ComPro.TSEND.BUSY,
ERROR => #ComCouple.ComPro.TSEND.ERROR,
STATUS => #ComCouple.ComPro.TSEND.STATUS,
DATA := #ComCouple.Snd.Sendebereich);
#TRCV_Instance(EN_R := true,
ID := #ComCouple.TCP_Parameter.ID,
LEN := 0,
ADHOC := TRUE,
NDR => #ComCouple.ComPro.TRCV.NDR,
BUSY => #ComCouple.ComPro.TRCV.BUSY,
ERROR => #ComCouple.ComPro.TRCV.ERROR,
STATUS => #ComCouple.ComPro.TRCV.STATUS,
RCVD_LEN => #ComCouple.ComPro.TRCV.LEN,
DATA := #ComCouple.Rec.Empfangsbereich);
#R_TRIG_TRCV_NDR(CLK:=#ComCouple.ComPro.TRCV.NDR,
Q=>#ComCouple.ComPro.Empfangstrigger);
IF #ComCouple.ComPro.TRCV.NDR THEN
#ComCouple.ComPro.TRCV.Donezähler := #ComCouple.ComPro.TRCV.Donezähler + 1;
END_IF;
IF #ComCouple.ComPro.TRCV.ERROR THEN
#ComCouple.ComPro.TRCV.Errorzähler := #ComCouple.ComPro.TRCV.Errorzähler + 1;
#ComCouple.ComPro.TRCV.STATUS_SAVE := #ComCouple.ComPro.TRCV.STATUS;
END_IF;
#SendREQ_TON(IN := #ComCouple.ComPro.TSEND.SEND,
PT := t#3s);
IF #SendREQ_TON.Q THEN
#ComCouple.ComPro.TSEND.SEND := false;
END_IF;
#SendeVerz(IN := #ComCouple.ComPro.TSEND.SEND, // diese Zeit ist wichtig um das Telegramm komplett in den Sendebuffer zu übertragen.
PT := #akt_vz_Time,
Q=>#ComCouple.sSendeVerz.Q);
IF NOT #akt_verz THEN
#ComCouple.sSendeVerz.Q := false;
END_IF;
#Error := #ComCouple.ComPro.TCON.CONN_ERROR OR #ComCouple.ComPro.TRCV.ERROR OR #ComCouple.ComPro.TSEND.ERROR;
END_REGION
END_FUNCTION_BLOCK
