Taste mit 2 Funktionen

[Phase]

Hallo, Ich habe eine Taste die mir, wenn ich sie drücke einen kurzen Impuls auf einen Ausgang gibt. Nun will ich zusätzlich wenn ich sie dann innerhalb einer Zeit von ca 1s. nochmals drücke einen Merker setzen.

Kann mir jemand ziemlich simpel erklären wie ich sowas realisieren kann und wie so etwas funktioniert?

[vierlagig]

nimm die taste, starte eine ausschaltverzögerung (dauer=1s), und werte diese undverknüpft mit einer positiven flanke am taster-eingang aus und setze deinen merker

[vierlagig]

*
FUNCTION FC 1607 : VOID
TITLE =double trigger
//for set xOut the xTrigger must have switched twice in the time tTime
AUTHOR : '4lagig'
FAMILY : BoolGF
VERSION : 0.1


VAR_INPUT
  xTrigger : BOOL ;    
  xReset : BOOL ;    
  fTimer : TIMER ;    
  tTime : S5TIME ;    
END_VAR
VAR_OUTPUT
  xOut : BOOL ;    
END_VAR
VAR_IN_OUT
  xHelpFlag : BOOL ;    
END_VAR
VAR_TEMP
  xTemp : BOOL ;    
END_VAR
BEGIN
NETWORK
TITLE =
//the first trigger takes effect in the last three lines
//the second trigger set the xOut
      U     #xTrigger; // check
      FP    #xHelpFlag; // for positive
      =     #xTemp; // flank

      U     #xTemp; // if flank
      U     #fTimer; // and fTimer on
      S     #xOut; // then set xOut
      U     #xReset; // if xReset
      R     #xOut; // then reset xOut

      U     #xTemp; // if flank
      L     #tTime; // then start
      SA    #fTimer; // the off delay
END_FUNCTION