o db210.dbx 0.1 [B]*** das ist käse, gehört natürlich weg ***[/B]
Ich würde es nicht als Umweg bezeichnen:
@linuxluder,
das Verwenden von Merkern und auch der S5-Timer ist nicht mehr wirklich zeitgemäß. Bei der S7-1200 gibt es z.B. letztere schon nicht mehr.
Du solltest den Baustein mal als gekapselten FB (warum FB und nicht FC?) erstellen.
Dabei musst Du dann auch überlegen, welche Merker durch statische Variablen ersetzt werden müssen, welche auch temporär sein können, wie man die IEC-Timer als Multiinstanz einfügt und wie Du Zeitvorgaben sowie Ein-/Ausgänge über die Bausteinschnittstelle übergibst.
Insgesamt ein wirklich schönes Übungsprojekt.
Also das hier, komplett ohne "Einweisung" anzugehen, dafür fehlt mir im Moment die Zeit. Bitte versteht mich nicht falsch, ihr habt mir auch eure Zeit geschenkt, aber für meine Zwecke würde ich das mit Kanonen auf Spatzen schießen.
Ist nicht so schlimm, wie es vielleicht klingt und sind ganz sicher keine Kanonen.
FUNCTION_BLOCK "Ventile"
TITLE =
VERSION : 0.1
VAR_INPUT
Start : BOOL ;
Stop : BOOL ;
END_VAR
VAR_OUTPUT
V1 : BOOL ;
V2 : BOOL ;
END_VAR
VAR
Oeffnen1 : BOOL ;
Oeffnen2 : BOOL ;
Flankenmerker : BOOL ;
T71_Merker : BOOL ;
Oeffnen1_V1 : "TON";
Oeffnen2_V1 : "TON";
Schliessen_V1 : "TON";
Oeffnen2_V2 : "TON";
Schliessen_V2 : "TON";
END_VAR
VAR_TEMP
Umschalten : BOOL ;
V1_Offen : BOOL ;
V2_Starten : BOOL ;
V2_Offen : BOOL ;
END_VAR
BEGIN
NETWORK
TITLE =
// U #Start // Ein-Schalter
// UN #Oeffnen2 // nicht vor komplettem Durchlauf neu starten
// S #Oeffnen1 // 1. Ein-Verzögerung starten
// U #Stop // Aus-Schalter
// R #Oeffnen1 // 1. Öffnung ausschalten
// R #Oeffnen2 // 2. Öffnung ausschalten
U #Start; // Ein-/Aus-Taster
FP #Flankenmerker; // Flankenmerker
= #Umschalten; // Flanke Taster
U #Umschalten; // bei Tastendruck (Flanke)
X #Oeffnen1; // 1. Öffnung invertieren
UN #Oeffnen2; // bei aktiver 2. Öffnung immer ausschalten
= #Oeffnen1;
U #Umschalten; // bei Tastendruck immer
R #Oeffnen2; // 2. Öffnung abschalten
// Öffnung beenden / nächste Öffnung:
U #Schliessen_V1.Q; // V1 schliessen
U #Schliessen_V2.Q; // V2 schliessen
U #Oeffnen2; // 2. Öffnung
R #Oeffnen2; // 2. Öffnung rücksetzen
U #Schliessen_V1.Q; // V1 schliessen
U #Oeffnen1; // 1. Öffnung
R #Oeffnen1; // 1. Öffnung rücksetzen
S #Oeffnen2; // 2. Ein-Verzögerung starten
// Zeiten Öffnen
CALL #Oeffnen1_V1 (
IN := #Oeffnen1,
PT := T#5S);
CALL #Oeffnen2_V1 (
IN := #Oeffnen2,
PT := T#4S);
U #Oeffnen1_V1.Q;
O #Oeffnen2;
= #V2_Starten;
CALL #Oeffnen2_V2 (
IN := #V2_Starten,
PT := T#2S);
// Zeiten schliessn
U #Oeffnen1_V1.Q;
O #Oeffnen2_V1.Q;
= #V1_Offen;
CALL #Schliessen_V1 (
IN := #V1_Offen,
PT := T#2S);
U #Oeffnen2_V2.Q;
= #V2_Offen;
CALL #Schliessen_V2 (
IN := #V2_Offen,
PT := T#8S);
// Ausgänge
U #V1_Offen; // V1 öffnen
UN #Schliessen_V1.Q; // V1 schliessen
= #V1; // V1
U #V2_Offen; // V2 öffnen
UN #Schliessen_V2.Q; // V2 schliessen
= #V2; // V2
END_FUNCTION_BLOCKZumindest kannst Du die Zeiten im ms-Bereich einstellen.
So kann ich im Moment ganz schlecht beurteilen, woran es genau liegt, dass ich keinen TaT bekomme. Soll aber jetzt nicht zum Foto-Forum werden hier. 
