Zuviel Werbung? - > Hier kostenlos beim SPS-Forum registrieren

Ergebnis 1 bis 5 von 5

Thema: Knx Szenenbaustein 753-646

  1. #1
    Registriert seit
    24.01.2015
    Ort
    94562 Oberpöring
    Beiträge
    24
    Danke
    4
    Erhielt 0 Danke für 0 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Hallo,

    wünsche noch ein frohes neues Jahr.

    Gibt es einen fertigen Szenenbausten bei dem man z. B. Bei langem Tastendruck Werte wie Licht gedimmt 40%, Jalousie 30%, Lamellen 20% Werte speichert und bei kurzem Tastendruck die Werte an den Blind_actuator oder Analogausgang weiter gibt?

    Danke im voraus

    Gruß Florian

    Gesendet von meinem HUAWEI MT7-L09 mit Tapatalk
    Zitieren Zitieren Knx Szenenbaustein 753-646  

  2. #2
    Registriert seit
    06.01.2016
    Beiträge
    3
    Danke
    1
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Hallo,
    Schau mal da nach vielleicht ist was für deinen fahl dabei.: http://www.wagocatalog.com/okv3/down...tions_02_d.pdf

  3. #3
    Registriert seit
    24.01.2015
    Ort
    94562 Oberpöring
    Beiträge
    24
    Danke
    4
    Erhielt 0 Danke für 0 Beiträge

    Standard

    Hallo IchundIch,

    nein leider ist das nicht dabei was ich suche.
    Danke trozdem.

    Gruß Florian

  4. #4
    Registriert seit
    29.01.2015
    Ort
    Hansastraße 27, 32423 Minden
    Beiträge
    136
    Danke
    7
    Erhielt 67 Danke für 20 Beiträge

    Standard

    Hallo,

    also einen Funktionsbaustein der die besagten Funktionen mitführt, haben wir leider nicht. Aber man kann sich mit einigen Funktionsbausteinen der Wago Bibliotheken, die gewünschten Funktionen nachbauen. Ich denke das auswerten der Kurz- und Lang- Signale der Digitalen Eingänge (oder KNX Tast/Dimmsensoren), ist das Hauptproblem?!

    Dieses ist in wenigen Wago Bausteinen, welche eine Dimmfunktion haben bereits integriert. Dies ist aber leider nicht in Kombination mit Dimmwert hoch-, runterzählen und Updaten bei kurz tasten verfügbar.

    Nach deiner beschriebenen Anforderung, habe ich einen Funktionsbaustein programmiert:

    Code:
    --------------------------------------------------------------------Anfang Deklaration-----------------------------------------------------------------------------------------
    
    
    FUNCTION_BLOCK Fb_ChangeOrUpdate_PrecentValue
    (*WICHTIG*)
    (*Bitte bedenke, dass dein Task Aufrufintervall immer min. doppelt so schnell sein muss, wie deine eingestellte Wertänderungsgeschwindigkeit
        Beispiel:
        Wertänderungsgeschwindigkeit: t#40ms
    
    
        zyklische Task
        Taskaufrufintervall:    t#20ms
    *)
    
    
    VAR_INPUT
        xSetOrDimmUp : BOOL;
        xSetOrDimmDown : BOOL;
        tShortTime: TIME := t#500ms;
    END_VAR
    VAR_OUTPUT
        rActualPrecentValue : REAL;(*Ausgang zeigt imme den aktuell eingestellten Dimmwert an*)
        rLastUpdatedPrecentValue : REAL;(*Ausgang Prozentwert nach kurz tasten (Update)*)
        xUpdate : BOOL; (*Ausgang wird immer für einen Zyklus auf "True" gesetzt, sollte ein kurz tasten betätigt worden sein*)
    
    
    END_VAR
    VAR
        TonDelayDimmUp: TON;
        tUpSignal: TIME;
        Ton1Inkrement: TON;
        tInkrementValue: TIME := t#40ms;(*Wertänderungsgeschwindigkeit*)
        flInkrement: R_TRIG;
        rValue: REAL := 0;
        TonDelayDimmDown: TON;
        Ton1Dekrement: TON;
        tDekrementValue: TIME := t#40ms;(*Wertänderungsgeschwindigkeit*)
        flDekrement: R_TRIG;
        tDownSignal: TIME ;
        flLostSignal: F_TRIG;
    END_VAR
    ------------------------------------------------------------Ende Deklaration---------------------------------------------------------------------------------
    
    ------------------------------------------------------------Anfang Quellcode--------------------------------------------------------------------------------
    
    (*Init----------------------------*)
    xUpdate := FALSE;
    tUpSignal := tShortTime ;
    tDownSignal := tShortTime;
    (*--------------------------------*)
    
    
    (*SET xUpDate bei kurz Tastendruck (DEFAULT: Tastendruck < t#500ms)*)
    flLostSignal(CLK:=xSetOrDimmUp OR xSetOrDimmDown , Q=> );(*überwachung fallende Flanke der UP/Down Inputs*)
    IF  flLostSignal.Q  AND NOT TonDelayDimmUp.Q AND NOT TonDelayDimmDown.Q THEN (*Set "xUpDate" WENN fallende Flanke und Tastendruck < t#500ms*)
       xUpdate := TRUE;
    END_IF
    (*----------------------------------------------------*)
    
    
    
    
    (*Einschaltverzögerung für UP and DOWN Inputs (Langtastendruck)*)
    TonDelayDimmUp(IN:=xSetOrDimmUp , PT:=tUpSignal , Q=> , ET=> );
    TonDelayDimmDown(IN:=xSetOrDimmDown , PT:= tDownSignal, Q=> , ET=> );
    (*-----------------------------------------------------*)
    
    
    
    
    (*Inkrementieren des Prozentwerts bei Langtastendruck des "xSetOrDimmUp" (Tasterverriegelung inklusieve)*)
    IF TonDelayDimmUp.Q AND NOT xSetOrDimmDown  THEN
    
    
        Ton1Inkrement(IN:=NOT Ton1Inkrement.Q , PT:= tInkrementValue, Q=> , ET=> );
        flInkrement(CLK:= Ton1Inkrement.Q, Q=> );
    
    
        IF flInkrement.Q AND rValue < 99.8  THEN
            rValue := rValue + 0.2;
        END_IF
    
    
    END_IF
    (*----------------------------------------------------------------------*)
    
    
    
    
    (*Dekrementieren des Prozentwertes bei Langtastendruck des "xSetOrDimmDown" (Tasterverriegelung inklusieve)*)
    IF TonDelayDimmDown.Q AND NOT xSetOrDimmUp  THEN
    
    
        Ton1Dekrement(IN:=NOT Ton1Dekrement.Q , PT:= tDekrementValue, Q=> , ET=> );
        flDekrement(CLK:= Ton1Dekrement.Q, Q=> );
    
    
        IF flDekrement.Q AND  rValue > 0.2 THEN
             rValue := rValue - 0.2;
        END_IF
    
    
    END_IF
    (*----------------------------------------------------------------------*)
    
    
    rActualPrecentValue := rValue;(*Zuweisung der internen Variable auf den Ausgang*)
    
    
    IF xUpdate THEN
       rLastUpdatedPrecentValue := rValue;
    END_IF
    
    ------------------------------------------------------------------------Ende Quellcode---------------------------------------------------------------------------------------------
    Ich habe folgende Variablen als Ausgang nach Außen geführt:

    1. aktuell geänderten Prozentwert
    2. Prozentwert, welcher den Zustand des letzten Updates beinhaltet

    Nun könntest du selber entscheiden ob du diesen Wert auf einen Analogen 0-10V Ausgang(Umrechnung mittels "FuAO" aus der "Building_HVAC_03.lib") gibst oder diesen Wert als Dimmwert für eine Dali Gruppe/Kurzadresse nutzt ("FbSendDimmValue" aus der "Dali_647_02.lib").

    Ich hoffe ich konnte dir mit diesem Beispiel etwas weiterhelfen.
    Ihr/Euer

    WAGO Support Team
    WAGO Kontakttechnik GmbH & Co. KG
    http://www.wago.com

    mailto:support@wago.com
    phone: +49 (0) 571 887 - 555

  5. #5
    Registriert seit
    15.04.2015
    Beiträge
    20
    Danke
    0
    Erhielt 3 Danke für 3 Beiträge

    Standard


    Zuviel Werbung?
    -> Hier kostenlos registrieren
    Hallo,

    die Wago Bibliothek WagoBuilding_01.lib sollte die notwenigen Hilfsmittel zur Verfügung stellen.

    http://www.wago.de/appnoteadmin/libr...lding_01_d.pdf

    Es gibt einen Szenenbaustein für Licht und Beschattung und bei Bedarf gibt es auch einen Baustein zur Auswertung Tastendruck Kurz/Lang.
    Wenn KNX Taster verwendet werden, dann ist die Auswertung Kurz/Lang schon im Tastsensor integriert (z.B. Funktion Jalousie).
    Die oben genannten und im Screenshot dargestellten Bausteine müssen "nur" noch mit den KNX Bausteinen verbunden werden.

    Unbenannt.JPG

Ähnliche Themen

  1. Antworten: 40
    Letzter Beitrag: 17.09.2017, 01:40
  2. Sonstiges LOGO 0BA8 an Siemens Display 6AV6 646-0BA21-2AX0
    Von thomsguy im Forum Simatic
    Antworten: 2
    Letzter Beitrag: 25.11.2015, 21:59
  3. Inbetriebnahme DALI-Multi-Klemme 753-647
    Von FS2015 im Forum CODESYS und IEC61131
    Antworten: 2
    Letzter Beitrag: 13.10.2015, 09:06
  4. Antworten: 0
    Letzter Beitrag: 16.07.2014, 10:01
  5. Wago Anschlusschema 753-440
    Von CoDeSys123456 im Forum CODESYS und IEC61131
    Antworten: 16
    Letzter Beitrag: 13.04.2012, 17:38

Lesezeichen

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •