digitales Potentiometer

Zuviel Werbung?
-> Hier kostenlos registrieren
Wenn es nur ein Vorschub ist und die Rückmeldung nicht notwendig wäre, dann kann man doch einfach 2 Tasten +/- verwenden.
Das können doch schon die meisten Umrichter direkt! Stichwort Motorpoti! Dazu bräuchte man nicht mal eine SPS

Zitieren
Da stellt sich aber die Frage, wie das bei größeren Sprüngen aussieht? Ein Poti/Drehgeber kann man ja schnell drehen, aber bei Tastern artet das in Dauerfeuer aus.
Alternativ könnte man vier Taster nehmen, zwei für große Schritte und zwei für kleine Schritte.
 
ich mach sowas ähnliches bei Vor-Ort Bedienungen von FU gesteuerten Pumpenantrieben, damit man im Handbetrieb die Geschwindikeit anpassen kann. Es geht, ist aber erklärungsbedürftig für den Bediener, bzw. muss man eine Bedienungsanleitung mit dran machen!

Hardware: Taste +, Taste-, Taste schnell. Auswahlschalter für Antriebe!

Mit Taster dauer drücken läuft Zähler hoch (Schrittweite für schnell und langsam einstelbar)
Mit Taster kurz drücken und wieder loslassen wird um eingestellten Wert gezählt (z.B. 5%, 10% pro Impuls)

ich hab einen Code dazu. Ist aber für S7-Classic. In Quelle konvertiert

Code:
FUNCTION_BLOCK FB 129
TITLE =UP_DOWN_INT: Wert mit Tasten vergrößeren und verkleinern
VERSION : 0.1


VAR_INPUT
  UP : BOOL ;   
  DOWN : BOOL ;   
  SET : BOOL ;   
  SET_VALUE : INT ;   
  MIN : INT ;   
  MAX : INT ;   
  STEP_SLOW : INT ;   
  STEP_FAST : INT ;   
  STEP_PULS : INT ;   
  TAKT : TIME ;   
  DELAY_FAST : TIME ;    //Verzögerungszeit für Umschalten auf Schnell
END_VAR
VAR_IN_OUT
  VALUE : INT ;   
END_VAR
VAR
  lb_FP_UP : BOOL ;   
  lb_FP_DOWN : BOOL ;   
  UP_PULS : BOOL ;   
  DOWN_PULS : BOOL ;   
  FAST : BOOL ;   
  TAKT_PULS : BOOL ;   
  T1 : SFB 4;   
  T2 : SFB 4;   
END_VAR
BEGIN
NETWORK
TITLE =



NETWORK
TITLE =Puls UP

      U     #UP;
      FP    #lb_FP_UP;
      =     #UP_PULS;
NETWORK
TITLE =Puls DOWN

      U     #DOWN;
      FP    #lb_FP_DOWN;
      =     #DOWN_PULS;
NETWORK
TITLE =Verzögerung bis zum schnellen Zählen

      U(    ;
      U     #UP;
      UN    #DOWN;
      O     ;
      U     #DOWN;
      UN    #UP;
      )     ;
      =     L      0.0;
      BLD   103;
      CALL #T1 (
           IN                       := L      0.0,
           PT                       := #DELAY_FAST,
           Q                        := #FAST);

      NOP   0;
NETWORK
TITLE =Zähltakt

      U(    ;
      O     #UP;
      O     #DOWN;
      )     ;
      UN    #TAKT_PULS;
      =     L      0.0;
      BLD   103;
      CALL #T2 (
           IN                       := L      0.0,
           PT                       := #TAKT,
           Q                        := #TAKT_PULS);

      NOP   0;
NETWORK
TITLE =SET: Wert setzen

      UN    #SET;
      SPB   NE5;
      L     #SET_VALUE;
      SPA   CHK;
NE5:  NOP   0;

NETWORK
TITLE =

      U     #DOWN_PULS;
      SPB   D_P;

      U     #UP_PULS;
      SPB   U_P;

      U     #UP;
      U     #TAKT_PULS;
      UN    #FAST;
      SPB   U_S;

      U     #DOWN;
      U     #TAKT_PULS;
      UN    #FAST;
      SPB   D_S;

      U     #UP;
      U     #FAST;
      U     #TAKT_PULS;
      SPB   U_F;

      U     #DOWN;
      U     #FAST;
      U     #TAKT_PULS;
      SPB   D_F;
      BEA   ;

NETWORK
TITLE =

U_S:  NOP   0; // Up slow
      L     #VALUE;
      L     #STEP_SLOW;
      +I    ;
      SPA   CHK;

U_F:  NOP   0; // Up fast
      L     #VALUE;
      L     #STEP_FAST;
      +I    ;
      SPA   CHK;

U_P:  NOP   0; // Up pulse
      L     #VALUE;
      L     #STEP_PULS;
      +I    ;
      SPA   CHK;


D_S:  NOP   0; // Down slow
      L     #VALUE;
      L     #STEP_SLOW;
      -I    ;
      SPA   CHK;

D_P:  NOP   0; // Down puls
      L     #VALUE;
      L     #STEP_PULS;
      -I    ;
      SPA   CHK;

D_F:  NOP   0; // Down fast
      L     #VALUE;
      L     #STEP_FAST;
      -I    ;

