In Step7 V5.x ist eine sehr detaillierte Baustein-Beschreibung wie der FC106 UNSCALE intern arbeitet. Damit kann man UNSCALE leicht in SCL nachprogrammieren.
Bipolar gibt lediglich an, ob beim jetzigen Scale_X beim Rückskalieren der Wert des Eingangs "Min" =0 oder =-27648 ist.
Eine solche Beschreibung mit der Formel findet man auch in der TIA-Hilfe unter UNSCALE (ohne die FC Nr.) für die Legacy-Bausteine der S7-1500.
Ich hatte etwas Zeit und Lust.
FUNCTION "UNSCALE_SCL" : Word
TITLE = 'UNSCALING VALUES'
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : PN_DP
FAMILY : CONVERT
NAME : UNSCALE
VERSION : 1.0
[COLOR="#008000"]//Funktion wie Step7 V5.x > TI-S7 Converting Blocks > FC106 UNSCALE[/COLOR]
VAR_INPUT
IN : Real; [COLOR="#008000"]// input value to be unscaled[/COLOR]
HI_LIM : Real; [COLOR="#008000"]// upper limit in engineering units[/COLOR]
LO_LIM : Real; [COLOR="#008000"]// lower limit in engineering units[/COLOR]
BIPOLAR : Bool; [COLOR="#008000"]// 1=bipolar; 0=unipolar[/COLOR]
END_VAR
VAR_OUTPUT
OUT : Int; [COLOR="#008000"]// result of the unscale conversion[/COLOR]
END_VAR
VAR_TEMP
tmp_OUT : Real;
K1 : Real;
END_VAR
VAR CONSTANT
K2 : Real := +27648.0;
END_VAR
BEGIN
[COLOR="#008000"]// Die Konstanten K1 und K2 werden unterschiedlich gesetzt, je nachdem, ob der Eingabewert BIPOLAR oder UNIPOLAR ist.[/COLOR]
[COLOR="#008000"]// BIPOLAR : Es wird angenommen, daß der ganzzahlige Ausgabewert zwischen -27648 und 27648 liegt, deshalb sind K1 = -27648,0 und K2 = +27648,0.[/COLOR]
[COLOR="#008000"]// UNIPOLAR: Es wird angenommen, daß der ganzzahlige Ausgabewert zwischen 0 und 27648 liegt, deshalb sind K1 = 0,0 und K2 = +27648,0.[/COLOR]
IF #BIPOLAR THEN
#K1 := -27648.0;
ELSE
#K1 := 0.0;
END_IF;
[COLOR="#008000"]// Liegt der Eingabewert nicht in dem Bereich zwischen LO_LIM und HI_LIM, dann wird der Ausgang (OUT) an den nächsten Grenzwert[/COLOR]
[COLOR="#008000"]// (den oberen oder den unteren) für den angegebenen Bereich des jeweiligen Typs (BIPOLAR oder UNIPOLAR) gebunden und ein Fehler ausgegeben.[/COLOR]
[COLOR="#008000"]// Der Signalzustand von ENO wird auf "0" und RET_VAL wird auf W#16#0008 gesetzt.[/COLOR]
#UNSCALE_SCL := 8; [COLOR="#008000"]// Return: Vorbelegung mit Fehlerstatus W#16#0008[/COLOR]
IF #HI_LIM > #LO_LIM THEN [COLOR="#008000"]// direkt proportional[/COLOR]
IF #IN < #LO_LIM THEN
#tmp_OUT := #K1;
ELSIF #IN > #HI_LIM THEN
#tmp_OUT := #K2;
ELSE
#UNSCALE_SCL := 0; [COLOR="#008000"]// Return: 0 für OK[/COLOR]
END_IF;
ELSE [COLOR="#008000"]// umgekehrt proportional[/COLOR]
IF #IN < #HI_LIM THEN
#tmp_OUT := #K1;
ELSIF #IN > #LO_LIM THEN
#tmp_OUT := #K2;
ELSE
#UNSCALE_SCL := 0; [COLOR="#008000"]// Return: 0 für OK[/COLOR]
END_IF;
END_IF;
IF #UNSCALE_SCL = 0 THEN [COLOR="#008000"]// IN ist OK[/COLOR]
[COLOR="#008000"]// Die Funktion UNSCALE arbeitet mit der folgenden Gleichung:[/COLOR]
[COLOR="#008000"]// OUT = [ ((IN-LO_LIM)/(HI_LIM-LO_LIM)) * (K2-K1) ] + K1[/COLOR]
#tmp_OUT := ( ((#IN - #LO_LIM) / (#HI_LIM - #LO_LIM)) * (#K2 - #K1) ) + #K1; [COLOR="#008000"]// Es muß HI_LIM <> LO_LIM sein![/COLOR]
END_IF;
#OUT := DINT_TO_INT(TRUNC(#tmp_OUT));
[COLOR="#008000"]// ENO: 1 kein Fehler / 0 Fehler[/COLOR]
ENO := #UNSCALE_SCL = 0;
END_FUNCTIONFUNCTION "SCALE_SCL" : Word
TITLE = 'SCALING VALUES'
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : PN_DP
FAMILY : CONVERT
NAME : SCALE
VERSION : 1.0
[COLOR="#008000"]//Funktion wie Step7 V5.x > TI-S7 Converting Blocks > FC105 SCALE[/COLOR]
VAR_INPUT
IN : Int; [COLOR="#008000"]// input value to be scaled[/COLOR]
HI_LIM : Real; [COLOR="#008000"]// upper limit in engineering units[/COLOR]
LO_LIM : Real; [COLOR="#008000"]// lower limit in engineering units[/COLOR]
BIPOLAR : Bool; [COLOR="#008000"]// 1=bipolar; 0=unipolar[/COLOR]
END_VAR
VAR_OUTPUT
OUT : Real; [COLOR="#008000"]// result of the scale conversion[/COLOR]
END_VAR
VAR_TEMP
IN_Real : Real;
K1 : Real;
END_VAR
VAR CONSTANT
K2 : Real := +27648.0;
END_VAR
BEGIN
[COLOR="#008000"]// Die Konstanten K1 und K2 werden unterschiedlich gesetzt, je nachdem, ob der Eingabewert BIPOLAR oder UNIPOLAR ist.[/COLOR]
[COLOR="#008000"]// BIPOLAR : Es wird angenommen, daß der ganzzahlige Eingabewert zwischen -27648 und 27648 liegt, deshalb sind K1 = -27648,0 und K2 = +27648,0.[/COLOR]
[COLOR="#008000"]// UNIPOLAR: Es wird angenommen, daß der ganzzahlige Eingabewert zwischen 0 und 27648 liegt, deshalb sind K1 = 0,0 und K2 = +27648,0.[/COLOR]
IF #BIPOLAR THEN
#K1 := -27648.0;
ELSE
#K1 := 0.0;
END_IF;
[COLOR="#008000"]// Ist der ganzzahlige Eingabewert kleiner als K1, dann wird der Ausgang (OUT) an LO_LIM gebunden und ein Fehler ausgegeben.[/COLOR]
[COLOR="#008000"]// Ist der ganzzahlige Eingabewert größer als K2, dann wird der Ausgang an HI_LIM gebunden und ein Fehler ausgegeben.[/COLOR]
[COLOR="#008000"]// Der Signalzustand von ENO wird auf "0" und RET_VAL wird auf W#16#0008 gesetzt.[/COLOR]
#SCALE_SCL := 8; [COLOR="#008000"]// Return: Vorbelegung mit Fehlerstatus W#16#0008[/COLOR]
#IN_Real := INT_TO_REAL(#IN);
IF #IN_Real < #K1 THEN
#OUT := #LO_LIM;
ELSIF #IN_Real > #K2 THEN
#OUT := #HI_LIM;
ELSE
#SCALE_SCL := 0; [COLOR="#008000"]// Return: 0 für OK[/COLOR]
[COLOR="#008000"]// Die Funktion SCALE arbeitet mit der folgenden Gleichung:[/COLOR]
[COLOR="#008000"]// OUT = [ ((FLOAT(IN) - K1)/(K2-K1)) * (HI_LIM-LO_LIM) ] + LO_LIM[/COLOR]
#OUT := ( ((#IN_Real - #K1) / (#K2 - #K1)) * (#HI_LIM - #LO_LIM) ) + #LO_LIM;
END_IF;
[COLOR="#008000"]// ENO: 1 kein Fehler / 0 Fehler[/COLOR]
ENO := #SCALE_SCL = 0;
END_FUNCTIONVorsicht! Die Beschreibung von UNSCALE in der TIA-Hilfe ist fehlerhaft (irgendwie typisch TIA
)Richtig ist, daß der Ausgabewert (OUT) im Bereich von -27648 bis +27648 bzw. 0 bis +27648 liegt. Der Wert am Parameter IN muß im Bereich LO_LIM bis HI_LIM liegen.TIA V15.1 UNSCALE: Deskalieren schrieb:
Ja, ist nicht 100% sicher formuliert, aber:Vorsicht! Die Beschreibung von UNSCALE in der TIA-Hilfe ist fehlerhaft (irgendwie typisch TIA
Richtig ist, daß der Ausgabewert (OUT) im Bereich von -27648 bis +27648 bzw. 0 bis +27648 liegt. Der Wert am Parameter IN muß im Bereich LO_LIM bis HI_LIM liegen.
"und in einem Wertebereich" bezieht sich also auf den durch die beiden Konstanten K1 und K2 im Zusammenhang mit der Formel angegebenen Wertebereich und nicht auf den Parameter IN (also kein logisches UND, sondern ein grammatikalisches zur Satzteilverknüpfung).
