FUNCTION_BLOCK FB 10
TITLE =
VERSION : 0.1
VAR_INPUT
Speicher : BOOL ;
Reset : BOOL ;
Eingangswert : S5TIME ;
DBNr : BLOCK_DB ;
Startbyte : DINT ;
Anzahl_Werte : DINT ;
END_VAR
VAR_IN_OUT
FP_Speicher : BOOL ;
Zeigernummer : DWORD ;
END_VAR
VAR_TEMP
Impuls_Speicher : BOOL ;
Byteanzahl : INT ;
Zeiger_Pointerformat : DWORD ;
END_VAR
BEGIN
NETWORK
TITLE =Initialisierung
//Mit Reset (z.B. beim SPS-Start) wird der Speicherstellenzeiger auf den
//Startwert zurückgesetzt.
U #Reset;
SPBN strt;
L #Startbyte;
T #Zeigernummer;
strt: NOP 0;
NETWORK
TITLE =Speichern?
//HIGH/LOW-Abfrage für Speichern
U #Speicher;
FP #FP_Speicher;
= #Impuls_Speicher;
U #Impuls_Speicher;
SPBN ende;
NETWORK
TITLE =Eingangswert im DB abspeichern
//Pointer erzeugen
//Wert an der gezeigten Stelle speichern
L #Zeigernummer; // Startbytenummer
SLD 3; // auf Bytestelle im Pointer verschieben
T #Zeiger_Pointerformat; //
AUF #DBNr;
L #Eingangswert; // Wert
T DBW [#Zeiger_Pointerformat]; // abspeichern
NETWORK
TITLE =Zeiger auf nächsten Wert stellen
L 2; // Byteanzahl des zu speichernden Wertes
T #Byteanzahl;
L #Zeigernummer; // ZeigerNr. erhöhen
L #Byteanzahl;
+D ;
T #Zeigernummer;
NETWORK
TITLE =
//Letztes Startbyte berechnen
//Anfangs-Offset hinzufügen
//Mit Zeigernummer vergleichen
//Gf. auf Start rücksetzen
L #Anzahl_Werte; // Letztes Anfangsbyte berechnen
L #Byteanzahl;
*D ;
L #Startbyte; // Startverschiebung
+D ;
L #Zeigernummer; // Abfrage auf Speicherende
<D ;
SPBN ende;
L #Startbyte; // Rücksetzen
T #Zeigernummer;
NETWORK
TITLE =Schleifen-Ende
ende: NOP 0;
END_FUNCTION_BLOCK
