Schrittkette in Step 5

R

Rollex

Guest
Zuviel Werbung?
->Hier kostenlos registrieren
Re: Mit welcher Sprache??

Zottel schrieb:
Die Sprachen FUP und KOP sollten Leuten mit einem bestimmten Vorwissen den Zugang zu SPS erleichtern.
FUP bildet in etwa logische Elemente nach, wie sie in ICs der TTL und CMOS Logikfamlien verwendet werden.
KOP bildet Schützsteuerungen nach.
Mit "BASIC" meinst Du sicher "structured text" (strukturierter Text?, ST). Dieser Sprache bildet algorithmische Abläufe besoders gut nach. Sie ist höheren Programmiersprachen, vor allem PASCAL, ähnlich.
AWL ist am nächsten an der Maschinensprache der CPU. Daher kann man die kürzesten Programme in AWL schreiben. Zeitverhalten ist dabei selten ausschlaggebend. Die meisten Programme, die ich gesehen habe, waren entweder in AWL oder einer Mischung von FUP und AWL geschrieben.

hallo zottel

gibt es bei s7 eigentlich noch den strukturierten text oder die ablaufsprache??? ich kenn das nur von der s5.

ich versuche mir grade in awl ne schrittkette aus merkern aufzubauen. aber leider funktioniert das nicht so wie ich will.

kannst du mal einige ideen geben?

danke

rollex
 

Markus

Administrator
Teammitglied
Beiträge
5.266
Punkte Reaktionen
1.301
hab das getrennt, hatte absolut nix mit dem anderen thema zu tun!
lest euch bitte die forenbeschreibungen durch, dann gibts hier kein so ein chaos...

was genau willst du? drück dich bitte etwas verständlicher aus, gedankenlesen kann hier keiner...
 

Ralle

Supermoderator
Teammitglied
Beiträge
14.401
Punkte Reaktionen
3.373
Zuviel Werbung?
->Hier kostenlos registrieren
Hier mal eine ganz einfache Merkerschrittkette als AWL-Quelle:

Code:
FUNCTION FC 38 : VOID
TITLE =Schrittketten
AUTHOR : Ralle
VERSION : 1.0

BEGIN
NETWORK
TITLE =Ende Schrittkette

      U     M     31.6; 
      =     M     31.7; //Endemerker (kann auch gesetzt und später rückgesetzt werden)
      R     M     31.6; //Schritt 7
      R     M     31.0; //Laufmerker
NETWORK
TITLE =Leerschritt

      U     M     31.5; 
      S     M     31.6; //Schritt 7
      R     M     31.5; //Schritt 6
NETWORK
TITLE =Schritt 5 - T33 läuft 3 Sek., dann weiter

      U     M     31.4; 
      L     S5T#3S; 
      SA    T     33; 
      NOP   0; 
      NOP   0; 
      NOP   0; 
      U     T     33; 
      S     M     31.5; //Schritt 6
      R     M     31.4; //Schritt 5
NETWORK
TITLE =Schritt 4 - T32 läuft 6 Sek., dann weiter

      U     M     31.3;
      L     S5T#6S; 
      SA    T     32; 
      NOP   0; 
      NOP   0; 
      NOP   0; 
      U     T     32;  
      S     M     31.4; //Schritt 5
      R     M     31.3; //Schritt 4
NETWORK
TITLE = Schritt 3 - Warten, auf Starttaster

      U     M     31.2; 
      U     E      1.0;    
      S     M     31.3; //Schritt 4
      R     M     31.2; //Schritt 3
NETWORK
TITLE =Schritt 2 - T31 läuft 3 Sek., dann weiter
      U     M     31.1; 
      L     S5T#3S; 
      SA    T     31; 
      NOP   0; 
      NOP   0; 
      NOP   0; 
      U     T     31; 
      S     M     31.2; //Schritt 3
      R     M     31.1; //Schritt 2 
NETWORK
TITLE =Schritt 1 - T30 läuft 6 Sek., dann weiter 
      U     M     31.1; 
      L     S5T#6S; 
      SA    T     30; 
      NOP   0; 
      NOP   0; 
      NOP   0; 
      U     T     30; 
      S     M     31.2; //Schritt 2
      R     M     31.1; //Schritt 1
NETWORK
TITLE = Start Schrittkette 
//E1.0 startet Schrittkette
      U     E      1.0; 
      UN    M     31.7; //Endemerker
      UN    M     31.0; 
      S     M     31.0; //Laufmerker
      S     M     31.1; //Schritt 1
END_FUNCTION

Die Schrittkette beginnt im letzten Netzwerk. Dadurch liegt zwischen jedem Schritt mindestens 1 Zyklus und die Kette "rauscht" nicht gleich durch, falls alle Bedingungen erfüllt sind. Mit den Schrittkettenmerkern kannst du dann die gewünschten Aktionen einleiten.
Diese Merkerschrittketten sind aber nur für kleine Sachen gut, für umfangreiche Schrittketten nutze ich Sprungverteiler und einen eigenen Schrittketten-FB (Step7).

Gruß Ralle
 
OP
R

Rollex

Guest
Sorry erstmal an Markus. War so froh das ich endlich Hilfe gefunden habe, dass ich wohl ne falsche Taste gedrückt habe. Obs den Strukturierten Text oder die Ablaufsprache in S7 gibt, würde mich trotzdem noch interessieren.

Danke an Ralle für den Tipp. Werd ich gleich mal ausprobieren.

Ich meld mich wieder.
 

Markus

Administrator
Teammitglied
Beiträge
5.266
Punkte Reaktionen
1.301
Zuviel Werbung?
->Hier kostenlos registrieren
@rollex
wenn nur alle so einsichtig wären wie du... :)

ja es gibt für s7 natürlich die awl (anweisungsliste) und scl (strukturierter text)
 
Oben