CHK:  L     #MIN; // Wert auf Min/Max begrenzen
      <I    ;
      SPB   SAVE;
      TAK   ;
      L     #MAX;
      >I    ;
      SPB   SAVE;
      TAK   ;
SAVE: T     #VALUE;

END_FUNCTION_BLOCK
 
Zuviel Werbung?
-> Hier kostenlos registrieren
Habe eine Variante für Elevatoren im Handbetrieb.
Taster [-], [0], [+].
Elevator steht und [-] + 0.5 sek. --> Elevator startet auf niedrigste Geschwindigkeit.
Elevator steht und [+] + 0.5 sek. --> Elevator startet auf höchste Geschwindigkeit.
Elevator steht und [-] & [+] + 0.5 sek. --> Elevator startet auf mittlere Geschwindigkeit.
Elevator läuft und [-] impuls --> Elevator läuft um 1% langsahmer.
Elevator läuft und [+] impuls --> Elevator läuft um 1% schneller.
Elevator läuft und [0] --> Elevator stoppt.
 
Moin zusammen,

wir bauen Maschinen, die vereinfacht gesagt konventionellen Werkzeugmaschinen wie Dreh- und Fräsmaschinen ähneln. Mehrere CNC gesteuerte Achsen, eine Spindel und ab geht die Blechbearbeitung.
Bedient wird das Ganze über einen Beckhoff PanelPC mit selbst gebautem Pult drunter. Dort befindet sich eine Maus, eine Tastatur und mehrere Taster ( zum Stoppen, Starten etc ) sowie ein paar Potis zum steuern der Vorschübe.
Um diese Potis geht es in meiner Fragestellung an euch.
In diesem Pult sitz ein EK1100 Buskoppler und diverse Beckhoff Klemmen. Die Potis gehen auf eine EL3204 ( analog Input PT100 ). Also eine Widerstandsmessung mit zwei festen Endlagen. Eine Klemme versorgt 4 Potis ( genau die verbaute Anzahl ) und kostet ~150€. Die Potis sind vernachlässigbar günstig.
Das ist die Ausganglage aller Maschinen und soweit gut.

Nun gibt es Kunden, die hätten gern an anderer Stelle der Maschine noch ein Poti verbaut, welches den selben Vorschub steuert. Und da fangen die Fragen an.
Die gleiche Lösung wie oben noch einmal verbauen ist zwar kostengünstig, bringt aber Probleme mit sich.
Welches Poti wirkt gerade?
Was ist, wenn ich das Eine auf die negative Endlage stelle und mit dem Anderen noch tiefer möchte?
Eins voll nach links, Eins voll nach rechts = Mittelstellung. Ich komme wieder in Bedrängnis bzgl. der Endlagen.
Gehen wir mal davon aus, dass Eins der Master wäre. Die Ausganglage sind unterschiedliche Stellungen beider zueinander. Sobald ich das Masterpoti berühre, springt mein Vorschub? Auch nicht schön.

Also wünschen wir uns die Potis "digitaler". Ohne Endanschläge. Endlosdrehend z.B.
Ein Poti mit IO-Link! Gibt es nur leider nicht.
Notlösung wäre nun einen inkrementellen Drehgeber mit IO-Link zu kaufen, die Welle schwergängiger zu machen, ne 3D-gedruckte Kappe drauf und fertig ist das "Poti". Da die physische Stellung keinen Bezug mehr zum Wert hat würden sich zwei Potis davon nicht mehr gegenseitig beeinflussen.
Für uns das "Problem" ist nun, das so ein Drehgeber mit mind. 200€ ( ifm Link ) zu Buche schlägt.
Das wären bei den bisherigen 4 Potis 800€ plus 120€ für die IO-Link Klemme. Mal Anzahl der "Steuerstellen".

Irgendwie ist mir die Lösung zu teuer. Jedes alte Autoradio hat einen Drehknopf.
Es wirkt so, als gäbe es industriell keinen Bedarf für so eine Anwendung und das kann ich mir einfach nicht vorstellen.

Habt Ihr mit so einer Fragestellung schon einmal zu tun gehabt, verbaut vielleicht genau solche Potentiometer oder kennt Maschinen, wo dies elegant gelöst wurde?

TLDR: Ich wünsche mir eine kostengünstige, endlosdrehende, digitale Dreheingabemöglichkeit für unsere Maschine.

Ja so etwas in der Art hatten wir damals auch gelöst, aber nicht direkt auf der SPS.
Wir hatten an der Maschine mit Potis und Tastern direkt die Möglichkeit zu Steuern und eine Fernbedienung mit den selben Funktionen (Eingabe/Ausgabe).
Die Potis waren Digital und hatten auch immer eine Anzeige(welcher Wert eingestellt ist) jetzt konnte man auf die Fernbedienung umschalten und die aktuellen Werte wurden auf der Fernbedienung übertragen und an der Maschine konnte man nichts mehr verstellen nur Anzeige, außer stop oder Not-Aus versteht sich.
Es waren um die 15 Potis und einige Knöpfe, die Fernbedienung war ein ganz schöner Prügel 😅
 
Bei den TE geht es um CNC gesteuerte Achsen,
da wird in den Maschinsteuertafeln findet man
üblicherweise diese Elektronischen Handräder,
damit man schnell reagieren kann, wenn man zb.
zu schnell ins Material fährt. Wenn er jetzt von
zwei Stellen bedienen möchte, führt doch kein
weg daran vorbei.
 
Zurück
Oben